Allow to pass arguments to a program compiled for the Oric Atmos. Code

contributed by Stefan A. Haubenthal.


git-svn-id: svn://svn.cc65.org/cc65/trunk@4941 b7a2c559-68d2-44c3-8de9-860c34a00d81

doc/atmos.sgml

@@ -162,13 +162,17 @@ following functions (and a few others):
 
 <sect>Other hints<p>
 
-<!--<sect1>Passing arguments to the program<p>
+<sect1>Function keys<p>
+
+These are defined to be FUNCT + number key.
+
+<sect1>Passing arguments to the program<p>
 
 Command line arguments can be passed to <tt/main()/. Since this is not
 supported by BASIC, the following syntax was chosen:
 
 <tscreen><verb>
-    CALL#500:REM,ARG1," ARG2", ARG 3,, ARG5, ...
+    CALL#500:REM ARG1 " ARG2 IS QUOTED" ARG3 "" ARG5
 </verb></tscreen>
 
 <enum>
@@ -179,7 +183,7 @@ supported by BASIC, the following syntax was chosen:
 <item>The first argument passed to <tt/main/ is the program name.
 <item>A maximum number of 10 arguments (including the program name) are
       supported.
-</enum>-->
+</enum>
 
 
 <sect1>Interrupts<p>

libsrc/atmos/mainargs.s

@@ -1,24 +1,113 @@
 ;
 ; Ullrich von Bassewitz, 2003-03-07
+; Stefan Haubenthal, 2011-01-28
 ;
 ; Setup arguments for main
 ;
 
+	.constructor	initmainargs, 24
+	.import		__argc, __argv
+	.macpack	generic
 
-	.constructor    initmainargs, 24
-       	.import         __argc, __argv
+MAXARGS	 = 10			; Maximum number of arguments allowed
+REM	 = $9d			; BASIC token-code
+NAME_LEN = 0			; maximum length of command-name
+BASIC_BUF = $35
 
 
 ;---------------------------------------------------------------------------
 ; Get possible command-line arguments. Goes into the special INIT segment,
 ; which may be reused after the startup code is run
 
-.segment        "INIT"
+.segment	"INIT"
 
-.proc   initmainargs
+.proc	initmainargs
 
-        rts
+	inc	__argc		; argc always is equal to, at least, 1
+
+; Find the "rem" token.
+;
+	ldx	#0
+L2:	lda	BASIC_BUF,x
+	beq	done		; no "rem," no args.
+	inx
+	cmp	#REM
+	bne	L2
+	ldy	#1 * 2
+
+; Find the next argument
+
+next:	lda	BASIC_BUF,x
+	beq	done		; End of line reached
+	inx
+	cmp	#' '		; Skip leading spaces
+	beq	next		;
+
+; Found start of next argument. We've incremented the pointer in X already, so
+; it points to the second character of the argument. This is useful since we
+; will check now for a quoted argument, in which case we will have to skip this
+; first character.
+
+found:	cmp	#'"'		; Is the argument quoted?
+	beq	setterm		; Jump if so
+	dex			; Reset pointer to first argument character
+	lda	#' '		; A space ends the argument
+setterm:sta	term		; Set end of argument marker
+
+; Now store a pointer to the argument into the next slot. Since the BASIC
+; input buffer is located at the start of a RAM page, no calculations are
+; necessary.
+
+	txa			; Get low byte
+	add	#<BASIC_BUF	; Not at page boundary
+	sta	argv,y		; argv[y]= &arg
+	iny
+;;	lda	#>BASIC_BUF
+;;	sta	argv,y
+	iny
+	inc	__argc		; Found another arg
+
+; Search for the end of the argument
+
+argloop:lda	BASIC_BUF,x
+	beq	done
+	inx
+	cmp	term
+	bne	argloop
+
+; We've found the end of the argument. X points one character behind it, and
+; A contains the terminating character. To make the argument a valid C string,
+; replace the terminating character by a zero.
+
+	lda	#0
+	sta	BASIC_BUF-1,x
+
+; Check if the maximum number of command line arguments is reached. If not,
+; parse the next one.
+
+	lda	__argc		; Get low byte of argument count
+	cmp	#MAXARGS	; Maximum number of arguments reached?
+	bcc	next		; Parse next one if not
+
+; (The last vector in argv[] already is NULL.)
+
+done:	lda	#<argv
+	ldx	#>argv
+	sta	__argv
+	stx	__argv + 1
+
+	rts
 
 .endproc
 
+; These arrays are zeroed before initmainargs is called.
+; char	name[16+1];
+; char* argv[MAXARGS+1]={name};
+;
+.bss
+term:	.res	1
+name:	.res	NAME_LEN + 1
 
+.data
+argv:	.addr	name
+	.res	MAXARGS * 2