mirror of
https://github.com/cc65/cc65.git
synced 2024-07-05 06:28:57 +00:00
074e10d288
When a program starts running, INIT is moved from one place to another place. Then, INIT's code is executed; and, the first place is re-used for variables. After the INIT code has finished, the second place can be re-used by the heap and the C stack. That means that initiation code and data won't waste any RAM space after they stop being needed.
143 lines
3.1 KiB
ArmAsm
143 lines
3.1 KiB
ArmAsm
;
|
|
; Startup code for cc65 (C64 version)
|
|
;
|
|
|
|
.export _exit
|
|
.exportzp init_load_, init_run_
|
|
.export __STARTUP__ : absolute = 1 ; Mark as startup
|
|
|
|
.import initlib, donelib
|
|
.import move_init, zerobss, callmain
|
|
.import RESTOR, BSOUT, CLRCH
|
|
.import __HIMEM__ ; from configure file
|
|
.importzp ST
|
|
|
|
.include "zeropage.inc"
|
|
.include "c64.inc"
|
|
|
|
|
|
; ------------------------------------------------------------------------
|
|
; Startup code
|
|
|
|
; Two zero-page pointers are needed before any zero-page stuff is saved.
|
|
; Choose locations that are not used by anything.
|
|
|
|
init_load_ := FREKZP
|
|
init_run_ := FREKZP+2
|
|
|
|
|
|
.segment "STARTUP"
|
|
|
|
Start:
|
|
|
|
; Switch to the second charset.
|
|
|
|
lda #14
|
|
jsr BSOUT
|
|
|
|
; Switch off the BASIC ROM.
|
|
|
|
lda $01
|
|
sta mmusave ; Save the memory configuration
|
|
and #$F8
|
|
ora #$06 ; Enable Kernal+I/O, disable BASIC
|
|
sta $01
|
|
|
|
tsx
|
|
stx spsave ; Save the system stack ptr
|
|
|
|
; Allow some re-entrancy by skipping the next task if it already was done.
|
|
; This often can let us rerun the program without reloading it.
|
|
|
|
ldx moveinit
|
|
beq L0
|
|
|
|
; Move the INIT segment from where it was loaded (over ZPSAVE and BSS)
|
|
; into where it must be run (in the heap).
|
|
|
|
jsr move_init
|
|
dec moveinit ; set to false
|
|
|
|
; Save space by putting the rest of the start-up code in the INIT segment,
|
|
; which can be re-used by the heap.
|
|
|
|
L0: jsr initstart
|
|
|
|
; Back from main() [this is also the exit() entry]. Run the module destructors.
|
|
|
|
_exit: pha ; Save the return code on stack
|
|
jsr donelib
|
|
|
|
; Copy back the zero-page stuff.
|
|
|
|
ldx #zpspace-1
|
|
L2: lda zpsave,x
|
|
sta sp,x
|
|
dex
|
|
bpl L2
|
|
|
|
; Place the program return code into BASIC's status variable.
|
|
|
|
pla
|
|
sta ST
|
|
|
|
; Restore the system stuff.
|
|
|
|
ldx spsave
|
|
txs ; Restore stack pointer
|
|
ldx mmusave
|
|
stx $01 ; Restore memory configuration
|
|
|
|
; Back to BASIC.
|
|
|
|
rts
|
|
|
|
|
|
; ------------------------------------------------------------------------
|
|
|
|
.segment "INIT"
|
|
|
|
initstart:
|
|
|
|
; Save the zero-page locations that we need.
|
|
|
|
ldx #zpspace-1
|
|
L1: lda sp,x
|
|
sta zpsave,x
|
|
dex
|
|
bpl L1
|
|
|
|
; Clear the BSS data.
|
|
|
|
jsr zerobss
|
|
|
|
; Set up the stack.
|
|
|
|
lda #<__HIMEM__
|
|
ldx #>__HIMEM__
|
|
sta sp
|
|
stx sp+1 ; Set argument stack ptr
|
|
|
|
; Call the module constructors.
|
|
|
|
jsr initlib
|
|
|
|
; Push the command-line arguments; and, call main().
|
|
|
|
jmp callmain
|
|
|
|
|
|
; ------------------------------------------------------------------------
|
|
; Data
|
|
|
|
.data
|
|
|
|
mmusave:.res 1
|
|
spsave: .res 1
|
|
moveinit:
|
|
.byte 1
|
|
|
|
.segment "ZPSAVE"
|
|
|
|
zpsave: .res zpspace
|