mirror of
https://github.com/cc65/cc65.git
synced 2024-11-03 10:07:02 +00:00
8ecdf9d6b7
Rename tgi_setup to tgi_install. Make tgi_install and tgi_deinstall user callable. More cosmetic changes. git-svn-id: svn://svn.cc65.org/cc65/trunk@1966 b7a2c559-68d2-44c3-8de9-860c34a00d81
73 lines
1.6 KiB
ArmAsm
73 lines
1.6 KiB
ArmAsm
;
|
|
; Ullrich von Bassewitz, 22.06.2002
|
|
;
|
|
|
|
|
|
.include "tgi-kernel.inc"
|
|
|
|
.import _strlen, pushax, tosumulax
|
|
|
|
;-----------------------------------------------------------------------------
|
|
; unsigned __fastcall__ tgi_textwidth (const char* s);
|
|
; /* Calculate the width of the text in pixels according to the current text
|
|
; * style.
|
|
; */
|
|
|
|
|
|
_tgi_textwidth:
|
|
|
|
ldy _tgi_textdir ; Get text direction
|
|
bne height
|
|
|
|
; Result is
|
|
;
|
|
; strlen (s) * tgi_textmagx * tgi_fontsizex
|
|
;
|
|
; Since we don't expect textmagx to have large values, we do the multiplication
|
|
; by looping.
|
|
|
|
width: jsr _strlen
|
|
jsr pushax
|
|
|
|
lda #0
|
|
tax
|
|
ldy _tgi_textmagx
|
|
@L1: clc
|
|
adc _tgi_fontsizex
|
|
bcc @L2
|
|
inx
|
|
@L2: dey
|
|
bne @L1
|
|
|
|
jmp tosumulax ; Result * strlen (s)
|
|
|
|
;-----------------------------------------------------------------------------
|
|
; unsigned __fastcall__ tgi_textheight (const char* s);
|
|
; /* Calculate the height of the text in pixels according to the current text
|
|
; * style.
|
|
; */
|
|
|
|
_tgi_textheight:
|
|
ldy _tgi_textdir ; Get text direction
|
|
bne width ; Jump if vertical
|
|
|
|
; Result is
|
|
;
|
|
; tgi_textmagy * tgi_fontsizey
|
|
;
|
|
; Since we don't expect textmagx to have large values, we do the multiplication
|
|
; by looping.
|
|
|
|
height: lda #0
|
|
tax
|
|
ldy _tgi_textmagy
|
|
@L1: clc
|
|
adc _tgi_fontsizey
|
|
bcc @L2
|
|
inx
|
|
@L2: dey
|
|
bne @L1
|
|
rts
|
|
|
|
|