mirror of
https://github.com/cc65/cc65.git
synced 2024-11-02 18:06:48 +00:00
e3b2fcc78d
module constructors/destructors and remove the conio init functions that were called from the startup code. git-svn-id: svn://svn.cc65.org/cc65/trunk@479 b7a2c559-68d2-44c3-8de9-860c34a00d81
131 lines
2.4 KiB
ArmAsm
131 lines
2.4 KiB
ArmAsm
;
|
|
; Startup code for cc65 (Plus/4 version)
|
|
;
|
|
; This must be the *first* file on the linker command line
|
|
;
|
|
|
|
.export _exit
|
|
.import initlib, donelib
|
|
.import push0, _main, zerobss
|
|
|
|
.include "plus4.inc"
|
|
.include "../cbm/cbm.inc"
|
|
|
|
; ------------------------------------------------------------------------
|
|
; Define and export the ZP variables for the C64 runtime
|
|
|
|
.exportzp sp, sreg, regsave
|
|
.exportzp ptr1, ptr2, ptr3, ptr4
|
|
.exportzp tmp1, tmp2, tmp3, tmp4
|
|
.exportzp regbank, zpspace
|
|
|
|
.zeropage
|
|
|
|
zpstart = *
|
|
sp: .res 2 ; Stack pointer
|
|
sreg: .res 2 ; Secondary register/high 16 bit for longs
|
|
regsave: .res 2 ; slot to save/restore (E)AX into
|
|
ptr1: .res 2
|
|
ptr2: .res 2
|
|
ptr3: .res 2
|
|
ptr4: .res 2
|
|
tmp1: .res 1
|
|
tmp2: .res 1
|
|
tmp3: .res 1
|
|
tmp4: .res 1
|
|
regbank: .res 6 ; 6 byte register bank
|
|
|
|
zpspace = * - zpstart ; Zero page space allocated
|
|
|
|
.code
|
|
|
|
; ------------------------------------------------------------------------
|
|
; BASIC header with a SYS call
|
|
|
|
.org $0FFF
|
|
.word Head ; Load address
|
|
Head: .word @Next
|
|
.word 1000 ; Line number
|
|
.byte $9E,"4109" ; SYS 4109
|
|
.byte $00 ; End of BASIC line
|
|
@Next: .word 0 ; BASIC end marker
|
|
.reloc
|
|
|
|
; ------------------------------------------------------------------------
|
|
; Actual code
|
|
|
|
ldx #zpspace-1
|
|
L1: lda sp,x
|
|
sta zpsave,x ; save the zero page locations we need
|
|
dex
|
|
bpl L1
|
|
|
|
; Close open files
|
|
|
|
jsr CLRCH
|
|
|
|
; Switch to second charset
|
|
|
|
lda #14
|
|
jsr BSOUT
|
|
|
|
; Clear the BSS data
|
|
|
|
jsr zerobss
|
|
|
|
; Save system stuff and setup the stack
|
|
|
|
tsx
|
|
stx spsave ; save system stk ptr
|
|
|
|
sec
|
|
jsr MEMTOP ; Get top memory
|
|
cpy #$80 ; We can only use the low 32K :-(
|
|
bcc MemOk
|
|
ldy #$80
|
|
ldx #$00
|
|
MemOk: stx sp
|
|
sty sp+1 ; set argument stack ptr
|
|
|
|
; Call module constructors
|
|
|
|
jsr initlib
|
|
|
|
; Pass an empty command line
|
|
|
|
jsr push0 ; argc
|
|
jsr push0 ; argv
|
|
|
|
ldy #4 ; Argument size
|
|
jsr _main ; call the users code
|
|
|
|
; Call module destructors. This is also the _exit entry.
|
|
|
|
_exit: jsr donelib ; Run module destructors
|
|
|
|
; Restore system stuff
|
|
|
|
ldx spsave
|
|
txs
|
|
|
|
; Copy back the zero page stuff
|
|
|
|
ldx #zpspace-1
|
|
L2: lda zpsave,x
|
|
sta sp,x
|
|
dex
|
|
bpl L2
|
|
|
|
; Reset changed vectors
|
|
|
|
jmp RESTOR
|
|
|
|
|
|
.data
|
|
zpsave: .res zpspace
|
|
|
|
.bss
|
|
spsave: .res 1
|
|
|
|
|