mirror of
https://github.com/cc65/cc65.git
synced 2024-07-05 06:28:57 +00:00
842c151edd
We want to add the capability to not only get the time but also set the time, but there's no "setter" for the "getter" time(). The first ones that come into mind are gettimeofday() and settimeofday(). However, they take a struct timezone argument that doesn't make sense - even the man pages says "The use of the timezone structure is obsolete; the tz argument should normally be specified as NULL." And POSIX says "Applications should use the clock_gettime() function instead of the obsolescent gettimeofday() function." The ...timeofday() functions work with microseconds while the clock_...time() functions work with nanoseconds. Given that we expect our targets to support only 1/10 of seconds the microseconds look preferable at first sight. However, already microseconds require the cc65 data type 'long' so it's not such a relevant difference to nanoseconds. Additionally clock_getres() seems useful. In order to avoid code duplication clock_gettime() takes over the role of the actual time getter from _systime(). So time() now calls clock_gettime() instead of _systime(). For some reason beyond my understanding _systime() was mentioned in time.h. _systime() worked exactly like e.g. _sysremove() and those _sys...() functions are all considered internal. The only reason I could see would be a performance gain of bypassing the time() wrapper. However, all known _systime() implementations internally called mktime(). And mktime() is implemented in C using an iterative algorithm so I really can't see what would be left to gain here. From that perspective I decided to just remove _systime().
109 lines
2.6 KiB
ArmAsm
109 lines
2.6 KiB
ArmAsm
;
|
|
; Stefan Haubenthal, 2009-07-27
|
|
; Ullrich von Bassewitz, 2009-09-24
|
|
; Oliver Schmidt, 2018-08-14
|
|
;
|
|
; int clock_gettime (clockid_t clk_id, struct timespec *tp);
|
|
;
|
|
|
|
.include "time.inc"
|
|
.include "cbm610.inc"
|
|
.include "extzp.inc"
|
|
|
|
.import pushax, pusheax, tosmul0ax, steaxspidx, incsp1
|
|
.import sys_bank, restore_bank
|
|
.importzp sreg, tmp1, tmp2
|
|
|
|
|
|
;----------------------------------------------------------------------------
|
|
.code
|
|
|
|
.proc _clock_gettime
|
|
|
|
jsr sys_bank
|
|
jsr pushax
|
|
jsr pushax
|
|
|
|
ldy #CIA::TODHR
|
|
lda (cia),y
|
|
bpl AM
|
|
and #%01111111
|
|
sed
|
|
clc
|
|
adc #$12
|
|
cld
|
|
AM: jsr BCD2dec
|
|
sta TM + tm::tm_hour
|
|
ldy #CIA::TODMIN
|
|
lda (cia),y
|
|
jsr BCD2dec
|
|
sta TM + tm::tm_min
|
|
ldy #CIA::TODSEC
|
|
lda (cia),y
|
|
jsr BCD2dec
|
|
sta TM + tm::tm_sec
|
|
lda #<TM
|
|
ldx #>TM
|
|
jsr _mktime
|
|
|
|
ldy #timespec::tv_sec
|
|
jsr steaxspidx ; Pops address pushed by 2. pushax
|
|
|
|
lda #<(100 * 1000 * 1000 / $10000)
|
|
ldx #>(100 * 1000 * 1000 / $10000)
|
|
sta sreg
|
|
stx sreg+1
|
|
lda #<(100 * 1000 * 1000)
|
|
ldx #>(100 * 1000 * 1000)
|
|
jsr pusheax
|
|
ldy #CIA::TOD10
|
|
lda (cia),y
|
|
ldx #>$0000
|
|
jsr tosmul0ax
|
|
|
|
ldy #timespec::tv_nsec
|
|
jsr steaxspidx ; Pops address pushed by 1. pushax
|
|
|
|
jsr incsp1
|
|
|
|
lda #0
|
|
tax
|
|
jmp restore_bank
|
|
|
|
.endproc
|
|
|
|
;----------------------------------------------------------------------------
|
|
; dec = (((BCD>>4)*10) + (BCD&0xf))
|
|
|
|
.proc BCD2dec
|
|
|
|
tax
|
|
and #%00001111
|
|
sta tmp1
|
|
txa
|
|
and #%11110000 ; *16
|
|
lsr ; *8
|
|
sta tmp2
|
|
lsr
|
|
lsr ; *2
|
|
adc tmp2 ; = *10
|
|
adc tmp1
|
|
rts
|
|
|
|
.endproc
|
|
|
|
;----------------------------------------------------------------------------
|
|
; TM struct with date set to 1970-01-01
|
|
.data
|
|
|
|
TM: .word 0 ; tm_sec
|
|
.word 0 ; tm_min
|
|
.word 0 ; tm_hour
|
|
.word 1 ; tm_mday
|
|
.word 0 ; tm_mon
|
|
.word 70 ; tm_year
|
|
.word 0 ; tm_wday
|
|
.word 0 ; tm_yday
|
|
.word 0 ; tm_isdst
|
|
|