mirror of
https://github.com/cc65/cc65.git
synced 2024-11-19 21:32:19 +00:00
e47485f925
For quite some time I deliberately didn't add cursor support to the Apple II CONIO imöplementation. I consider it inappropriate to increase the size of cgetc() unduly for a rather seldom used feature. There's no hardware cursor on the Apple II so displaying a cursor during keyboard input means reading the character stored at the cursor location, writing the cursor character, reading the keyboard and finally writing back the character read initially. The naive approach is to reuse the part of cputc() that determines the memory location of the character at the cursor position in order to read the character stored there. However that means to add at least one additional JSR / RTS pair to cputc() adding 4 bytes and 12 cycles :-( Apart from that this approach means still a "too" large cgetc(). The approach implemented instead is to include all functionality required by cgetc() into cputc() - which is to read the current character before writing a new one. This may seem surprising at first glance but an LDA(),Y / TAX sequence adds only 3 bytes and 7 cycles so it cheaper than the JSR / RTS pair and allows to brings down the code increase in cgetc() down to a reasonable value. However so far the internal cputc() code in question saved the X register. Now it uses the X register to return the old character present before writing the new character for cgetc(). This requires some rather small adjustments in other functions using that internal cputc() code.
50 lines
1.2 KiB
ArmAsm
50 lines
1.2 KiB
ArmAsm
;
|
|
; Kevin Ruland
|
|
;
|
|
; char cgetc (void);
|
|
;
|
|
; If open_apple key is pressed then the high-bit of the key is set.
|
|
;
|
|
|
|
.export _cgetc
|
|
.import cursor, putchardirect
|
|
|
|
.include "apple2.inc"
|
|
|
|
_cgetc:
|
|
; Cursor on ?
|
|
lda cursor
|
|
beq :+
|
|
|
|
; Show caret.
|
|
.ifdef __APPLE2ENH__
|
|
lda #$7F | $80 ; Checkerboard, screen code
|
|
.else
|
|
lda #' ' | $40 ; Blank, flashing
|
|
.endif
|
|
jsr putchardirect ; Returns old character in X
|
|
|
|
; Wait for keyboard strobe.
|
|
: lda KBD
|
|
bpl :- ; If < 128, no key pressed
|
|
|
|
; Cursor on ?
|
|
ldy cursor
|
|
beq :+
|
|
|
|
; Restore old character.
|
|
pha
|
|
txa
|
|
jsr putchardirect
|
|
pla
|
|
|
|
; At this time, the high bit of the key pressed is set.
|
|
: bit KBDSTRB ; Clear keyboard strobe
|
|
.ifdef __APPLE2ENH__
|
|
bit BUTN0 ; Check if OpenApple is down
|
|
bmi done
|
|
.endif
|
|
and #$7F ; If not down, then clear high bit
|
|
done: ldx #>$0000
|
|
rts
|