mirror of
https://github.com/c64scene-ar/llvm-6502.git
synced 2025-10-31 08:16:47 +00:00
d442ab87b3
directory. This is useful in case someone who works with the config&make build system forgot to add a file to its CMakeLists.txt. Instead of obtaining undefined references at link time, cmake will complain at configure time on the first build after a svn update. git-svn-id: https://llvm.org/svn/llvm-project/llvm/trunk@85817 91177308-0d34-0410-b5e6-96231b3b80d8
55 lines
1.6 KiB
CMake
55 lines
1.6 KiB
CMake
include(AddFileDependencies)
|
|
|
|
|
|
macro(add_td_sources srcs)
|
|
file(GLOB tds *.td)
|
|
if( tds )
|
|
source_group("TableGen descriptions" FILES ${tds})
|
|
set_source_files_properties(${tds} PROPERTIES HEADER_FILE_ONLY ON)
|
|
list(APPEND ${srcs} ${tds})
|
|
endif()
|
|
endmacro(add_td_sources)
|
|
|
|
|
|
macro(add_header_files srcs)
|
|
file(GLOB hds *.h)
|
|
if( hds )
|
|
set_source_files_properties(${hds} PROPERTIES HEADER_FILE_ONLY ON)
|
|
list(APPEND ${srcs} ${hds})
|
|
endif()
|
|
endmacro(add_header_files)
|
|
|
|
|
|
function(llvm_process_sources OUT_VAR)
|
|
set( sources ${ARGN} )
|
|
llvm_check_source_file_list( ${sources} )
|
|
# Create file dependencies on the tablegenned files, if any. Seems
|
|
# that this is not strictly needed, as dependencies of the .cpp
|
|
# sources on the tablegenned .inc files are detected and handled,
|
|
# but just in case...
|
|
foreach( s ${sources} )
|
|
set( f ${CMAKE_CURRENT_SOURCE_DIR}/${s} )
|
|
add_file_dependencies( ${f} ${TABLEGEN_OUTPUT} )
|
|
endforeach(s)
|
|
if( MSVC_IDE )
|
|
# This adds .td and .h files to the Visual Studio solution:
|
|
add_td_sources(sources)
|
|
add_header_files(sources)
|
|
endif()
|
|
set( ${OUT_VAR} ${sources} PARENT_SCOPE )
|
|
endfunction(llvm_process_sources)
|
|
|
|
|
|
function(llvm_check_source_file_list)
|
|
set(listed ${ARGN})
|
|
file(GLOB globbed *.cpp)
|
|
foreach(g ${globbed})
|
|
get_filename_component(fn ${g} NAME)
|
|
list(FIND listed ${fn} idx)
|
|
if( idx LESS 0 )
|
|
message(SEND_ERROR "Found unknown source file ${g}
|
|
Please update ${CMAKE_CURRENT_SOURCE_DIR}/CMakeLists.txt\n")
|
|
endif()
|
|
endforeach()
|
|
endfunction(llvm_check_source_file_list)
|