PR#3
PREFIX /A2OSX.BUILD
NEW
INC 1
AUTO 6
				.LIST OFF
				.OP	65C02
				.OR	$2000
				.TF /A2OSX.BUILD/BIN/PS
*--------------------------------------
				.INB /A2OSX.BUILD/INC/MACROS.I
				.INB /A2OSX.BUILD/INC/A2OSX.I
*--------------------------------------
ZPPTR1			.EQ ZPBIN
*--------------------------------------
*			File Header (16 Bytes)
*--------------------------------------
CS.START		cld
				jmp (.1,x)
				.DA #$61				6502,Level 1 (65c02)
				.DA #1					BIN Layout Version 1
				.DA 0
				.DA CS.END-CS.START		CS
				.DA DS.END-DS.START		DS
				.DA #16					SS
				.DA #2					ZP
				.DA 0
*--------------------------------------
* Relocation Table
*--------------------------------------				
.1				.DA CS.INIT
				.DA CS.RUN
				.DA CS.DOEVENT		
				.DA	CS.QUIT
L.MSG0			.DA MSG0
L.MSG1			.DA MSG1
				.DA 0
*--------------------------------------
CS.INIT			clc
				rts
*--------------------------------------
CS.RUN			>LDYA pData
				>SYSCALL GetPSList.YA

				>LDYA L.MSG0
				>SYSCALL PrintF.YA

				lda (pData)				PS.COUNT
				beq .8			
				
.1				>LDA.G PS.Index
				inc
				sta (pData),y
				
				tay				
				lda (pData),y			PID
				
				>SYSCALL GetMemPtr.A
				>STYA ZPPTR1
				
				ldy #S.PS.hARGS
				lda (ZPPTR1),y
				>SYSCALL GetMemPtr.A
				>PUSHYA
				
				ldy #S.PS.PPID
				lda (ZPPTR1),y
				>PUSHA					Parent PID
				
				lda (ZPPTR1)			push flags
				>PUSHA

				ldy #S.PS.PID
				lda (ZPPTR1),y
				>PUSHA					PID
				>LDYA L.MSG1
				>SYSCALL PrintF.YA
				
.7				lda (pData)				PS.COUNT
				dec
				sta (pData)
				bne .1
				
.8				lda #0					tell Kernel that all done ok, but 
				sec						we do not want to stay in memory
				rts
*--------------------------------------
CS.DOEVENT		sec
				rts
*--------------------------------------
CS.QUIT			clc
				rts
*--------------------------------------
CS.END			
MSG0			>CSTR "ID  Flags    PID Command Line\r\n"
MSG1			>CSTR "%03d %b %03d %S\r\n"
*--------------------------------------
				.DUMMY
				.OR 0
DS.START
PS.COUNT		.BS 1
PS.DATA			.BS K.PS.MAX
PS.Index		.BS 1
DS.END
				.ED
*--------------------------------------
MAN
SAVE /A2OSX.SRC/BIN/PS.S
ASM