NEW
  AUTO 3,1
				.LIST OFF	
				.OP	65C02
				.OR	$2000
				.TF BIN/GTEST
*--------------------------------------
				.INB INC/MACROS.I
				.INB INC/A2OSX.I
				.INB INC/KERNEL.I
				.INB INC/GFX.I
*--------------------------------------
				.DUMMY
				.OR ZPBIN
ZS.START
hDevGFX			.BS 1
hFont			.BS 1
ZS.END
				.ED
*--------------------------------------
*			File Header (16 Bytes)
*--------------------------------------
CS.START		cld
				jmp (.1,x)
				.DA #$61				6502,Level 1 (65c02)
				.DA #1					BIN Layout Version 1
				.DA #0					#S.PS.F.EVENT		S.PS.F
				.DA #0
				.DA CS.END-CS.START		Code Size (without Constants)
				.DA DS.END-DS.START		Data Segment Size
				.DA #64					Stack Size
				.DA #ZS.END-ZS.START	Zero Page Size
				.DA 0
*--------------------------------------
.1				.DA CS.INIT
				.DA CS.RUN
				.DA CS.DOEVENT
				.DA	CS.QUIT
L.DEVNAME.GFX	.DA DEVNAME.GFX
L.FONTFILE		.DA FONTFILE
L.CB.RECT		.DA CB.RECT
L.CB.TEXT		.DA CB.TEXT
L.CB.Apple		.DA CB.Apple
L.BM.Apple		.DA BM.Apple
L.MESSAGE		.DA MESSAGE

				.DA 0
*--------------------------------------
CS.INIT			clc
				rts
*--------------------------------------
CS.RUN			jsr GFX.Open
				bcs .9
				
				>LDYA L.FONTFILE
				>SYSCALL LoadStkObj
				bcs .9
				stx hFont

				>LDYA L.CB.RECT
				jsr GFX.Write.YA
				>DEBUG				
				lda hFont
				sta CB.TEXT+S.CB.hFont
							
				>LDYA L.MESSAGE
				>STYA CB.TEXT+S.CB.TxtPtr
				
				>LDYA L.CB.TEXT
				>SYSCALL OSD
				bcs .9

				>LDYA L.CB.TEXT
				jsr GFX.Write.YA
				>DEBUG
				>LDYA L.BM.Apple
				>STYA CB.Apple+S.CB.SrcPtr

				>LDYA L.CB.Apple
				jsr GFX.Write.YA
				
				jsr GFX.Close
				
				lda #0
				sec
.9				rts
*--------------------------------------
CS.DOEVENT		clc
				rts
*--------------------------------------
CS.QUIT			lda hFont
				beq .8
				
				>SYSCALL FreeStkObj
				
.8				clc
				rts
*--------------------------------------
GFX.Open		>PUSHBI 0
				>LDYA L.DEVNAME.GFX
				>SYSCALL open
				bcs .9
				
				sta hDevGFX
.9				rts
*--------------------------------------
GFX.Write.YA	>PUSHYA
				>PUSHBI IOCTL.WRITE
				lda hDevGFX
				>SYSCALL IOCTL
				rts		
*--------------------------------------
GFX.Close		lda hDevGFX
				>SYSCALL close
				rts
*--------------------------------------
CS.END
DEVNAME.GFX		.AZ "/DEV/GFX"
FONTFILE		.AZ "${ROOT}SBIN/GUI/SYSX7"
MESSAGE			.AZ "        DHGR & OSD Drivers Test        "

CB.RECT			.DA #S.CB.CMD.FILLRECT
				.DA #S.CB.OP.SET
				.DA #S.CB.M.C16
				.DA #6					Color
				.DA 20
				.DA 10
				.DA 540
				.DA 182

CB.TEXT			.DA #S.CB.CMD.DRAWTEXT
				.DA #S.CB.OP.SET
				.DA #S.CB.M.MONO
				.BS 1					hFONT
				.DA 0					X1
				.DA 0					Y1
				.DA 0					X2
				.DA 0					Y2
				.DA 60					DstX
				.DA 60					DstY				
				.BS 2					TXTPTR
				.DA 0					DSTPTR

CB.Apple		.DA #S.CB.CMD.BITBLT
				.DA #S.CB.OP.SET+S.CB.OP.COLOR
				.DA #S.CB.M.C16
				.DA 0
				.DA 0					X1
				.DA 0					Y1
				.DA 16					SrcW
				.DA 7					SrcH
				.DA 60					DstX
				.DA 80					DstY				
				.BS 2					SrcPtr
				.DA 0					DSTPTR

*--------------------------------------
BM.Apple		.DA #S.BM.F.BBP4
				.DA #2					RowBytes
				.DA 16					W
				.DA 7					H
				.DA 0					no MASK.OFS
				
				.HS FFF6				green (8)
				.HS 6FF6				green (8)
				.HS EEEE				yellow (15)
				.HS	CCFC				orange (14)
				.HS 88F8				magenta (10)
				.HS 9999				violet (11)
				.HS 1FF1				Dark blue (4)
*--------------------------------------
				.DUMMY
				.OR 0
DS.START	
DS.END
				.ED
*--------------------------------------
MAN
SAVE USR/SRC/BIN/GTEST.S
ASM