mirror of
https://github.com/deater/dos33fsprogs.git
synced 2024-09-10 08:54:51 +00:00
186 lines
3.0 KiB
ArmAsm
186 lines
3.0 KiB
ArmAsm
|
; Display a 40x96 lo-res image
|
||
|
|
||
|
; by deater (Vince Weaver) <vince@deater.net>
|
||
|
|
||
|
|
||
|
appleII_intro:
|
||
|
|
||
|
;===================
|
||
|
; init screen
|
||
|
jsr TEXT
|
||
|
jsr HOME
|
||
|
bit KEYRESET
|
||
|
|
||
|
;===================
|
||
|
; init vars
|
||
|
|
||
|
lda #0
|
||
|
sta DRAW_PAGE
|
||
|
|
||
|
;=============================
|
||
|
; Load graphic page0
|
||
|
|
||
|
lda #<appleII_low
|
||
|
sta GBASL
|
||
|
lda #>appleII_low
|
||
|
sta GBASH
|
||
|
lda #$c
|
||
|
jsr load_rle_gr
|
||
|
|
||
|
lda #4
|
||
|
sta DRAW_PAGE
|
||
|
|
||
|
jsr gr_copy_to_current ; copy to page1
|
||
|
|
||
|
; GR part
|
||
|
bit PAGE1
|
||
|
bit LORES ; 4
|
||
|
bit SET_GR ; 4
|
||
|
bit FULLGR ; 4
|
||
|
|
||
|
jsr wait_until_keypressed
|
||
|
|
||
|
|
||
|
;=============================
|
||
|
; Load graphic page1
|
||
|
|
||
|
lda #<appleII_high
|
||
|
sta GBASL
|
||
|
lda #>appleII_high
|
||
|
sta GBASH
|
||
|
lda #$c
|
||
|
jsr load_rle_gr
|
||
|
|
||
|
lda #0
|
||
|
sta DRAW_PAGE
|
||
|
|
||
|
jsr gr_copy_to_current
|
||
|
|
||
|
; GR part
|
||
|
bit PAGE0
|
||
|
|
||
|
jsr wait_until_keypressed
|
||
|
|
||
|
|
||
|
;==============================
|
||
|
; setup graphics for vapor lock
|
||
|
;==============================
|
||
|
|
||
|
jsr vapor_lock ; 6+
|
||
|
|
||
|
; vapor lock returns with us at beginning of hsync in line
|
||
|
; 114 (7410 cycles), so with 5070 lines to go
|
||
|
|
||
|
; GR part
|
||
|
bit LORES ; 4
|
||
|
bit SET_GR ; 4
|
||
|
bit FULLGR ; 4
|
||
|
|
||
|
jsr gr_copy_to_current ; 6+ 9292
|
||
|
|
||
|
; now we have 322 left
|
||
|
|
||
|
; 322 - 12 = 310
|
||
|
; - 3 for jmp
|
||
|
; 307
|
||
|
|
||
|
; Try X=9 Y=6 cycles=307
|
||
|
ldy #6 ; 2
|
||
|
loopA: ldx #9 ; 2
|
||
|
loopB: dex ; 2
|
||
|
bne loopB ; 2nt/3
|
||
|
dey ; 2
|
||
|
bne loopA ; 2nt/3
|
||
|
|
||
|
jmp display_loop ; 3
|
||
|
|
||
|
.align $100
|
||
|
|
||
|
|
||
|
;================================================
|
||
|
; Display Loop
|
||
|
;================================================
|
||
|
; each scan line 65 cycles
|
||
|
; 1 cycle each byte (40cycles) + 25 for horizontal
|
||
|
; Total of 12480 cycles to draw screen
|
||
|
; Vertical blank = 4550 cycles (70 scan lines)
|
||
|
; Total of 17030 cycles to get back to where was
|
||
|
|
||
|
; We want to alternate between page1 and page2 every 65 cycles
|
||
|
; vblank = 4550 cycles to do scrolling
|
||
|
|
||
|
|
||
|
; 2 + 48*( (4+2+25*(2+3)) + (4+2+23*(2+3)+4+5)) + 9)
|
||
|
; 48*[(6+125)-1] + [(6+115+10)-1]
|
||
|
|
||
|
display_loop:
|
||
|
|
||
|
ldy #48 ; 2
|
||
|
|
||
|
outer_loop:
|
||
|
|
||
|
bit PAGE0 ; 4
|
||
|
ldx #25 ; 130 cycles with PAGE0 ; 2
|
||
|
page0_loop: ; delay 126+bit
|
||
|
dex ; 2
|
||
|
bne page0_loop ; 2/3
|
||
|
|
||
|
|
||
|
bit PAGE1 ; 4
|
||
|
ldx #23 ; 130 cycles with PAGE1 ; 2
|
||
|
page1_loop: ; delay 115+(7 loop)+4 (bit)+4(extra)
|
||
|
dex ; 2
|
||
|
bne page1_loop ; 2/3
|
||
|
|
||
|
nop ; 2
|
||
|
lda DRAW_PAGE ; 3
|
||
|
|
||
|
dey ; 2
|
||
|
bne outer_loop ; 2/3
|
||
|
|
||
|
|
||
|
|
||
|
;======================================================
|
||
|
; We have 4550 cycles in the vblank, use them wisely
|
||
|
;======================================================
|
||
|
; do_nothing should be 4550+1 -2-9 -7= 4533
|
||
|
|
||
|
jsr do_nothing ; 6
|
||
|
|
||
|
lda KEYPRESS ; 4
|
||
|
bpl no_keypress ; 3
|
||
|
jmp appleii_done
|
||
|
no_keypress:
|
||
|
|
||
|
jmp display_loop ; 3
|
||
|
|
||
|
appleii_done:
|
||
|
rts
|
||
|
|
||
|
|
||
|
;=================================
|
||
|
; do nothing
|
||
|
;=================================
|
||
|
; and take 4533-6 = 4527 cycles to do it
|
||
|
do_nothing:
|
||
|
|
||
|
; Try X=4 Y=174 cycles=4525 R2
|
||
|
|
||
|
nop ; 2
|
||
|
|
||
|
ldy #174 ; 2
|
||
|
loop1:
|
||
|
ldx #4 ; 2
|
||
|
loop2:
|
||
|
dex ; 2
|
||
|
bne loop2 ; 2nt/3
|
||
|
|
||
|
dey ; 2
|
||
|
bne loop1 ; 2nt/3
|
||
|
|
||
|
|
||
|
rts ; 6
|
||
|
|
||
|
|
||
|
|