mirror of
https://github.com/deater/dos33fsprogs.git
synced 2024-12-25 05:29:34 +00:00
dlowres_mode7: add initial checkin
This commit is contained in:
Vince Weaver
parent
af84003bcc
commit
0f6b0e0ef4
27
dlowres_mode7/Makefile
Normal file
27
dlowres_mode7/Makefile
Normal file
@ -0,0 +1,27 @@
|
|||||||
|
include ../Makefile.inc
|
||||||
|
|
||||||
|
DOS33 = ../dos33fs-utils/dos33
|
||||||
|
PNG2GR = ../gr-utils/png2gr
|
||||||
|
PNG2RLE = ../gr-utils/png2rle
|
||||||
|
|
||||||
|
all: dlowres_mode7.dsk
|
||||||
|
|
||||||
|
$(DOS33):
|
||||||
|
cd ../dos33fs-utils && make
|
||||||
|
|
||||||
|
dlowres_mode7.dsk: $(DOS33) DLOWRES_MODE7
|
||||||
|
$(DOS33) -y dlowres_mode7.dsk BSAVE -a 0x1000 DLOWRES_MODE7
|
||||||
|
|
||||||
|
###
|
||||||
|
|
||||||
|
DLOWRES_MODE7: dlowres_mode7.o
|
||||||
|
ld65 -o DLOWRES_MODE7 dlowres_mode7.o -C ./apple2_1000.inc
|
||||||
|
|
||||||
|
dlowres_mode7.o: dlowres_mode7.s \
|
||||||
|
dlowres_flying.s fast_multiply.s \
|
||||||
|
dlowres_utils.s dlowres_zp.inc
|
||||||
|
ca65 -o dlowres_mode7.o dlowres_mode7.s -l dlowres_mode7.lst
|
||||||
|
|
||||||
|
clean:
|
||||||
|
rm -f *~ *.o *.lst
|
||||||
|
|
||||||
12
dlowres_mode7/apple2_1000.inc
Normal file
12
dlowres_mode7/apple2_1000.inc
Normal file
@ -0,0 +1,12 @@
|
|||||||
|
MEMORY {
|
||||||
|
ZP: start = $00, size = $1A, type = rw;
|
||||||
|
RAM: start = $1000, size = $8E00, file = %O;
|
||||||
|
}
|
||||||
|
|
||||||
|
SEGMENTS {
|
||||||
|
CODE: load = RAM, type = ro;
|
||||||
|
RODATA: load = RAM, type = ro;
|
||||||
|
DATA: load = RAM, type = rw;
|
||||||
|
BSS: load = RAM, type = bss, define = yes;
|
||||||
|
ZEROPAGE: load = ZP, type = zp;
|
||||||
|
}
|
||||||
1256
dlowres_mode7/dlowres_flying.s
Normal file
1256
dlowres_mode7/dlowres_flying.s
Normal file
File diff suppressed because it is too large
Load Diff
BIN
dlowres_mode7/dlowres_mode7.dsk
Normal file
BIN
dlowres_mode7/dlowres_mode7.dsk
Normal file
Binary file not shown.
83
dlowres_mode7/dlowres_mode7.s
Normal file
83
dlowres_mode7/dlowres_mode7.s
Normal file
@ -0,0 +1,83 @@
|
|||||||
|
.include "dlowres_zp.inc"
|
||||||
|
|
||||||
|
;================================
|
||||||
|
; Clear screen and setup graphics
|
||||||
|
;================================
|
||||||
|
|
||||||
|
jsr HOME
|
||||||
|
jsr set_gr_page0
|
||||||
|
|
||||||
|
;================================
|
||||||
|
; Set up Double Low-res
|
||||||
|
;================================
|
||||||
|
; lda SET_GR ; graphics C050
|
||||||
|
; lda LORES ; lores C056
|
||||||
|
; lda TEXTGR ; mixset C053
|
||||||
|
; sta EIGHTYSTORE_OFF ; 80store C001
|
||||||
|
; sta EIGHTYCOL ; 80col C00d
|
||||||
|
; lda AN3 ; AN3 C05E
|
||||||
|
|
||||||
|
lda #0
|
||||||
|
sta DISP_PAGE ; Forgot to set initially
|
||||||
|
; real hardware and AppleWin default
|
||||||
|
; to different values
|
||||||
|
|
||||||
|
;===================================
|
||||||
|
; zero out the zero page that we use
|
||||||
|
;===================================
|
||||||
|
|
||||||
|
; memset()
|
||||||
|
|
||||||
|
;===================================
|
||||||
|
; Clear top/bottom of page 0 and 1
|
||||||
|
;===================================
|
||||||
|
|
||||||
|
jsr clear_screens
|
||||||
|
|
||||||
|
;=====================
|
||||||
|
; Flying
|
||||||
|
;=====================
|
||||||
|
|
||||||
|
jsr flying_start
|
||||||
|
|
||||||
|
;=====================
|
||||||
|
; All finished
|
||||||
|
;=====================
|
||||||
|
exit:
|
||||||
|
|
||||||
|
lda #$4
|
||||||
|
sta BASH
|
||||||
|
lda #$0
|
||||||
|
sta BASL ; restore to 0x400 (page 0)
|
||||||
|
; copy to 0x400 (page 0)
|
||||||
|
|
||||||
|
; call home
|
||||||
|
jsr HOME
|
||||||
|
|
||||||
|
|
||||||
|
; Return to BASIC?
|
||||||
|
rts
|
||||||
|
|
||||||
|
|
||||||
|
;===============================================
|
||||||
|
; External modules
|
||||||
|
;===============================================
|
||||||
|
|
||||||
|
.include "dlowres_utils.s"
|
||||||
|
.include "dlowres_flying.s"
|
||||||
|
|
||||||
|
.include "dlowres_sprites.inc"
|
||||||
|
|
||||||
|
;===============================================
|
||||||
|
; Variables
|
||||||
|
;===============================================
|
||||||
|
|
||||||
|
; waste memory with a lookup table
|
||||||
|
; maybe faster than using GBASCALC?
|
||||||
|
|
||||||
|
gr_offsets:
|
||||||
|
.word $400,$480,$500,$580,$600,$680,$700,$780
|
||||||
|
.word $428,$4a8,$528,$5a8,$628,$6a8,$728,$7a8
|
||||||
|
.word $450,$4d0,$550,$5d0,$650,$6d0,$750,$7d0
|
||||||
|
|
||||||
|
|
||||||
60
dlowres_mode7/dlowres_sprites.inc
Normal file
60
dlowres_mode7/dlowres_sprites.inc
Normal file
@ -0,0 +1,60 @@
|
|||||||
|
;================
|
||||||
|
; Ship Sprites
|
||||||
|
;================
|
||||||
|
|
||||||
|
splash_forward:
|
||||||
|
.byte $7,$2
|
||||||
|
.byte $00,$ee,$00,$00,$00,$ee,$00
|
||||||
|
.byte $ee,$00,$00,$00,$00,$00,$ee
|
||||||
|
|
||||||
|
splash_right:
|
||||||
|
.byte $7,$2
|
||||||
|
.byte $00,$00,$00,$00,$00,$ee,$00
|
||||||
|
.byte $00,$00,$00,$00,$00,$00,$ee
|
||||||
|
|
||||||
|
|
||||||
|
splash_left:
|
||||||
|
.byte $7,$2
|
||||||
|
.byte $00,$ee,$00,$00,$00,$00,$00
|
||||||
|
.byte $ee,$00,$00,$00,$00,$00,$00
|
||||||
|
|
||||||
|
shadow_forward:
|
||||||
|
.byte $3,$2
|
||||||
|
.byte $00,$aa,$00
|
||||||
|
.byte $a0,$aa,$a0
|
||||||
|
|
||||||
|
shadow_right:
|
||||||
|
.byte $3,$2
|
||||||
|
.byte $a0,$00,$aa
|
||||||
|
.byte $00,$0a,$a0
|
||||||
|
|
||||||
|
shadow_left:
|
||||||
|
.byte $3,$2
|
||||||
|
.byte $aa,$00,$a0
|
||||||
|
.byte $a0,$0a,$00
|
||||||
|
|
||||||
|
ship_forward:
|
||||||
|
.byte $9,$5
|
||||||
|
.byte $00,$00,$00,$00,$ff,$00,$00,$00,$00
|
||||||
|
.byte $00,$00,$00,$66,$ff,$66,$00,$00,$00
|
||||||
|
.byte $00,$00,$70,$2f,$12,$2f,$70,$00,$00
|
||||||
|
.byte $f0,$f7,$f7,$f2,$d9,$f2,$f7,$f7,$f0
|
||||||
|
.byte $00,$00,$00,$00,$0d,$00,$00,$00,$00
|
||||||
|
|
||||||
|
ship_right:
|
||||||
|
.byte $9,$5
|
||||||
|
.byte $00,$00,$00,$00,$00,$60,$60,$f0,$00
|
||||||
|
.byte $00,$f0,$70,$70,$f6,$f6,$6f,$66,$00
|
||||||
|
.byte $00,$07,$ff,$2f,$12,$27,$f6,$00,$00
|
||||||
|
.byte $00,$00,$00,$dd,$d9,$f2,$77,$00,$00
|
||||||
|
.byte $00,$00,$00,$00,$00,$0f,$ff,$70,$00
|
||||||
|
|
||||||
|
ship_left:
|
||||||
|
.byte $9,$5
|
||||||
|
.byte $00,$f0,$60,$60,$00,$00,$00,$00,$00
|
||||||
|
.byte $00,$66,$6f,$f6,$f6,$70,$70,$f0,$00
|
||||||
|
.byte $00,$00,$f6,$27,$12,$2f,$ff,$07,$00
|
||||||
|
.byte $00,$00,$77,$f2,$d9,$dd,$00,$00,$00
|
||||||
|
.byte $00,$70,$ff,$0f,$00,$00,$00,$00,$00
|
||||||
|
|
||||||
|
|
||||||
753
dlowres_mode7/dlowres_utils.s
Normal file
753
dlowres_mode7/dlowres_utils.s
Normal file
@ -0,0 +1,753 @@
|
|||||||
|
;=====================================================================
|
||||||
|
;= ROUTINES
|
||||||
|
;=====================================================================
|
||||||
|
|
||||||
|
|
||||||
|
clear_screens:
|
||||||
|
;===================================
|
||||||
|
; Clear top/bottom of page 0
|
||||||
|
;===================================
|
||||||
|
|
||||||
|
lda #$0
|
||||||
|
sta DRAW_PAGE
|
||||||
|
jsr clear_top
|
||||||
|
jsr clear_bottom
|
||||||
|
|
||||||
|
;===================================
|
||||||
|
; Clear top/bottom of page 1
|
||||||
|
;===================================
|
||||||
|
|
||||||
|
lda #$4
|
||||||
|
sta DRAW_PAGE
|
||||||
|
jsr clear_top
|
||||||
|
jsr clear_bottom
|
||||||
|
|
||||||
|
rts
|
||||||
|
|
||||||
|
;==========
|
||||||
|
; page_flip
|
||||||
|
;==========
|
||||||
|
|
||||||
|
page_flip:
|
||||||
|
lda DISP_PAGE ; 3
|
||||||
|
beq page_flip_show_1 ; 2nt/3
|
||||||
|
page_flip_show_0:
|
||||||
|
bit PAGE0 ; 4
|
||||||
|
lda #4 ; 2
|
||||||
|
sta DRAW_PAGE ; DRAW_PAGE=1 ; 3
|
||||||
|
lda #0 ; 2
|
||||||
|
sta DISP_PAGE ; DISP_PAGE=0 ; 3
|
||||||
|
rts ; 6
|
||||||
|
page_flip_show_1:
|
||||||
|
bit PAGE1 ; 4
|
||||||
|
sta DRAW_PAGE ; DRAW_PAGE=0 ; 3
|
||||||
|
lda #1 ; 2
|
||||||
|
sta DISP_PAGE ; DISP_PAGE=1 ; 3
|
||||||
|
rts ; 6
|
||||||
|
;====================
|
||||||
|
; DISP_PAGE=0 26
|
||||||
|
; DISP_PAGE=1 24
|
||||||
|
|
||||||
|
;======================
|
||||||
|
; memset
|
||||||
|
;======================
|
||||||
|
; a=value
|
||||||
|
; x=length
|
||||||
|
; MEMPTRL/MEMPTRH is address
|
||||||
|
memset:
|
||||||
|
ldy #0
|
||||||
|
memset_loop:
|
||||||
|
sta MEMPTRL,Y
|
||||||
|
iny
|
||||||
|
dex
|
||||||
|
bne memset_loop
|
||||||
|
rts
|
||||||
|
|
||||||
|
|
||||||
|
;=================
|
||||||
|
; load RLE image
|
||||||
|
;=================
|
||||||
|
; Output is BASH/BASL
|
||||||
|
; Input is in GBASH/GBASL
|
||||||
|
load_rle_gr:
|
||||||
|
lda #$0
|
||||||
|
tax
|
||||||
|
tay ; init X and Y to 0
|
||||||
|
|
||||||
|
sta CV ; ycoord=0
|
||||||
|
|
||||||
|
lda (GBASL),y ; load xsize
|
||||||
|
sta CH
|
||||||
|
iny ; (we should check if we had
|
||||||
|
; bad luck and overflows page)
|
||||||
|
|
||||||
|
iny ; skip ysize
|
||||||
|
|
||||||
|
rle_loop:
|
||||||
|
lda (GBASL),y ; load run value
|
||||||
|
cmp #$ff ; if 0xff
|
||||||
|
beq rle_done ; we are done
|
||||||
|
sta RUN
|
||||||
|
iny ; point to next value
|
||||||
|
bne rle_yskip1 ; if overflow, increment address
|
||||||
|
inc GBASH
|
||||||
|
rle_yskip1:
|
||||||
|
lda (GBASL),y ; load value to write
|
||||||
|
iny
|
||||||
|
bne rle_yskip2
|
||||||
|
inc GBASH
|
||||||
|
rle_yskip2:
|
||||||
|
sty TEMP2 ; save y for later
|
||||||
|
pha
|
||||||
|
lda #$0
|
||||||
|
tay
|
||||||
|
pla ; convoluted way to set y to 0
|
||||||
|
|
||||||
|
rle_run_loop:
|
||||||
|
sta (BASL),y ; write out the value
|
||||||
|
inc BASL ; increment the pointer
|
||||||
|
bne rle_skip3 ; if wrapped
|
||||||
|
inc BASH ; then increment the high value
|
||||||
|
rle_skip3:
|
||||||
|
inx ; increment the X value
|
||||||
|
cpx CH ; compare against the image width
|
||||||
|
bcc rle_not_eol ; if less then keep going
|
||||||
|
|
||||||
|
pha ; save out value on stack
|
||||||
|
|
||||||
|
lda BASL ; cheat to avoid a 16-bit add
|
||||||
|
cmp #$a7 ; we are adding 0x58 to get
|
||||||
|
bcc rle_add_skip ; to the next line
|
||||||
|
inc BASH
|
||||||
|
rle_add_skip:
|
||||||
|
clc
|
||||||
|
adc #$58 ; actually do the 0x58 add
|
||||||
|
sta BASL ; and store it back
|
||||||
|
|
||||||
|
inc CV ; add 2 to ypos
|
||||||
|
inc CV ; each "line" is two high
|
||||||
|
|
||||||
|
lda CV ; load value
|
||||||
|
cmp #15 ; if it's greater than 14 it wraps
|
||||||
|
bcc rle_no_wrap ; Thanks Woz
|
||||||
|
|
||||||
|
lda #$0 ; we wrapped, so set to zero
|
||||||
|
sta CV
|
||||||
|
|
||||||
|
; when wrapping have to sub 0x3d8
|
||||||
|
sec ; this is a 16-bit subtract routine
|
||||||
|
lda BASL
|
||||||
|
sbc #$d8 ; LSB
|
||||||
|
sta BASL
|
||||||
|
lda BASH ; MSB
|
||||||
|
sbc #$3 ;
|
||||||
|
sta BASH
|
||||||
|
|
||||||
|
rle_no_wrap:
|
||||||
|
lda #$0 ; set X value back to zero
|
||||||
|
tax
|
||||||
|
pla ; restore value to write from stack
|
||||||
|
|
||||||
|
rle_not_eol:
|
||||||
|
dec RUN ; decrement run value
|
||||||
|
bne rle_run_loop ; if not zero, keep looping
|
||||||
|
|
||||||
|
ldy TEMP2 ; restore the input pointer
|
||||||
|
sec
|
||||||
|
bcs rle_loop ; and branch always
|
||||||
|
|
||||||
|
rle_done:
|
||||||
|
lda #$15 ; move the cursor somewhere sane
|
||||||
|
sta CV
|
||||||
|
rts
|
||||||
|
|
||||||
|
|
||||||
|
;==========================================================
|
||||||
|
; set_text_page0
|
||||||
|
;==========================================================
|
||||||
|
;
|
||||||
|
set_text_page0:
|
||||||
|
bit PAGE0 ; set page0
|
||||||
|
bit TEXT ; set text mode
|
||||||
|
rts
|
||||||
|
|
||||||
|
;==========================================================
|
||||||
|
; set_gr_page0
|
||||||
|
;==========================================================
|
||||||
|
;
|
||||||
|
set_gr_page0:
|
||||||
|
;lda #4
|
||||||
|
;sta GR_PAGE
|
||||||
|
bit PAGE0 ; set page 0
|
||||||
|
bit LORES ; Lo-res graphics
|
||||||
|
bit TEXTGR ; mixed gr/text mode
|
||||||
|
bit SET_GR ; set graphics
|
||||||
|
rts
|
||||||
|
|
||||||
|
;=========================================================
|
||||||
|
; gr_copy_to_current
|
||||||
|
;=========================================================
|
||||||
|
; copy 0xc00 to DRAW_PAGE
|
||||||
|
; 2 + 8*38 + 4*80*23 + 4*120*26 + 13 = 20,159 = 20ms = 50Hz
|
||||||
|
;
|
||||||
|
gr_copy_to_current:
|
||||||
|
ldx #0 ; set y to zero ; 2
|
||||||
|
|
||||||
|
gr_copy_loop:
|
||||||
|
stx TEMP ; save y ; 3
|
||||||
|
txa ; move to A ; 2
|
||||||
|
asl ; mult by 2 ; 2
|
||||||
|
tay ; put into Y ; 2
|
||||||
|
lda gr_offsets,Y ; lookup low byte for line addr ; 5
|
||||||
|
sta OUTL ; out and in are the same ; 3
|
||||||
|
sta INL ; 3
|
||||||
|
lda gr_offsets+1,Y ; lookup high byte for line addr ; 5
|
||||||
|
adc DRAW_PAGE
|
||||||
|
sta OUTH ; 3
|
||||||
|
lda gr_offsets+1,Y ; lookup high byte for line addr ; 5
|
||||||
|
adc #$8 ; for now, fixed 0xc ; 2
|
||||||
|
sta INH ; 3
|
||||||
|
ldx TEMP ; restore y ; 3
|
||||||
|
|
||||||
|
ldy #0 ; set X counter to 0 ; 2
|
||||||
|
gr_copy_line:
|
||||||
|
lda (INL),Y ; load a byte ; 5
|
||||||
|
sta (OUTL),Y ; store a byte ; 6
|
||||||
|
iny ; increment pointer ; 2
|
||||||
|
|
||||||
|
cpx #$4 ; don't want to copy bottom 4*40 ; 2
|
||||||
|
bcs gr_copy_above4 ; 3
|
||||||
|
|
||||||
|
gr_copy_below4:
|
||||||
|
cpy #120 ; for early ones, copy 120 bytes ; 2
|
||||||
|
bne gr_copy_line ; 3
|
||||||
|
beq gr_copy_line_done ; 3
|
||||||
|
|
||||||
|
gr_copy_above4: ; for last four, just copy 80 bytes
|
||||||
|
cpy #80 ; 2
|
||||||
|
bne gr_copy_line ; 3
|
||||||
|
|
||||||
|
gr_copy_line_done:
|
||||||
|
inx ; increment y value ; 2
|
||||||
|
cpx #8 ; there are 8 of them ; 2
|
||||||
|
bne gr_copy_loop ; if not, loop ; 3
|
||||||
|
rts ; 6
|
||||||
|
|
||||||
|
;==========================================================
|
||||||
|
; Wait until keypressed
|
||||||
|
;==========================================================
|
||||||
|
;
|
||||||
|
|
||||||
|
wait_until_keypressed:
|
||||||
|
lda KEYPRESS ; check if keypressed
|
||||||
|
bpl wait_until_keypressed ; if not, loop
|
||||||
|
jmp figure_out_key
|
||||||
|
|
||||||
|
|
||||||
|
;==========================================================
|
||||||
|
; Get Key
|
||||||
|
;==========================================================
|
||||||
|
;
|
||||||
|
|
||||||
|
get_key:
|
||||||
|
|
||||||
|
check_paddle_button:
|
||||||
|
|
||||||
|
; check for paddle button
|
||||||
|
|
||||||
|
bit PADDLE_BUTTON0 ; 4
|
||||||
|
bpl no_button ; 2nt/3
|
||||||
|
lda #' '+128 ; 2
|
||||||
|
jmp save_key ; 3
|
||||||
|
|
||||||
|
no_button:
|
||||||
|
lda KEYPRESS ; 3
|
||||||
|
bpl no_key ; 2nt/3
|
||||||
|
|
||||||
|
figure_out_key:
|
||||||
|
cmp #' '+128 ; the mask destroys space ; 2
|
||||||
|
beq save_key ; so handle it specially ; 2nt/3
|
||||||
|
|
||||||
|
and #$5f ; mask, to make upper-case ; 2
|
||||||
|
check_right_arrow:
|
||||||
|
cmp #$15 ; 2
|
||||||
|
bne check_left_arrow ; 2nt/3
|
||||||
|
lda #'D' ; 2
|
||||||
|
check_left_arrow:
|
||||||
|
cmp #$08 ; 2
|
||||||
|
bne check_up_arrow ; 2nt/3
|
||||||
|
lda #'A' ; 2
|
||||||
|
check_up_arrow:
|
||||||
|
cmp #$0B ; 2
|
||||||
|
bne check_down_arrow ; 2nt/3
|
||||||
|
lda #'W' ; 2
|
||||||
|
check_down_arrow:
|
||||||
|
cmp #$0A ; 2
|
||||||
|
bne check_escape ; 2nt/3
|
||||||
|
lda #'S' ; 2
|
||||||
|
check_escape:
|
||||||
|
cmp #$1B ; 2
|
||||||
|
bne save_key ; 2nt/3
|
||||||
|
lda #'Q' ; 2
|
||||||
|
jmp save_key ; 3
|
||||||
|
|
||||||
|
no_key:
|
||||||
|
bit PADDLE_STATUS ; 3
|
||||||
|
bpl no_key_store ; 2nt/3
|
||||||
|
|
||||||
|
; check for paddle action
|
||||||
|
; code from http://web.pdx.edu/~heiss/technotes/aiie/tn.aiie.06.html
|
||||||
|
|
||||||
|
inc PADDLE_STATUS ; 5
|
||||||
|
lda PADDLE_STATUS ; 3
|
||||||
|
and #$03 ; 2
|
||||||
|
beq check_paddles ; 2nt/3
|
||||||
|
jmp no_key_store ; 3
|
||||||
|
|
||||||
|
check_paddles:
|
||||||
|
lda PADDLE_STATUS ; 3
|
||||||
|
and #$80 ; 2
|
||||||
|
sta PADDLE_STATUS ; 3
|
||||||
|
|
||||||
|
ldx #$0 ; 2
|
||||||
|
LDA PTRIG ;TRIGGER PADDLES ; 4
|
||||||
|
LDY #0 ;INIT COUNTER ; 2
|
||||||
|
NOP ;COMPENSATE FOR 1ST COUNT ; 2
|
||||||
|
NOP ; 2
|
||||||
|
PREAD2: LDA PADDL0,X ;COUNT EVERY 11 uSEC. ; 4
|
||||||
|
BPL RTS2D ;BRANCH WHEN TIMED OUT ; 2nt/3
|
||||||
|
INY ;INCREMENT COUNTER ; 2
|
||||||
|
BNE PREAD2 ;CONTINUE COUNTING ; 2nt/3
|
||||||
|
DEY ;COUNTER OVERFLOWED ; 2
|
||||||
|
RTS2D: ;RETURN W/VALUE 0-255
|
||||||
|
|
||||||
|
cpy #96 ; 2
|
||||||
|
bmi paddle_left ; 2nt/3
|
||||||
|
cpy #160 ; 2
|
||||||
|
bmi no_key_store ; 2nt/3
|
||||||
|
lda #'D' ; 2
|
||||||
|
jmp save_key ; 3
|
||||||
|
paddle_left:
|
||||||
|
lda #'A' ; 2
|
||||||
|
jmp save_key ; 3
|
||||||
|
|
||||||
|
no_key_store:
|
||||||
|
lda #0 ; no key, so save a zero ; 2
|
||||||
|
|
||||||
|
save_key:
|
||||||
|
sta LASTKEY ; save the key to our buffer ; 2
|
||||||
|
bit KEYRESET ; clear the keyboard buffer ; 4
|
||||||
|
rts ; 6
|
||||||
|
;============
|
||||||
|
; 33=nokey
|
||||||
|
; 48=worstkey
|
||||||
|
|
||||||
|
|
||||||
|
;=============================================
|
||||||
|
; put_sprite
|
||||||
|
;=============================================
|
||||||
|
; Sprite to display in INH,INL
|
||||||
|
; Location is XPOS,YPOS
|
||||||
|
; Note, only works if YPOS is multiple of two?
|
||||||
|
|
||||||
|
put_sprite:
|
||||||
|
|
||||||
|
ldy #0 ; byte 0 is xsize ; 2
|
||||||
|
lda (INL),Y ; 5
|
||||||
|
sta CH ; xsize is in CH ; 3
|
||||||
|
iny ; 2
|
||||||
|
|
||||||
|
lda (INL),Y ; byte 1 is ysize ; 5
|
||||||
|
sta CV ; ysize is in CV ; 3
|
||||||
|
iny ; 2
|
||||||
|
|
||||||
|
lda YPOS ; make a copy of ypos ; 3
|
||||||
|
sta TEMPY ; as we modify it ; 3
|
||||||
|
;===========
|
||||||
|
; 28
|
||||||
|
put_sprite_loop:
|
||||||
|
sty TEMP ; save sprite pointer ; 3
|
||||||
|
|
||||||
|
ldy TEMPY ; 3
|
||||||
|
lda gr_offsets,Y ; lookup low-res memory address ; 5
|
||||||
|
clc ; 2
|
||||||
|
adc XPOS ; add in xpos ; 3
|
||||||
|
sta OUTL ; store out low byte of addy ; 3
|
||||||
|
lda gr_offsets+1,Y ; look up high byte ; 5
|
||||||
|
adc DRAW_PAGE ; ; 3
|
||||||
|
sta OUTH ; and store it out ; 3
|
||||||
|
ldy TEMP ; restore sprite pointer ; 3
|
||||||
|
|
||||||
|
; OUTH:OUTL now points at right place
|
||||||
|
|
||||||
|
ldx CH ; load xsize into x ; 3
|
||||||
|
;===========
|
||||||
|
; 36
|
||||||
|
put_sprite_pixel:
|
||||||
|
lda (INL),Y ; get sprite colors ; 5
|
||||||
|
iny ; increment sprite pointer ; 2
|
||||||
|
|
||||||
|
sty TEMP ; save sprite pointer ; 3
|
||||||
|
ldy #$0 ; 2
|
||||||
|
|
||||||
|
; check if completely transparent
|
||||||
|
; if so, skip
|
||||||
|
|
||||||
|
cmp #$0 ; if all zero, transparent ; 2
|
||||||
|
beq put_sprite_done_draw ; don't draw it ; 2nt/3
|
||||||
|
; FIXME: use BIT? ;==============
|
||||||
|
; 17
|
||||||
|
|
||||||
|
sta COLOR ; save color for later ; 3
|
||||||
|
|
||||||
|
; check if top pixel transparent
|
||||||
|
|
||||||
|
and #$f0 ; check if top nibble zero ; 2
|
||||||
|
bne put_sprite_bottom ; if not skip ahead ; 2nt/3
|
||||||
|
|
||||||
|
lda #$f0 ; setup mask ; 2
|
||||||
|
sta MASK ; 3
|
||||||
|
bmi put_sprite_mask ; 2nt/3
|
||||||
|
|
||||||
|
put_sprite_bottom:
|
||||||
|
lda COLOR ; re-load color ; 3
|
||||||
|
and #$0f ; check if bottom nibble zero ; 2
|
||||||
|
bne put_sprite_all ; if not, skip ahead ; 2nt/3
|
||||||
|
lda #$0f ; 2
|
||||||
|
sta MASK ; setup mask ; 3
|
||||||
|
|
||||||
|
put_sprite_mask:
|
||||||
|
lda (OUTL),Y ; get color at output ; 5
|
||||||
|
and MASK ; mask off unneeded part ; 3
|
||||||
|
ora COLOR ; or the color in ; 3
|
||||||
|
sta (OUTL),Y ; store it back ; 5
|
||||||
|
|
||||||
|
jmp put_sprite_done_draw ; we are done ; 3
|
||||||
|
|
||||||
|
put_sprite_all:
|
||||||
|
lda COLOR ; load color ; 3
|
||||||
|
sta (OUTL),Y ; and write it out ; 5
|
||||||
|
|
||||||
|
|
||||||
|
put_sprite_done_draw:
|
||||||
|
|
||||||
|
ldy TEMP ; restore sprite pointer ; 3
|
||||||
|
|
||||||
|
inc OUTL ; increment output pointer ; 5
|
||||||
|
dex ; decrement x counter ; 2
|
||||||
|
bne put_sprite_pixel ; if not done, keep looping ; 2nt/3
|
||||||
|
|
||||||
|
inc TEMPY ; each line has two y vars ; 5
|
||||||
|
inc TEMPY ; 5
|
||||||
|
dec CV ; decemenet total y count ; 5
|
||||||
|
bne put_sprite_loop ; loop if not done ; 2nt/3
|
||||||
|
|
||||||
|
rts ; return ; 6
|
||||||
|
|
||||||
|
|
||||||
|
;================================
|
||||||
|
; htab_vtab
|
||||||
|
;================================
|
||||||
|
; move to CH/CV
|
||||||
|
htab_vtab:
|
||||||
|
lda CV
|
||||||
|
asl
|
||||||
|
tay
|
||||||
|
lda gr_offsets,Y ; lookup low-res memory address
|
||||||
|
clc
|
||||||
|
adc CH ; add in xpos
|
||||||
|
sta BASL ; store out low byte of addy
|
||||||
|
|
||||||
|
lda gr_offsets+1,Y ; look up high byte
|
||||||
|
adc DRAW_PAGE ;
|
||||||
|
sta BASH ; and store it out
|
||||||
|
; BASH:BASL now points at right place
|
||||||
|
|
||||||
|
rts
|
||||||
|
|
||||||
|
;================================
|
||||||
|
; move_and_print
|
||||||
|
;================================
|
||||||
|
; move to CH/CV
|
||||||
|
move_and_print:
|
||||||
|
jsr htab_vtab
|
||||||
|
|
||||||
|
;================================
|
||||||
|
; print_string
|
||||||
|
;================================
|
||||||
|
|
||||||
|
print_string:
|
||||||
|
ldy #0
|
||||||
|
print_string_loop:
|
||||||
|
lda (OUTL),Y
|
||||||
|
beq done_print_string
|
||||||
|
ora #$80
|
||||||
|
sta (BASL),Y
|
||||||
|
iny
|
||||||
|
bne print_string_loop
|
||||||
|
done_print_string:
|
||||||
|
rts
|
||||||
|
|
||||||
|
;====================
|
||||||
|
; point_to_end_string
|
||||||
|
;====================
|
||||||
|
point_to_end_string:
|
||||||
|
iny
|
||||||
|
tya
|
||||||
|
clc
|
||||||
|
adc OUTL
|
||||||
|
sta OUTL
|
||||||
|
lda #0
|
||||||
|
adc OUTH
|
||||||
|
sta OUTH
|
||||||
|
|
||||||
|
rts
|
||||||
|
|
||||||
|
|
||||||
|
;================================
|
||||||
|
; print_both_pages
|
||||||
|
;================================
|
||||||
|
print_both_pages:
|
||||||
|
lda DRAW_PAGE
|
||||||
|
pha
|
||||||
|
|
||||||
|
lda #0
|
||||||
|
sta DRAW_PAGE
|
||||||
|
jsr move_and_print
|
||||||
|
|
||||||
|
lda #4
|
||||||
|
sta DRAW_PAGE
|
||||||
|
jsr move_and_print
|
||||||
|
|
||||||
|
pla
|
||||||
|
sta DRAW_PAGE
|
||||||
|
|
||||||
|
rts ; oops forgot this initially
|
||||||
|
; explains the weird vertical stripes on the screen
|
||||||
|
|
||||||
|
;=========================================
|
||||||
|
; vlin
|
||||||
|
;=========================================
|
||||||
|
; X, V2 at Y
|
||||||
|
vlin:
|
||||||
|
|
||||||
|
sty TEMPY ; save Y (x location)
|
||||||
|
vlin_loop:
|
||||||
|
|
||||||
|
txa ; a=x (get first y)
|
||||||
|
and #$fe ; Clear bottom bit
|
||||||
|
tay ;
|
||||||
|
lda gr_offsets,Y ; lookup low-res memory address low
|
||||||
|
sta GBASL ; put it into our indirect pointer
|
||||||
|
iny
|
||||||
|
lda gr_offsets,Y ; lookup low-res memory address high
|
||||||
|
clc
|
||||||
|
adc DRAW_PAGE ; add in draw page offset
|
||||||
|
sta GBASH ; put into top of indirect
|
||||||
|
|
||||||
|
ldy TEMPY ; load back in y (x offset)
|
||||||
|
|
||||||
|
txa ; load back in x (current y)
|
||||||
|
lsr ; check the low bit
|
||||||
|
bcc vlin_low ; if not set, skip to low
|
||||||
|
|
||||||
|
vlin_high:
|
||||||
|
lda #$F0 ; setup masks
|
||||||
|
sta MASK
|
||||||
|
lda #$0f
|
||||||
|
bcs vlin_too_slow
|
||||||
|
|
||||||
|
vlin_low: ; setup masks
|
||||||
|
lda #$0f
|
||||||
|
sta MASK
|
||||||
|
lda #$f0
|
||||||
|
vlin_too_slow:
|
||||||
|
|
||||||
|
and (GBASL),Y ; mask current byte
|
||||||
|
sta (GBASL),Y ; and store back
|
||||||
|
|
||||||
|
lda MASK ; mask the color
|
||||||
|
and COLOR
|
||||||
|
ora (GBASL),Y ; or into the right place
|
||||||
|
sta (GBASL),Y ; store it
|
||||||
|
|
||||||
|
inx ; increment X (current y)
|
||||||
|
cpx V2 ; compare to the limit
|
||||||
|
bcc vlin_loop ; if <= then loop
|
||||||
|
|
||||||
|
rts ; return
|
||||||
|
|
||||||
|
|
||||||
|
;================================
|
||||||
|
; hlin_setup
|
||||||
|
;================================
|
||||||
|
; put address in GBASL/GBASH
|
||||||
|
; Ycoord in A, Xcoord in Y
|
||||||
|
hlin_setup:
|
||||||
|
sty TEMPY ; 3
|
||||||
|
tay ; y=A ; 2
|
||||||
|
lda gr_offsets,Y ; lookup low-res memory address ; 4
|
||||||
|
clc ; 2
|
||||||
|
adc TEMPY ; 3
|
||||||
|
sta GBASL ; 3
|
||||||
|
iny ; 2
|
||||||
|
|
||||||
|
lda gr_offsets,Y ; 4
|
||||||
|
adc DRAW_PAGE ; add in draw page offset ; 3
|
||||||
|
sta GBASH ; 3
|
||||||
|
rts ; 6
|
||||||
|
;===========
|
||||||
|
; 35
|
||||||
|
;================================
|
||||||
|
; hlin_double:
|
||||||
|
;================================
|
||||||
|
; HLIN Y, V2 AT A
|
||||||
|
; Y, X, A trashed
|
||||||
|
; start at Y, draw up to and including X
|
||||||
|
hlin_double:
|
||||||
|
;int hlin_double(int page, int x1, int x2, int at) {
|
||||||
|
|
||||||
|
jsr hlin_setup ; 41
|
||||||
|
|
||||||
|
sec ; 2
|
||||||
|
lda V2 ; 3
|
||||||
|
sbc TEMPY ; 3
|
||||||
|
|
||||||
|
tax ; 2
|
||||||
|
inx ; 2
|
||||||
|
;===========
|
||||||
|
; 53
|
||||||
|
; fallthrough
|
||||||
|
|
||||||
|
;=================================
|
||||||
|
; hlin_double_continue: width
|
||||||
|
;=================================
|
||||||
|
; width in X
|
||||||
|
|
||||||
|
hlin_double_continue:
|
||||||
|
|
||||||
|
ldy #0 ; 2
|
||||||
|
lda COLOR ; 3
|
||||||
|
hlin_double_loop:
|
||||||
|
sta (GBASL),Y ; 6
|
||||||
|
inc GBASL ; 5
|
||||||
|
dex ; 2
|
||||||
|
bne hlin_double_loop ; 2nt/3
|
||||||
|
|
||||||
|
rts ; 6
|
||||||
|
;=============
|
||||||
|
; 53+5+X*16+5
|
||||||
|
|
||||||
|
;================================
|
||||||
|
; hlin_single:
|
||||||
|
;================================
|
||||||
|
; HLIN Y, V2 AT A
|
||||||
|
; Y, X, A trashed
|
||||||
|
hlin_single:
|
||||||
|
|
||||||
|
jsr hlin_setup
|
||||||
|
|
||||||
|
sec
|
||||||
|
lda V2
|
||||||
|
sbc TEMPY
|
||||||
|
|
||||||
|
tax
|
||||||
|
|
||||||
|
; fallthrough
|
||||||
|
|
||||||
|
;=================================
|
||||||
|
; hlin_single_continue: width
|
||||||
|
;=================================
|
||||||
|
; width in X
|
||||||
|
|
||||||
|
hlin_single_continue:
|
||||||
|
|
||||||
|
hlin_single_top:
|
||||||
|
lda COLOR
|
||||||
|
and #$f0
|
||||||
|
sta COLOR
|
||||||
|
|
||||||
|
hlin_single_top_loop:
|
||||||
|
ldy #0
|
||||||
|
lda (GBASL),Y
|
||||||
|
and #$0f
|
||||||
|
ora COLOR
|
||||||
|
sta (GBASL),Y
|
||||||
|
inc GBASL
|
||||||
|
dex
|
||||||
|
bne hlin_single_top_loop
|
||||||
|
|
||||||
|
rts
|
||||||
|
|
||||||
|
hlin_single_bottom:
|
||||||
|
|
||||||
|
lda COLOR
|
||||||
|
and #$0f
|
||||||
|
sta COLOR
|
||||||
|
|
||||||
|
hlin_single_bottom_loop:
|
||||||
|
ldy #0
|
||||||
|
lda (GBASL),Y
|
||||||
|
and #$f0
|
||||||
|
sta (GBASL),Y
|
||||||
|
inc GBASL
|
||||||
|
dex
|
||||||
|
bne hlin_single_bottom_loop
|
||||||
|
|
||||||
|
rts
|
||||||
|
|
||||||
|
|
||||||
|
;=============================
|
||||||
|
; clear_top
|
||||||
|
;=============================
|
||||||
|
clear_top:
|
||||||
|
lda #$00
|
||||||
|
|
||||||
|
;=============================
|
||||||
|
; clear_top_a
|
||||||
|
;=============================
|
||||||
|
clear_top_a:
|
||||||
|
|
||||||
|
sta COLOR
|
||||||
|
|
||||||
|
; VLIN Y, V2 AT A
|
||||||
|
|
||||||
|
lda #40
|
||||||
|
sta V2
|
||||||
|
|
||||||
|
lda #0
|
||||||
|
|
||||||
|
clear_top_loop:
|
||||||
|
ldy #0
|
||||||
|
pha
|
||||||
|
|
||||||
|
jsr hlin_double
|
||||||
|
|
||||||
|
pla
|
||||||
|
clc
|
||||||
|
adc #$2
|
||||||
|
cmp #40
|
||||||
|
bne clear_top_loop
|
||||||
|
|
||||||
|
rts
|
||||||
|
|
||||||
|
clear_bottom:
|
||||||
|
lda #$a0 ; NORMAL space
|
||||||
|
sta COLOR
|
||||||
|
|
||||||
|
lda #40
|
||||||
|
sta V2
|
||||||
|
|
||||||
|
clear_bottom_loop:
|
||||||
|
ldy #0
|
||||||
|
pha
|
||||||
|
|
||||||
|
jsr hlin_double
|
||||||
|
|
||||||
|
pla
|
||||||
|
clc
|
||||||
|
adc #$2
|
||||||
|
cmp #48
|
||||||
|
bne clear_bottom_loop
|
||||||
|
|
||||||
|
rts
|
||||||
194
dlowres_mode7/dlowres_zp.inc
Normal file
194
dlowres_mode7/dlowres_zp.inc
Normal file
@ -0,0 +1,194 @@
|
|||||||
|
.define EQU =
|
||||||
|
|
||||||
|
;; Zero page monitor routines addresses
|
||||||
|
|
||||||
|
WNDLFT EQU $20
|
||||||
|
WNDWDTH EQU $21
|
||||||
|
WNDTOP EQU $22
|
||||||
|
WNDBTM EQU $23
|
||||||
|
CH EQU $24
|
||||||
|
CV EQU $25
|
||||||
|
GBASL EQU $26
|
||||||
|
GBASH EQU $27
|
||||||
|
BASL EQU $28
|
||||||
|
BASH EQU $29
|
||||||
|
H2 EQU $2C
|
||||||
|
V2 EQU $2D
|
||||||
|
MASK EQU $2E
|
||||||
|
COLOR EQU $30
|
||||||
|
INVFLG EQU $32
|
||||||
|
|
||||||
|
; More zero-page addresses
|
||||||
|
; we try not to conflict with anything DOS, MONITOR or BASIC related
|
||||||
|
|
||||||
|
COLOR1 EQU $E0
|
||||||
|
COLOR2 EQU $E1
|
||||||
|
MATCH EQU $E2
|
||||||
|
XX EQU $E3
|
||||||
|
YY EQU $E4
|
||||||
|
YADD EQU $E5
|
||||||
|
LOOP EQU $E6
|
||||||
|
MEMPTRL EQU $E7
|
||||||
|
MEMPTRH EQU $E8
|
||||||
|
NAMEL EQU $E9
|
||||||
|
NAMEH EQU $EA
|
||||||
|
NAMEX EQU $EB
|
||||||
|
CHAR EQU $EC
|
||||||
|
DISP_PAGE EQU $ED
|
||||||
|
DRAW_PAGE EQU $EE
|
||||||
|
|
||||||
|
FIRST EQU $F0
|
||||||
|
LASTKEY EQU $F1
|
||||||
|
PADDLE_STATUS EQU $F2
|
||||||
|
XPOS EQU $F3
|
||||||
|
YPOS EQU $F4
|
||||||
|
TEMP EQU $FA
|
||||||
|
RUN EQU $FA
|
||||||
|
TEMP2 EQU $FB
|
||||||
|
TEMPY EQU $FB
|
||||||
|
INL EQU $FC
|
||||||
|
INH EQU $FD
|
||||||
|
OUTL EQU $FE
|
||||||
|
OUTH EQU $FF
|
||||||
|
|
||||||
|
|
||||||
|
;; Flying Routine Only
|
||||||
|
|
||||||
|
TURNING EQU $60
|
||||||
|
;SCREEN_X EQU $61 ; not used?
|
||||||
|
SCREEN_Y EQU $62
|
||||||
|
ANGLE EQU $63
|
||||||
|
HORIZ_SCALE_I EQU $64
|
||||||
|
HORIZ_SCALE_F EQU $65
|
||||||
|
FACTOR_I EQU $66
|
||||||
|
FACTOR_F EQU $67
|
||||||
|
DX_I EQU $68
|
||||||
|
DX_F EQU $69
|
||||||
|
SPACEX_I EQU $6A
|
||||||
|
SPACEX_F EQU $6B
|
||||||
|
CX_I EQU $6C
|
||||||
|
CX_F EQU $6D
|
||||||
|
DY_I EQU $6E
|
||||||
|
DY_F EQU $6F
|
||||||
|
SPACEY_I EQU $70
|
||||||
|
SPACEY_F EQU $71
|
||||||
|
CY_I EQU $72
|
||||||
|
CY_F EQU $73
|
||||||
|
TEMP_I EQU $74
|
||||||
|
TEMP_F EQU $75
|
||||||
|
DISTANCE_I EQU $76
|
||||||
|
DISTANCE_F EQU $77
|
||||||
|
SPACEZ_I EQU $78
|
||||||
|
SPACEZ_F EQU $79
|
||||||
|
DRAW_SPLASH EQU $7A
|
||||||
|
SPEED EQU $7B
|
||||||
|
SPLASH_COUNT EQU $7C
|
||||||
|
OVER_LAND EQU $7D
|
||||||
|
NUM1L EQU $7E
|
||||||
|
NUM1H EQU $7F
|
||||||
|
NUM2L EQU $80
|
||||||
|
NUM2H EQU $81
|
||||||
|
RESULT EQU $82 ; 83,84,85
|
||||||
|
NEGATE EQU $86 ; UNUSED?
|
||||||
|
LAST_SPACEX_I EQU $87
|
||||||
|
LAST_SPACEY_I EQU $88
|
||||||
|
LAST_MAP_COLOR EQU $89
|
||||||
|
DRAW_SKY EQU $8A
|
||||||
|
COLOR_MASK EQU $8B
|
||||||
|
|
||||||
|
SHIPY EQU $E4
|
||||||
|
|
||||||
|
;; World Map Only
|
||||||
|
|
||||||
|
ODD EQU $7B
|
||||||
|
DIRECTION EQU $7C
|
||||||
|
REFRESH EQU $7D
|
||||||
|
ON_BIRD EQU $7E
|
||||||
|
MOVED EQU $7F
|
||||||
|
STEPS EQU $80
|
||||||
|
TFV_X EQU $81
|
||||||
|
TFV_Y EQU $82
|
||||||
|
NEWX EQU $83
|
||||||
|
NEWY EQU $84
|
||||||
|
MAP_X EQU $85
|
||||||
|
GROUND_COLOR EQU $86
|
||||||
|
|
||||||
|
|
||||||
|
|
||||||
|
|
||||||
|
KEYPRESS EQU $C000
|
||||||
|
KEYRESET EQU $C010
|
||||||
|
|
||||||
|
;; SOFT SWITCHES
|
||||||
|
EIGHTYSTORE_ON EQU $C000
|
||||||
|
EIGHTYSTORE_OFF EQU $C001
|
||||||
|
EIGHTYCOL EQU $C00D
|
||||||
|
SET_GR EQU $C050
|
||||||
|
SET_TEXT EQU $C051
|
||||||
|
FULLGR EQU $C052
|
||||||
|
TEXTGR EQU $C053
|
||||||
|
PAGE0 EQU $C054
|
||||||
|
PAGE1 EQU $C055
|
||||||
|
LORES EQU $C056
|
||||||
|
HIRES EQU $C057
|
||||||
|
AN3 EQU $C05E
|
||||||
|
|
||||||
|
PADDLE_BUTTON0 EQU $C061
|
||||||
|
PADDL0 EQU $C064
|
||||||
|
PTRIG EQU $C070
|
||||||
|
|
||||||
|
;; BASIC ROUTINES
|
||||||
|
|
||||||
|
NORMAL EQU $F273
|
||||||
|
|
||||||
|
;; MONITOR ROUTINES
|
||||||
|
|
||||||
|
HLINE EQU $F819 ;; HLINE Y,$2C at A
|
||||||
|
VLINE EQU $F828 ;; VLINE A,$2D at Y
|
||||||
|
CLRSCR EQU $F832 ;; Clear low-res screen
|
||||||
|
CLRTOP EQU $F836 ;; clear only top of low-res screen
|
||||||
|
SETCOL EQU $F864 ;; COLOR=A
|
||||||
|
TEXT EQU $FB36
|
||||||
|
TABV EQU $FB5B ;; VTAB to A
|
||||||
|
BASCALC EQU $FBC1 ;;
|
||||||
|
VTAB EQU $FC22 ;; VTAB to CV
|
||||||
|
HOME EQU $FC58 ;; Clear the text screen
|
||||||
|
WAIT EQU $FCA8 ;; delay 1/2(26+27A+5A^2) us
|
||||||
|
SETINV EQU $FE80 ;; INVERSE
|
||||||
|
SETNORM EQU $FE84 ;; NORMAL
|
||||||
|
COUT EQU $FDED ;; output A to screen
|
||||||
|
COUT1 EQU $FDF0 ;; output A to screen
|
||||||
|
|
||||||
|
|
||||||
|
|
||||||
|
|
||||||
|
|
||||||
|
|
||||||
|
COLOR_BLACK EQU 0
|
||||||
|
COLOR_RED EQU 1
|
||||||
|
COLOR_DARKBLUE EQU 2
|
||||||
|
COLOR_PURPLE EQU 3
|
||||||
|
COLOR_DARKGREEN EQU 4
|
||||||
|
COLOR_GREY EQU 5
|
||||||
|
COLOR_MEDIUMBLUE EQU 6
|
||||||
|
COLOR_LIGHTBLUE EQU 7
|
||||||
|
COLOR_BROWN EQU 8
|
||||||
|
COLOR_ORANGE EQU 9
|
||||||
|
COLOR_GREY2 EQU 10
|
||||||
|
COLOR_PINK EQU 11
|
||||||
|
COLOR_LIGHTGREEN EQU 12
|
||||||
|
COLOR_YELLOW EQU 13
|
||||||
|
COLOR_AQUA EQU 14
|
||||||
|
COLOR_WHITE EQU 15
|
||||||
|
|
||||||
|
COLOR_BOTH_RED EQU $11
|
||||||
|
COLOR_BOTH_DARKBLUE EQU $22
|
||||||
|
COLOR_BOTH_DARKGREEN EQU $44
|
||||||
|
COLOR_BOTH_GREY EQU $55
|
||||||
|
COLOR_BOTH_MEDIUMBLUE EQU $66
|
||||||
|
COLOR_BOTH_LIGHTBLUE EQU $77
|
||||||
|
COLOR_BOTH_BROWN EQU $88
|
||||||
|
COLOR_BOTH_ORANGE EQU $99
|
||||||
|
COLOR_BOTH_LIGHTGREEN EQU $CC
|
||||||
|
COLOR_BOTH_YELLOW EQU $DD
|
||||||
|
COLOR_BOTH_WHITE EQU $FF
|
||||||
349
dlowres_mode7/fast_multiply.s
Normal file
349
dlowres_mode7/fast_multiply.s
Normal file
@ -0,0 +1,349 @@
|
|||||||
|
; Fast mutiply
|
||||||
|
|
||||||
|
|
||||||
|
; Note for our purposes we only care about 8.8 x 8.8 fixed point
|
||||||
|
; with 8.8 result, which means we only care about the middle two bytes
|
||||||
|
; of the 32 bit result. So we disable generation of the high and low byte
|
||||||
|
; to save some cycles.
|
||||||
|
|
||||||
|
;
|
||||||
|
; The old routine took around 700 cycles for a 16bitx16bit=32bit mutiply
|
||||||
|
; This routine, at an expense of 2kB of looku tables, takes around 250
|
||||||
|
; If you reuse a term the next time this drops closer to 200
|
||||||
|
|
||||||
|
; This routine was described by Stephen Judd and found
|
||||||
|
; in The Fridge and in the C=Hacking magazine
|
||||||
|
; http://codebase64.org/doku.php?id=base:seriously_fast_multiplication
|
||||||
|
|
||||||
|
; The key thing to note is that
|
||||||
|
; (a+b)^2 (a-b)^2
|
||||||
|
; a*b = ------- - --------
|
||||||
|
; 4 4
|
||||||
|
; So if you have tables of the squares of 0..511 you can lookup and subtract
|
||||||
|
; instead of multiplying.
|
||||||
|
|
||||||
|
; Table generation: I:0..511
|
||||||
|
; square1_lo = <((I*I)/4)
|
||||||
|
; square1_hi = >((I*I)/4)
|
||||||
|
; square2_lo = <(((I-255)*(I-255))/4)
|
||||||
|
; square2_hi = >(((I-255)*(I-255))/4)
|
||||||
|
|
||||||
|
; Note: DOS3.3 starts at $9600
|
||||||
|
|
||||||
|
square1_lo EQU $8E00
|
||||||
|
square1_hi EQU $9000
|
||||||
|
square2_lo EQU $9200
|
||||||
|
square2_hi EQU $9400
|
||||||
|
|
||||||
|
; for(i=0;i<512;i++) {
|
||||||
|
; square1_lo[i]=((i*i)/4)&0xff;
|
||||||
|
; square1_hi[i]=(((i*i)/4)>>8)&0xff;
|
||||||
|
; square2_lo[i]=( ((i-255)*(i-255))/4)&0xff;
|
||||||
|
; square2_hi[i]=(( ((i-255)*(i-255))/4)>>8)&0xff;
|
||||||
|
; }
|
||||||
|
|
||||||
|
init_multiply_tables:
|
||||||
|
|
||||||
|
; Build the add tables
|
||||||
|
|
||||||
|
ldx #$00
|
||||||
|
txa
|
||||||
|
.byte $c9 ; CMP #immediate - skip TYA and clear carry flag
|
||||||
|
lb1: tya
|
||||||
|
adc #$00 ; 0
|
||||||
|
ml1: sta square1_hi,x ; square1_hi[0]=0
|
||||||
|
tay ; y=0
|
||||||
|
cmp #$40 ; subtract 64 and update flags (c=0)
|
||||||
|
txa ; a=0
|
||||||
|
ror ; rotate
|
||||||
|
ml9: adc #$00 ; add 0
|
||||||
|
sta ml9+1 ; update add value
|
||||||
|
inx ; x=1
|
||||||
|
ml0: sta square1_lo,x ; square1_lo[0]=1
|
||||||
|
bne lb1 ; if not zero, loop
|
||||||
|
inc ml0+2 ; increment values
|
||||||
|
inc ml1+2 ; increment values
|
||||||
|
clc ; c=0
|
||||||
|
iny ; y=1
|
||||||
|
bne lb1 ; loop
|
||||||
|
|
||||||
|
; Build the subtract tables based on the existing one
|
||||||
|
|
||||||
|
ldx #$00
|
||||||
|
ldy #$ff
|
||||||
|
second_table:
|
||||||
|
lda square1_hi+1,x
|
||||||
|
sta square2_hi+$100,x
|
||||||
|
lda square1_hi,x
|
||||||
|
sta square2_hi,y
|
||||||
|
lda square1_lo+1,x
|
||||||
|
sta square2_lo+$100,x
|
||||||
|
lda square1_lo,x
|
||||||
|
sta square2_lo,y
|
||||||
|
dey
|
||||||
|
inx
|
||||||
|
bne second_table
|
||||||
|
|
||||||
|
|
||||||
|
rts
|
||||||
|
|
||||||
|
|
||||||
|
; Fast 16x16 bit unsigned multiplication, 32-bit result
|
||||||
|
; Input: NUM1H:NUM1L * NUM2H:NUM2L
|
||||||
|
; Result: RESULT3:RESULT2:RESULT1:RESULT0
|
||||||
|
;
|
||||||
|
; Does self-modifying code to hard-code NUM1H:NUM1L into the code
|
||||||
|
; carry=0: re-use previous NUM1H:NUM1L
|
||||||
|
; carry=1: reload NUM1H:NUM1L (58 cycles slower)
|
||||||
|
;
|
||||||
|
; clobbered: RESULT, X, A, C
|
||||||
|
; Allocation setup: T1,T2 and RESULT preferably on Zero-page.
|
||||||
|
;
|
||||||
|
; NUM1H (x_i), NUM1L (x_f)
|
||||||
|
; NUM2H (y_i), NUM2L (y_f)
|
||||||
|
|
||||||
|
; NUM1L * NUM2L = AAaa
|
||||||
|
; NUM1L * NUM2H = BBbb
|
||||||
|
; NUM1H * NUM2L = CCcc
|
||||||
|
; NUM1H * NUM2H = DDdd
|
||||||
|
;
|
||||||
|
; AAaa
|
||||||
|
; BBbb
|
||||||
|
; CCcc
|
||||||
|
; + DDdd
|
||||||
|
; ----------
|
||||||
|
; RESULT
|
||||||
|
|
||||||
|
;fixed_16x16_mul_unsigned:
|
||||||
|
|
||||||
|
multiply:
|
||||||
|
|
||||||
|
bcc num1_same_as_last_time ; 2nt/3
|
||||||
|
|
||||||
|
;============================
|
||||||
|
; Set up self-modifying code
|
||||||
|
; this changes the code to be hard-coded to multiply by NUM1H:NUM1L
|
||||||
|
;============================
|
||||||
|
|
||||||
|
lda NUM1L ; load the low byte ; 3
|
||||||
|
sta sm1a+1 ; 3
|
||||||
|
sta sm3a+1 ; 3
|
||||||
|
sta sm5a+1 ; 3
|
||||||
|
sta sm7a+1 ; 3
|
||||||
|
eor #$ff ; invert the bits for subtracting ; 2
|
||||||
|
sta sm2a+1 ; 3
|
||||||
|
sta sm4a+1 ; 3
|
||||||
|
sta sm6a+1 ; 3
|
||||||
|
sta sm8a+1 ; 3
|
||||||
|
lda NUM1H ; load the high byte ; 3
|
||||||
|
sta sm1b+1 ; 3
|
||||||
|
sta sm3b+1 ; 3
|
||||||
|
sta sm5b+1 ; 3
|
||||||
|
; sta sm7b+1 ;
|
||||||
|
eor #$ff ; invert the bits for subtractin ; 2
|
||||||
|
sta sm2b+1 ; 3
|
||||||
|
sta sm4b+1 ; 3
|
||||||
|
sta sm6b+1 ; 3
|
||||||
|
; sta sm8b+1 ;
|
||||||
|
;===========
|
||||||
|
; 52
|
||||||
|
|
||||||
|
num1_same_as_last_time:
|
||||||
|
|
||||||
|
;==========================
|
||||||
|
; Perform NUM1L * NUM2L = AAaa
|
||||||
|
;==========================
|
||||||
|
|
||||||
|
ldx NUM2L ; (low le) ; 3
|
||||||
|
sec ; 2
|
||||||
|
sm1a:
|
||||||
|
lda square1_lo,x ; 4
|
||||||
|
sm2a:
|
||||||
|
sbc square2_lo,x ; 4
|
||||||
|
|
||||||
|
; a is _aa
|
||||||
|
|
||||||
|
; sta RESULT+0 ;
|
||||||
|
|
||||||
|
sm3a:
|
||||||
|
lda square1_hi,x ; 4
|
||||||
|
sm4a:
|
||||||
|
sbc square2_hi,x ; 4
|
||||||
|
; a is _AA
|
||||||
|
sta _AA+1 ; 3
|
||||||
|
;===========
|
||||||
|
; 24
|
||||||
|
|
||||||
|
; Perform NUM1H * NUM2L = CCcc
|
||||||
|
sec ; 2
|
||||||
|
sm1b:
|
||||||
|
lda square1_lo,x ; 4
|
||||||
|
sm2b:
|
||||||
|
sbc square2_lo,x ; 4
|
||||||
|
; a is _cc
|
||||||
|
sta _cc+1 ; 3
|
||||||
|
sm3b:
|
||||||
|
lda square1_hi,x ; 4
|
||||||
|
sm4b:
|
||||||
|
sbc square2_hi,x ; 4
|
||||||
|
; a is _CC
|
||||||
|
sta _CC+1 ; 3
|
||||||
|
;===========
|
||||||
|
; 24
|
||||||
|
|
||||||
|
;==========================
|
||||||
|
; Perform NUM1L * NUM2H = BBbb
|
||||||
|
;==========================
|
||||||
|
ldx NUM2H ; 3
|
||||||
|
sec ; 2
|
||||||
|
sm5a:
|
||||||
|
lda square1_lo,x ; 4
|
||||||
|
sm6a:
|
||||||
|
sbc square2_lo,x ; 4
|
||||||
|
; a is _bb
|
||||||
|
sta _bb+1 ; 3
|
||||||
|
|
||||||
|
sm7a:
|
||||||
|
lda square1_hi,x ; 4
|
||||||
|
sm8a:
|
||||||
|
sbc square2_hi,x ; 4
|
||||||
|
; a is _BB
|
||||||
|
sta _BB+1 ; 3
|
||||||
|
;===========
|
||||||
|
; 27
|
||||||
|
|
||||||
|
;==========================
|
||||||
|
; Perform NUM1H * NUM2H = DDdd
|
||||||
|
;==========================
|
||||||
|
sec ; 2
|
||||||
|
sm5b:
|
||||||
|
lda square1_lo,x ; 4
|
||||||
|
sm6b:
|
||||||
|
sbc square2_lo,x ; 4
|
||||||
|
; a is _dd
|
||||||
|
sta _dd+1 ; 3
|
||||||
|
;sm7b:
|
||||||
|
; lda square1_hi,x ;
|
||||||
|
;sm8b:
|
||||||
|
; sbc square2_hi,x ;
|
||||||
|
; a = _DD
|
||||||
|
; sta RESULT+3 ;
|
||||||
|
;===========
|
||||||
|
; 13
|
||||||
|
|
||||||
|
;===========================================
|
||||||
|
; Add the separate multiplications together
|
||||||
|
;===========================================
|
||||||
|
|
||||||
|
clc ; 2
|
||||||
|
_AA:
|
||||||
|
lda #0 ; loading _AA ; 2
|
||||||
|
_bb:
|
||||||
|
adc #0 ; adding in _bb ; 2
|
||||||
|
sta RESULT+1 ; 3
|
||||||
|
;==========
|
||||||
|
; 9
|
||||||
|
; product[2]=_BB+_CC+c
|
||||||
|
|
||||||
|
_BB:
|
||||||
|
lda #0 ; loading _BB ; 2
|
||||||
|
_CC:
|
||||||
|
adc #0 ; adding in _CC ; 2
|
||||||
|
sta RESULT+2 ; 3
|
||||||
|
;===========
|
||||||
|
; 7
|
||||||
|
|
||||||
|
; product[3]=_DD+c
|
||||||
|
|
||||||
|
; bcc dd_no_carry1 ;
|
||||||
|
; inc RESULT+3 ;
|
||||||
|
clc ; 2
|
||||||
|
;=============
|
||||||
|
; 2
|
||||||
|
dd_no_carry1:
|
||||||
|
|
||||||
|
; product[1]=_AA+_bb+_cc
|
||||||
|
|
||||||
|
_cc:
|
||||||
|
lda #0 ; load _cc ; 2
|
||||||
|
adc RESULT+1 ; 3
|
||||||
|
sta RESULT+1 ; 3
|
||||||
|
|
||||||
|
; product[2]=_BB+_CC+_dd+c
|
||||||
|
|
||||||
|
_dd:
|
||||||
|
lda #0 ; load _dd ; 2
|
||||||
|
adc RESULT+2 ; 3
|
||||||
|
sta RESULT+2 ; 3
|
||||||
|
|
||||||
|
;===========
|
||||||
|
; 16
|
||||||
|
; product[3]=_DD+c
|
||||||
|
|
||||||
|
|
||||||
|
; bcc dd_no_carry2 ;
|
||||||
|
; inc RESULT+3 ;
|
||||||
|
|
||||||
|
;=============
|
||||||
|
; 0
|
||||||
|
|
||||||
|
dd_no_carry2:
|
||||||
|
|
||||||
|
; *z_i=product[1];
|
||||||
|
; *z_f=product[0];
|
||||||
|
|
||||||
|
; rts ; 6
|
||||||
|
|
||||||
|
|
||||||
|
;=================
|
||||||
|
; Signed multiply
|
||||||
|
;=================
|
||||||
|
|
||||||
|
;multiply:
|
||||||
|
|
||||||
|
; jsr fixed_16x16_mul_unsigned ; 6
|
||||||
|
|
||||||
|
lda NUM1H ; x_i ; 3
|
||||||
|
;===========
|
||||||
|
; 12
|
||||||
|
|
||||||
|
|
||||||
|
bpl x_positive ;^3/2nt
|
||||||
|
|
||||||
|
sec ; 2
|
||||||
|
lda RESULT+2 ; 3
|
||||||
|
sbc NUM2L ; 3
|
||||||
|
sta RESULT+2 ; 3
|
||||||
|
; lda RESULT+3 ;
|
||||||
|
; sbc NUM2H ;
|
||||||
|
; sta RESULT+3 ;
|
||||||
|
;============
|
||||||
|
; 10
|
||||||
|
|
||||||
|
x_positive:
|
||||||
|
|
||||||
|
lda NUM2H ; y_i ; 3
|
||||||
|
;============
|
||||||
|
; ; 6
|
||||||
|
|
||||||
|
bpl y_positive ;^3/2nt
|
||||||
|
|
||||||
|
|
||||||
|
sec ; 2
|
||||||
|
lda RESULT+2 ; 3
|
||||||
|
sbc NUM1L ; 3
|
||||||
|
sta RESULT+2 ; 3
|
||||||
|
; lda RESULT+3 ;
|
||||||
|
; sbc NUM1H ;
|
||||||
|
; sta RESULT+3 ;
|
||||||
|
;===========
|
||||||
|
; 10
|
||||||
|
|
||||||
|
y_positive:
|
||||||
|
ldx RESULT+2 ; *z_i=product[2]; ; 3
|
||||||
|
lda RESULT+1 ; *z_f=product[1]; ; 3
|
||||||
|
|
||||||
|
rts ; 6
|
||||||
|
;==========
|
||||||
|
; 12
|
||||||
|
|
||||||
Loading…
Reference in New Issue
Block a user