mirror of
https://github.com/deater/dos33fsprogs.git
synced 2024-11-01 01:06:33 +00:00
compression: doing some tests
This commit is contained in:
Vince Weaver
parent
4305eedcd2
commit
6f6e36b231
50
compression/comparison/Makefile
Normal file
50
compression/comparison/Makefile
Normal file
@ -0,0 +1,50 @@
|
|||||||
|
PNG2RLE = ../../utils/gr-utils/png2rle
|
||||||
|
PNG2GR = ../../utils/gr-utils/png2gr
|
||||||
|
PNG2HGR = ../../utils/hgr-utils/png2hgr
|
||||||
|
LZSA = ~/research/lzsa/lzsa/lzsa
|
||||||
|
B2D = ../../utils/bmp2dhr/b2d
|
||||||
|
|
||||||
|
DOS33 = ../../utils/dos33fs-utils/dos33
|
||||||
|
TOKENIZE = ../../utils/asoft_basic-utils/tokenize_asoft
|
||||||
|
EMPTYDISK = ../../empty_disk/empty.dsk
|
||||||
|
LINKERSCRIPTS = ../../linker_scripts/
|
||||||
|
|
||||||
|
|
||||||
|
|
||||||
|
all: compression_test.dsk
|
||||||
|
|
||||||
|
compression_test.dsk: HELLO LZSA_TEST
|
||||||
|
cp $(EMPTYDISK) compression_test.dsk
|
||||||
|
$(DOS33) -y compression_test.dsk SAVE A HELLO
|
||||||
|
$(DOS33) -y compression_test.dsk BSAVE -a 0x6000 LZSA_TEST
|
||||||
|
|
||||||
|
|
||||||
|
####
|
||||||
|
|
||||||
|
HELLO: hello.bas
|
||||||
|
$(TOKENIZE) < hello.bas > HELLO
|
||||||
|
|
||||||
|
###
|
||||||
|
|
||||||
|
LZSA_TEST: lzsa_test.o
|
||||||
|
ld65 -o LZSA_TEST lzsa_test.o -C $(LINKERSCRIPTS)/apple2_6000.inc
|
||||||
|
|
||||||
|
lzsa_test.o: lzsa_test.s graphics_level5.inc
|
||||||
|
ca65 -o lzsa_test.o lzsa_test.s -l lzsa_test.lst
|
||||||
|
|
||||||
|
###
|
||||||
|
|
||||||
|
graphics_level5.inc: level5.lzsa
|
||||||
|
echo "level5_lzsa: .incbin \"level5.lzsa\"" > graphics_level5.inc
|
||||||
|
|
||||||
|
###
|
||||||
|
|
||||||
|
level5.lzsa: level5.hgr
|
||||||
|
$(LZSA) -r -f2 level5.hgr level5.lzsa
|
||||||
|
|
||||||
|
level5.hgr: level5.png
|
||||||
|
$(PNG2HGR) level5.png > level5.hgr
|
||||||
|
|
||||||
|
|
||||||
|
clean:
|
||||||
|
rm -f HELLO LZSA_TEST *~ *.o *.lst level5.lzsa
|
||||||
370
compression/comparison/decompress_fast_v2.s
Normal file
370
compression/comparison/decompress_fast_v2.s
Normal file
@ -0,0 +1,370 @@
|
|||||||
|
; note -- modified by Vince Weaver to assemble with ca65
|
||||||
|
; in this case, A = page to decompress to
|
||||||
|
; getsrc_smc+1, getsrc_smc+2 is src location
|
||||||
|
|
||||||
|
; -----------------------------------------------------------------------------
|
||||||
|
; Decompress raw LZSA2 block.
|
||||||
|
; Create one with lzsa -r -f2 <original_file> <compressed_file>
|
||||||
|
;
|
||||||
|
; in:
|
||||||
|
; * LZSA_SRC_LO and LZSA_SRC_HI contain the compressed raw block address
|
||||||
|
; * LZSA_DST_LO and LZSA_DST_HI contain the destination buffer address
|
||||||
|
;
|
||||||
|
; out:
|
||||||
|
; * LZSA_DST_LO and LZSA_DST_HI contain the last decompressed byte address, +1
|
||||||
|
;
|
||||||
|
; -----------------------------------------------------------------------------
|
||||||
|
; Backward decompression is also supported, use lzsa -r -b -f2 <original_file> <compressed_file>
|
||||||
|
; To use it, also define BACKWARD_DECOMPRESS=1 before including this code!
|
||||||
|
;
|
||||||
|
; in:
|
||||||
|
; * LZSA_SRC_LO/LZSA_SRC_HI must contain the address of the last byte of compressed data
|
||||||
|
; * LZSA_DST_LO/LZSA_DST_HI must contain the address of the last byte of the destination buffer
|
||||||
|
;
|
||||||
|
; out:
|
||||||
|
; * LZSA_DST_LO/LZSA_DST_HI contain the last decompressed byte address, -1
|
||||||
|
;
|
||||||
|
; -----------------------------------------------------------------------------
|
||||||
|
;
|
||||||
|
; Copyright (C) 2019 Emmanuel Marty, Peter Ferrie
|
||||||
|
;
|
||||||
|
; This software is provided 'as-is', without any express or implied
|
||||||
|
; warranty. In no event will the authors be held liable for any damages
|
||||||
|
; arising from the use of this software.
|
||||||
|
;
|
||||||
|
; Permission is granted to anyone to use this software for any purpose,
|
||||||
|
; including commercial applications, and to alter it and redistribute it
|
||||||
|
; freely, subject to the following restrictions:
|
||||||
|
;
|
||||||
|
; 1. The origin of this software must not be misrepresented; you must not
|
||||||
|
; claim that you wrote the original software. If you use this software
|
||||||
|
; in a product, an acknowledgment in the product documentation would be
|
||||||
|
; appreciated but is not required.
|
||||||
|
; 2. Altered source versions must be plainly marked as such, and must not be
|
||||||
|
; misrepresented as being the original software.
|
||||||
|
; 3. This notice may not be removed or altered from any source distribution.
|
||||||
|
; -----------------------------------------------------------------------------
|
||||||
|
|
||||||
|
;NIBCOUNT = $FC ; zero-page location for temp offset
|
||||||
|
|
||||||
|
decompress_lzsa2_fast:
|
||||||
|
|
||||||
|
sta LZSA_DST_HI
|
||||||
|
|
||||||
|
ldy #$00
|
||||||
|
sty LZSA_DST_LO
|
||||||
|
sty NIBCOUNT
|
||||||
|
|
||||||
|
decode_token:
|
||||||
|
jsr getsrc ; read token byte: XYZ|LL|MMM
|
||||||
|
pha ; preserve token on stack
|
||||||
|
|
||||||
|
and #$18 ; isolate literals count (LL)
|
||||||
|
beq no_literals ; skip if no literals to copy
|
||||||
|
cmp #$18 ; LITERALS_RUN_LEN_V2?
|
||||||
|
bcc prepare_copy_literals ; if less, count is directly embedded in token
|
||||||
|
|
||||||
|
jsr getnibble ; get extra literals length nibble
|
||||||
|
; add nibble to len from token
|
||||||
|
adc #$02 ; (LITERALS_RUN_LEN_V2) minus carry
|
||||||
|
cmp #$12 ; LITERALS_RUN_LEN_V2 + 15 ?
|
||||||
|
bcc prepare_copy_literals_direct ; if less, literals count is complete
|
||||||
|
|
||||||
|
jsr getsrc ; get extra byte of variable literals count
|
||||||
|
; the carry is always set by the CMP above
|
||||||
|
; GETSRC doesn't change it
|
||||||
|
sbc #$EE ; overflow?
|
||||||
|
jmp prepare_copy_literals_direct
|
||||||
|
|
||||||
|
prepare_copy_literals_large:
|
||||||
|
; handle 16 bits literals count
|
||||||
|
; literals count = directly these 16 bits
|
||||||
|
jsr getlargesrc ; grab low 8 bits in X, high 8 bits in A
|
||||||
|
tay ; put high 8 bits in Y
|
||||||
|
bcs prepare_copy_literals_high ; (*same as JMP PREPARE_COPY_LITERALS_HIGH but shorter)
|
||||||
|
|
||||||
|
prepare_copy_literals:
|
||||||
|
lsr ; shift literals count into place
|
||||||
|
lsr
|
||||||
|
lsr
|
||||||
|
|
||||||
|
prepare_copy_literals_direct:
|
||||||
|
tax
|
||||||
|
bcs prepare_copy_literals_large ; if so, literals count is large
|
||||||
|
|
||||||
|
prepare_copy_literals_high:
|
||||||
|
txa
|
||||||
|
beq copy_literals
|
||||||
|
iny
|
||||||
|
|
||||||
|
copy_literals:
|
||||||
|
jsr getput ; copy one byte of literals
|
||||||
|
dex
|
||||||
|
bne copy_literals
|
||||||
|
dey
|
||||||
|
bne copy_literals
|
||||||
|
|
||||||
|
no_literals:
|
||||||
|
pla ; retrieve token from stack
|
||||||
|
pha ; preserve token again
|
||||||
|
asl
|
||||||
|
bcs repmatch_or_large_offset ; 1YZ: rep-match or 13/16 bit offset
|
||||||
|
|
||||||
|
asl ; 0YZ: 5 or 9 bit offset
|
||||||
|
bcs offset_9_bit
|
||||||
|
|
||||||
|
; 00Z: 5 bit offset
|
||||||
|
|
||||||
|
ldx #$FF ; set offset bits 15-8 to 1
|
||||||
|
|
||||||
|
jsr getcombinedbits ; rotate Z bit into bit 0, read nibble for bits 4-1
|
||||||
|
ora #$E0 ; set bits 7-5 to 1
|
||||||
|
bne got_offset_lo ; go store low byte of match offset and prepare match
|
||||||
|
|
||||||
|
offset_9_bit: ; 01Z: 9 bit offset
|
||||||
|
;;asl ; shift Z (offset bit 8) in place
|
||||||
|
rol
|
||||||
|
rol
|
||||||
|
and #$01
|
||||||
|
eor #$FF ; set offset bits 15-9 to 1
|
||||||
|
bne got_offset_hi ; go store high byte, read low byte of match offset and prepare match
|
||||||
|
; (*same as JMP GOT_OFFSET_HI but shorter)
|
||||||
|
|
||||||
|
repmatch_or_large_offset:
|
||||||
|
asl ; 13 bit offset?
|
||||||
|
bcs repmatch_or_16bit ; handle rep-match or 16-bit offset if not
|
||||||
|
|
||||||
|
; 10Z: 13 bit offset
|
||||||
|
|
||||||
|
jsr getcombinedbits ; rotate Z bit into bit 8, read nibble for bits 12-9
|
||||||
|
adc #$DE ; set bits 15-13 to 1 and substract 2 (to substract 512)
|
||||||
|
bne got_offset_hi ; go store high byte, read low byte of match offset and prepare match
|
||||||
|
; (*same as JMP GOT_OFFSET_HI but shorter)
|
||||||
|
|
||||||
|
repmatch_or_16bit: ; rep-match or 16 bit offset
|
||||||
|
;;ASL ; XYZ=111?
|
||||||
|
bmi rep_match ; reuse previous offset if so (rep-match)
|
||||||
|
|
||||||
|
; 110: handle 16 bit offset
|
||||||
|
jsr getsrc ; grab high 8 bits
|
||||||
|
got_offset_hi:
|
||||||
|
tax
|
||||||
|
jsr getsrc ; grab low 8 bits
|
||||||
|
got_offset_lo:
|
||||||
|
sta OFFSLO ; store low byte of match offset
|
||||||
|
stx OFFSHI ; store high byte of match offset
|
||||||
|
|
||||||
|
rep_match:
|
||||||
|
.ifdef BACKWARD_DECOMPRESS
|
||||||
|
|
||||||
|
; Backward decompression - substract match offset
|
||||||
|
|
||||||
|
sec ; add dest + match offset
|
||||||
|
lda putdst+1 ; low 8 bits
|
||||||
|
OFFSLO = *+1
|
||||||
|
sbc #$AA
|
||||||
|
sta copy_match_loop+1 ; store back reference address
|
||||||
|
lda putdst+2
|
||||||
|
OFFSHI = *+1
|
||||||
|
sbc #$AA ; high 8 bits
|
||||||
|
sta copy_match_loop+2 ; store high 8 bits of address
|
||||||
|
sec
|
||||||
|
|
||||||
|
.else
|
||||||
|
|
||||||
|
; Forward decompression - add match offset
|
||||||
|
|
||||||
|
clc ; add dest + match offset
|
||||||
|
lda putdst+1 ; low 8 bits
|
||||||
|
OFFSLO = *+1
|
||||||
|
adc #$AA
|
||||||
|
sta copy_match_loop+1 ; store back reference address
|
||||||
|
OFFSHI = *+1
|
||||||
|
lda #$AA ; high 8 bits
|
||||||
|
adc putdst+2
|
||||||
|
sta copy_match_loop+2 ; store high 8 bits of address
|
||||||
|
.endif
|
||||||
|
|
||||||
|
pla ; retrieve token from stack again
|
||||||
|
and #$07 ; isolate match len (MMM)
|
||||||
|
adc #$01 ; add MIN_MATCH_SIZE_V2 and carry
|
||||||
|
cmp #$09 ; MIN_MATCH_SIZE_V2 + MATCH_RUN_LEN_V2?
|
||||||
|
bcc prepare_copy_match ; if less, length is directly embedded in token
|
||||||
|
|
||||||
|
jsr getnibble ; get extra match length nibble
|
||||||
|
; add nibble to len from token
|
||||||
|
adc #$08 ; (MIN_MATCH_SIZE_V2 + MATCH_RUN_LEN_V2) minus carry
|
||||||
|
cmp #$18 ; MIN_MATCH_SIZE_V2 + MATCH_RUN_LEN_V2 + 15?
|
||||||
|
bcc prepare_copy_match ; if less, match length is complete
|
||||||
|
|
||||||
|
jsr getsrc ; get extra byte of variable match length
|
||||||
|
; the carry is always set by the CMP above
|
||||||
|
; GETSRC doesn't change it
|
||||||
|
sbc #$E8 ; overflow?
|
||||||
|
|
||||||
|
prepare_copy_match:
|
||||||
|
tax
|
||||||
|
bcc prepare_copy_match_y ; if not, the match length is complete
|
||||||
|
beq decompression_done ; if EOD code, bail
|
||||||
|
|
||||||
|
; Handle 16 bits match length
|
||||||
|
jsr getlargesrc ; grab low 8 bits in X, high 8 bits in A
|
||||||
|
tay ; put high 8 bits in Y
|
||||||
|
|
||||||
|
prepare_copy_match_y:
|
||||||
|
txa
|
||||||
|
beq copy_match_loop
|
||||||
|
iny
|
||||||
|
|
||||||
|
copy_match_loop:
|
||||||
|
lda $AAAA ; get one byte of backreference
|
||||||
|
jsr putdst ; copy to destination
|
||||||
|
|
||||||
|
.ifdef BACKWARD_DECOMPRESS
|
||||||
|
|
||||||
|
; Backward decompression -- put backreference bytes backward
|
||||||
|
|
||||||
|
lda copy_match_loop+1
|
||||||
|
beq getmatch_adj_hi
|
||||||
|
getmatch_done:
|
||||||
|
dec copy_match_loop+1
|
||||||
|
|
||||||
|
.else
|
||||||
|
|
||||||
|
; Forward decompression -- put backreference bytes forward
|
||||||
|
|
||||||
|
inc copy_match_loop+1
|
||||||
|
beq getmatch_adj_hi
|
||||||
|
getmatch_done:
|
||||||
|
|
||||||
|
.endif
|
||||||
|
|
||||||
|
dex
|
||||||
|
bne copy_match_loop
|
||||||
|
dey
|
||||||
|
bne copy_match_loop
|
||||||
|
jmp decode_token
|
||||||
|
|
||||||
|
.ifdef BACKWARD_DECOMPRESS
|
||||||
|
|
||||||
|
getmatch_adj_hi:
|
||||||
|
dec copy_match_loop+2
|
||||||
|
jmp getmatch_done
|
||||||
|
|
||||||
|
.else
|
||||||
|
|
||||||
|
getmatch_adj_hi:
|
||||||
|
inc copy_match_loop+2
|
||||||
|
jmp getmatch_done
|
||||||
|
.endif
|
||||||
|
|
||||||
|
getcombinedbits:
|
||||||
|
eor #$80
|
||||||
|
asl
|
||||||
|
php
|
||||||
|
|
||||||
|
jsr getnibble ; get nibble into bits 0-3 (for offset bits 1-4)
|
||||||
|
plp ; merge Z bit as the carry bit (for offset bit 0)
|
||||||
|
combinedbitz:
|
||||||
|
rol ; nibble -> bits 1-4; carry(!Z bit) -> bit 0 ; carry cleared
|
||||||
|
decompression_done:
|
||||||
|
rts
|
||||||
|
|
||||||
|
getnibble:
|
||||||
|
NIBBLES = *+1
|
||||||
|
lda #$AA
|
||||||
|
lsr NIBCOUNT
|
||||||
|
bcc need_nibbles
|
||||||
|
and #$0F ; isolate low 4 bits of nibble
|
||||||
|
rts
|
||||||
|
|
||||||
|
need_nibbles:
|
||||||
|
inc NIBCOUNT
|
||||||
|
jsr getsrc ; get 2 nibbles
|
||||||
|
sta NIBBLES
|
||||||
|
lsr
|
||||||
|
lsr
|
||||||
|
lsr
|
||||||
|
lsr
|
||||||
|
sec
|
||||||
|
rts
|
||||||
|
|
||||||
|
.ifdef BACKWARD_DECOMPRESS
|
||||||
|
|
||||||
|
; Backward decompression -- get and put bytes backward
|
||||||
|
|
||||||
|
getput:
|
||||||
|
jsr getsrc
|
||||||
|
putdst:
|
||||||
|
LZSA_DST_LO = *+1
|
||||||
|
LZSA_DST_HI = *+2
|
||||||
|
sta $AAAA
|
||||||
|
lda putdst+1
|
||||||
|
beq putdst_adj_hi
|
||||||
|
dec putdst+1
|
||||||
|
rts
|
||||||
|
|
||||||
|
putdst_adj_hi:
|
||||||
|
dec putdst+2
|
||||||
|
dec putdst+1
|
||||||
|
rts
|
||||||
|
|
||||||
|
getlargesrc:
|
||||||
|
jsr getsrc ; grab low 8 bits
|
||||||
|
tax ; move to X
|
||||||
|
; fall through grab high 8 bits
|
||||||
|
|
||||||
|
getsrc:
|
||||||
|
LZSA_SRC_LO = *+1
|
||||||
|
LZSA_SRC_HI = *+2
|
||||||
|
lda $AAAA
|
||||||
|
pha
|
||||||
|
lda getsrc+1
|
||||||
|
beq getsrc_adj_hi
|
||||||
|
dec getsrc+1
|
||||||
|
pla
|
||||||
|
rts
|
||||||
|
|
||||||
|
getsrc_adj_hi:
|
||||||
|
dec getsrc+2
|
||||||
|
dec getsrc+1
|
||||||
|
pla
|
||||||
|
rts
|
||||||
|
|
||||||
|
.else
|
||||||
|
|
||||||
|
; Forward decompression -- get and put bytes forward
|
||||||
|
|
||||||
|
getput:
|
||||||
|
jsr getsrc
|
||||||
|
putdst:
|
||||||
|
LZSA_DST_LO = *+1
|
||||||
|
LZSA_DST_HI = *+2
|
||||||
|
sta $AAAA
|
||||||
|
inc putdst+1
|
||||||
|
beq putdst_adj_hi
|
||||||
|
rts
|
||||||
|
|
||||||
|
putdst_adj_hi:
|
||||||
|
inc putdst+2
|
||||||
|
rts
|
||||||
|
|
||||||
|
getlargesrc:
|
||||||
|
jsr getsrc ; grab low 8 bits
|
||||||
|
tax ; move to X
|
||||||
|
; fall through grab high 8 bits
|
||||||
|
|
||||||
|
getsrc:
|
||||||
|
getsrc_smc:
|
||||||
|
LZSA_SRC_LO = *+1
|
||||||
|
LZSA_SRC_HI = *+2
|
||||||
|
lda $AAAA
|
||||||
|
inc getsrc+1
|
||||||
|
beq getsrc_adj_hi
|
||||||
|
rts
|
||||||
|
|
||||||
|
getsrc_adj_hi:
|
||||||
|
inc getsrc+2
|
||||||
|
rts
|
||||||
|
.endif
|
||||||
|
|
||||||
102
compression/comparison/hardware.inc
Normal file
102
compression/comparison/hardware.inc
Normal file
@ -0,0 +1,102 @@
|
|||||||
|
;; HARDWARE LOCATIONS
|
||||||
|
|
||||||
|
KEYPRESS = $C000
|
||||||
|
KEYRESET = $C010
|
||||||
|
|
||||||
|
;; SOFT SWITCHES
|
||||||
|
CLR80COL = $C000 ; PAGE0/PAGE1 normal
|
||||||
|
SET80COL = $C001 ; PAGE0/PAGE1 switches PAGE0 in Aux instead
|
||||||
|
EIGHTYCOLOFF = $C00C
|
||||||
|
EIGHTYCOLON = $C00D
|
||||||
|
VBLANK = $C019 ; IIe *not* RDVBL (VBL low), IIgs opposite
|
||||||
|
RSTVBL = $C019 ; reset VBLANK interrupt (iic)
|
||||||
|
RDVBLBAR = $C019
|
||||||
|
TBCOLOR = $C022 ; IIgs text foreground / background colors
|
||||||
|
NEWVIDEO = $C029 ; IIgs graphics modes
|
||||||
|
SPEAKER = $C030
|
||||||
|
CLOCKCTL = $C034 ; bits 0-3 are IIgs border color
|
||||||
|
RDVBLMSK = $C041 ; read VBL interrupt (bit 7)
|
||||||
|
SET_GR = $C050
|
||||||
|
SET_TEXT = $C051
|
||||||
|
FULLGR = $C052
|
||||||
|
TEXTGR = $C053
|
||||||
|
PAGE0 = $C054
|
||||||
|
PAGE1 = $C055
|
||||||
|
LORES = $C056 ; Enable LORES graphics
|
||||||
|
HIRES = $C057 ; Enable HIRES graphics
|
||||||
|
CLRAN1 = $C05A ; clear annunciator 1 (if IOUDIS off)
|
||||||
|
DISVBL = $C05A ; disable VBLANK (iic) (if IOUDIS on)
|
||||||
|
SETAN1 = $C05B ; set annunciator 1 (if IOUDIS off)
|
||||||
|
ENVBL = $C05B ; enable VBLANK (iic) (if IOUDIS on)
|
||||||
|
AN3 = $C05E ; Annunciator 3
|
||||||
|
PADDLE_BUTTON0 = $C061
|
||||||
|
PADDL0 = $C064
|
||||||
|
PTRIG = $C070 ; Analog input reset
|
||||||
|
VBLINT = $C070 ; Analog input reset + reset vblank (iic)
|
||||||
|
IOUDISON = $C07E ; iic
|
||||||
|
IOUDISOFF = $C07F ; iic
|
||||||
|
|
||||||
|
;; BASIC ROUTINES
|
||||||
|
|
||||||
|
NORMAL = $F273
|
||||||
|
|
||||||
|
;; MONITOR ROUTINES
|
||||||
|
|
||||||
|
HLINE = $F819 ;; HLINE Y,$2C at A
|
||||||
|
VLINE = $F828 ;; VLINE A,$2D at Y
|
||||||
|
CLRSCR = $F832 ;; Clear low-res screen
|
||||||
|
CLRTOP = $F836 ;; clear only top of low-res screen
|
||||||
|
SETCOL = $F864 ;; COLOR=A
|
||||||
|
ROM_TEXT2COPY = $F962 ;; iigs
|
||||||
|
TEXT = $FB36
|
||||||
|
TABV = $FB5B ;; VTAB to A
|
||||||
|
ROM_MACHINEID = $FBB3 ;; iigs
|
||||||
|
BELL = $FBDD ;; ring the bell
|
||||||
|
BASCALC = $FBC1 ;;
|
||||||
|
VTAB = $FC22 ;; VTAB to CV
|
||||||
|
HOME = $FC58 ;; Clear the text screen
|
||||||
|
WAIT = $FCA8 ;; delay 1/2(26+27A+5A^2) us
|
||||||
|
CROUT1 = $FD8B
|
||||||
|
SETINV = $FE80 ;; INVERSE
|
||||||
|
SETNORM = $FE84 ;; NORMAL
|
||||||
|
COUT = $FDED ;; output A to screen
|
||||||
|
COUT1 = $FDF0 ;; output A to screen
|
||||||
|
|
||||||
|
|
||||||
|
|
||||||
|
|
||||||
|
|
||||||
|
|
||||||
|
|
||||||
|
COLOR_BLACK = 0
|
||||||
|
COLOR_RED = 1
|
||||||
|
COLOR_DARKBLUE = 2
|
||||||
|
COLOR_PURPLE = 3
|
||||||
|
COLOR_DARKGREEN = 4
|
||||||
|
COLOR_GREY = 5
|
||||||
|
COLOR_MEDIUMBLUE = 6
|
||||||
|
COLOR_LIGHTBLUE = 7
|
||||||
|
COLOR_BROWN = 8
|
||||||
|
COLOR_ORANGE = 9
|
||||||
|
COLOR_GREY2 = 10
|
||||||
|
COLOR_PINK = 11
|
||||||
|
COLOR_LIGHTGREEN = 12
|
||||||
|
COLOR_YELLOW = 13
|
||||||
|
COLOR_AQUA = 14
|
||||||
|
COLOR_WHITE = 15
|
||||||
|
|
||||||
|
COLOR_BOTH_BLACK = $00
|
||||||
|
COLOR_BOTH_RED = $11
|
||||||
|
COLOR_BOTH_DARKBLUE = $22
|
||||||
|
COLOR_BOTH_DARKGREEN = $44
|
||||||
|
COLOR_BOTH_GREY = $55
|
||||||
|
COLOR_BOTH_MEDIUMBLUE = $66
|
||||||
|
COLOR_BOTH_LIGHTBLUE = $77
|
||||||
|
COLOR_BOTH_BROWN = $88
|
||||||
|
COLOR_BOTH_ORANGE = $99
|
||||||
|
COLOR_BOTH_PINK = $BB
|
||||||
|
COLOR_BOTH_LIGHTGREEN = $CC
|
||||||
|
COLOR_BOTH_YELLOW = $DD
|
||||||
|
COLOR_BOTH_AQUA = $EE
|
||||||
|
COLOR_BOTH_WHITE = $FF
|
||||||
|
|
||||||
2
compression/comparison/hello.bas
Normal file
2
compression/comparison/hello.bas
Normal file
@ -0,0 +1,2 @@
|
|||||||
|
5 HOME
|
||||||
|
10 PRINT CHR$(4);"CATALOG"
|
||||||
BIN
compression/comparison/level5.png
Normal file
BIN
compression/comparison/level5.png
Normal file
Binary file not shown.
|
After Width: | Height: | Size: 28 KiB |
26
compression/comparison/lzsa_test.s
Normal file
26
compression/comparison/lzsa_test.s
Normal file
@ -0,0 +1,26 @@
|
|||||||
|
.include "zp.inc"
|
||||||
|
.include "hardware.inc"
|
||||||
|
|
||||||
|
lzsa_test:
|
||||||
|
|
||||||
|
bit SET_GR
|
||||||
|
bit PAGE0
|
||||||
|
bit HIRES
|
||||||
|
bit FULLGR
|
||||||
|
|
||||||
|
lda #<level5_lzsa
|
||||||
|
sta getsrc_smc+1 ; LZSA_SRC_LO
|
||||||
|
lda #>level5_lzsa
|
||||||
|
sta getsrc_smc+2 ; LZSA_SRC_HI
|
||||||
|
|
||||||
|
lda #$20
|
||||||
|
|
||||||
|
jsr decompress_lzsa2_fast
|
||||||
|
|
||||||
|
end:
|
||||||
|
jmp end
|
||||||
|
|
||||||
|
|
||||||
|
.include "graphics_level5.inc"
|
||||||
|
|
||||||
|
.include "decompress_fast_v2.s"
|
||||||
131
compression/comparison/zp.inc
Normal file
131
compression/comparison/zp.inc
Normal file
@ -0,0 +1,131 @@
|
|||||||
|
;; Zero Page
|
||||||
|
|
||||||
|
;; LZSA addresses
|
||||||
|
NIBCOUNT = $00
|
||||||
|
WHICH_LOAD = $01
|
||||||
|
|
||||||
|
;; Zero page monitor routines addresses
|
||||||
|
|
||||||
|
HGR_BITS= $1C
|
||||||
|
WNDLFT = $20
|
||||||
|
WNDWDTH = $21
|
||||||
|
WNDTOP = $22
|
||||||
|
WNDBTM = $23
|
||||||
|
CH = $24
|
||||||
|
CV = $25
|
||||||
|
GBASL = $26
|
||||||
|
GBASH = $27
|
||||||
|
BASL = $28
|
||||||
|
BASH = $29
|
||||||
|
H2 = $2C
|
||||||
|
X_LEFT = $2C
|
||||||
|
V2 = $2D
|
||||||
|
MASK = $2E
|
||||||
|
COLOR_MASK = $2F
|
||||||
|
COLOR = $30
|
||||||
|
|
||||||
|
SEEDLO = $4e
|
||||||
|
SEEDHI = $4f
|
||||||
|
XMAX = $50
|
||||||
|
|
||||||
|
|
||||||
|
FRAMEL = $60
|
||||||
|
FRAMEH = $61
|
||||||
|
;CURSOR_X = $62
|
||||||
|
;CURSOR_Y = $63
|
||||||
|
XPOS = $64
|
||||||
|
YPOS = $65
|
||||||
|
LOCATION_STRUCT_L = $66
|
||||||
|
LOCATION_STRUCT_H = $67
|
||||||
|
IN_SPECIAL = $68
|
||||||
|
CURSOR_VISIBLE = $69
|
||||||
|
IN_LEFT = $6A
|
||||||
|
IN_RIGHT = $6B
|
||||||
|
BTC_L = $6C
|
||||||
|
BTC_H = $6D
|
||||||
|
|
||||||
|
; ym player
|
||||||
|
CURRENT_FRAME_L = $70
|
||||||
|
CURRENT_FRAME_H = $71
|
||||||
|
BASE_FRAME_L = $72
|
||||||
|
BASE_FRAME_H = $73
|
||||||
|
CURRENT_CHUNK = $74
|
||||||
|
TIME_MINUTES = $75
|
||||||
|
TIME_SECONDS = $76
|
||||||
|
CURSOR_X = $77
|
||||||
|
CURSOR_Y = $78
|
||||||
|
DISP_PAGE = $79
|
||||||
|
DRAW_PAGE = $7A
|
||||||
|
LEVEL_OVER = $7B
|
||||||
|
LEVEL_FAIL = 1
|
||||||
|
LEVEL_WIN = 2
|
||||||
|
DOOR_OPEN = $7C
|
||||||
|
CHUNK_NEXT_LOAD = $7D
|
||||||
|
CHUNK_NEXT_PLAY = $7E
|
||||||
|
LOAD_NEXT_CHUNK = $7F
|
||||||
|
OVER_LEMMING = $80
|
||||||
|
TIMER_COUNT = $81
|
||||||
|
UPDATE_POINTER = $82
|
||||||
|
NEXT_LEMMING_TO_RELEASE = $83
|
||||||
|
SAVED_Y1 = $84
|
||||||
|
SAVED_Y2 = $85
|
||||||
|
LEMMINGS_OUT = $86
|
||||||
|
BUTTON_LOCATION = $87
|
||||||
|
WHICH_LEVEL = $88
|
||||||
|
LEMMINGS_TO_RELEASE = $89
|
||||||
|
CURRENT_LEMMING = $8A
|
||||||
|
APPLEII_MODEL = $8B
|
||||||
|
PERCENT_RESCUED_L = $8C
|
||||||
|
PERCENT_RESCUED_H = $8D
|
||||||
|
PERCENT_NEEDED = $8E
|
||||||
|
PERCENT_ADD = $8F
|
||||||
|
|
||||||
|
DOOR_X = $90 ; location of door
|
||||||
|
DOOR_Y = $91
|
||||||
|
INIT_X = $92 ; initial lemming position
|
||||||
|
INIT_Y = $93
|
||||||
|
|
||||||
|
CLIMBER_COUNT = $94
|
||||||
|
FLOATER_COUNT = $95
|
||||||
|
EXPLODER_COUNT = $96
|
||||||
|
STOPPER_COUNT = $97
|
||||||
|
BUILDER_COUNT = $98
|
||||||
|
BASHER_COUNT = $99
|
||||||
|
MINER_COUNT = $9A
|
||||||
|
DIGGER_COUNT = $9B
|
||||||
|
|
||||||
|
|
||||||
|
; done game puzzle state
|
||||||
|
|
||||||
|
|
||||||
|
WHICH_SLOT = $DA
|
||||||
|
JS_BUTTON_STATE = $DB
|
||||||
|
CURRENT_DISK = $DC
|
||||||
|
JOYSTICK_ENABLED= $DD
|
||||||
|
SOUND_STATUS = $DE
|
||||||
|
SOUND_DISABLED = $80
|
||||||
|
SOUND_IN_LC = $01 ; $01 sound effects in language card
|
||||||
|
SOUND_MOCKINGBOARD = $02 ; mockingboard detected
|
||||||
|
|
||||||
|
HGR_COLOR = $E4
|
||||||
|
HGR_PAGE = $E6
|
||||||
|
|
||||||
|
|
||||||
|
|
||||||
|
|
||||||
|
; rest of pt3_player
|
||||||
|
LOOP = $F4
|
||||||
|
MB_VALUE = $F5
|
||||||
|
MB_ADDR_L = $F6
|
||||||
|
MB_ADDR_H = $F7
|
||||||
|
DONE_PLAYING = $F8
|
||||||
|
DONE_SONG = $F9
|
||||||
|
|
||||||
|
|
||||||
|
TEMP = $FA
|
||||||
|
TEMPY = $FB
|
||||||
|
INL = $FC
|
||||||
|
INH = $FD
|
||||||
|
OUTL = $FE
|
||||||
|
OUTH = $FF
|
||||||
|
|
||||||
Loading…
Reference in New Issue
Block a user