4cade/src/prelaunch/video.vegas.a

;license:MIT
;(c) 2021 by qkumba

!cpu 6502
!to "build/PRELAUNCH.INDEXED/VIDEO.VEGAS",plain
*=$106

         !source "src/macros.a"

         lda   #$60
         sta   $9E5
         jsr   $800       ; load "DOS"
         lda   #>callback1
         sta   $E079
         lda   #<callback1
         sta   $E078
         jmp   $E03A

callback1
         lda   #$A6
         sta   $3DD
         lda   #$FA
         sta   $3DE
         lda   #$60
         sta   $E0BC
         jsr   $E083
         ldx   #(callback2_e-callback2_b)-1
-        lda   callback2_b,x
         sta   callback2,x
         dex
         bpl   -
         lda   #>callback2
         sta   $D402
         lda   #<callback2
         sta   $D401
         lda   #$00
         ldx   #$0F
         jmp   $D000

callback2_b !pseudopc $174 {
callback2
         jsr   $D432
         ldy   $DFD4
         lda   $DFD3
         beq   checksec
         cmp   #4
         bne   nottrack
         cpy   #$0A
         bne   nottrack
         lda   #$A6
         sta   $A42F
         lda   #$FA
         sta   $A430
         bne   nottrack

checksec
         cpy   #$0D
         bne   nottrack
         lda   #$A6
         sta   $3DD
         lda   #$FA
         sta   $3DE

nottrack
         clc
         jmp   $D403
}
callback2_e

!if * > $1C0 {
  !error "code is too large, ends at ", *
}