;license:MIT
;(c) 2021-2022 by qkumba

!cpu 6502
!to "build/PRELAUNCH.INDEXED/PEGASUS.II",plain
*=$106

         !source "src/macros.a"

         +ENABLE_ACCEL
         lda   #$60
         sta   $9E0
         jsr   $800       ; load "DOS"
         lda   #>callback
         sta   $BD08
         lda   #<callback
         sta   $BD07
         +DISABLE_ACCEL
         jmp   $B700

callback
         pla
         pla
         jsr   $BD3C
         jsr   $BD09
         ldx   #0
         ldy   $B7ED
         lda   $B7EC
         beq   checksec
         cmp   #$13
         bne   nottrack
         cpy   #$0B
         bne   nottrack
         stx   $9949
         inx
         stx   $994A
         lda   #$A4
         sta   $994B
         +GET_MACHINE_STATUS
         and   #CHEATS_ENABLED
         beq   +
         lda   #$ad
         sta   $CD5       ; patch - don't decrease lives
         sta   $719F      ; patch - don't increase lives
         sta   $71C0      ; patch - don't decrease fuel
+
         clc
         rts

checksec
         cpy   #$0C
         bne   nottrack
         stx   $9E52
         inx
         stx   $9E53
nottrack

         clc
         rts

!if * > $1C0 {
  !error "code is too large, ends at ", *
}