;license:MIT
;(c) 2021-2022 by Frank M., qkumba

!cpu 6502
!to "build/DEMO/FIREBUG#060200",plain
*=$200

         !source "src/constants.a"   ; no code in these
         !source "src/macros.a"

         +READ_RAM2_WRITE_RAM2
         jsr   EnableAccelerator
         +LOAD_FILE_AT title, $00

         lda   #$2C
         sta   $2070      ; don't load "RECORD" (demo doesn't show high scores)

         lda   #$60
         sta   $2076
         jsr   $2000      ; decompress

         ldx   #0
         stx   $83E
         inx
         stx   $849       ; reset vector fix

         ldx   #3-1
-        lda   patch,x
         sta   $1105,x
         sta   $151A,x
         sta   $5EA5,x
         sta   $5F3B,x    ; exit on keypress
         sta   $5F46,x    ; exit at end of demo cycle
         dex
         bpl   -

         lda   #$54
         sta   $086F      ; disable sound

         +DISABLE_ACCEL

         jmp   $810

patch    !byte $4C,$00,$01

title    !byte x_e-x_b
x_b      !text "X/FIREBUG/FIREBUG"
x_e

!if * > $3F0 {
  !error "code is too large, ends at ", *
}