mirror of
https://github.com/autc04/Retro68.git
synced 2024-09-10 03:54:48 +00:00
198 lines
8.8 KiB
Plaintext
198 lines
8.8 KiB
Plaintext
|
# po.m4 serial 1 (gettext-0.12)
|
||
|
dnl Copyright (C) 1995-2003 Free Software Foundation, Inc.
|
||
|
dnl This file is free software, distributed under the terms of the GNU
|
||
|
dnl General Public License. As a special exception to the GNU General
|
||
|
dnl Public License, this file may be distributed as part of a program
|
||
|
dnl that contains a configuration script generated by Autoconf, under
|
||
|
dnl the same distribution terms as the rest of that program.
|
||
|
dnl
|
||
|
dnl This file can can be used in projects which are not available under
|
||
|
dnl the GNU General Public License or the GNU Library General Public
|
||
|
dnl License but which still want to provide support for the GNU gettext
|
||
|
dnl functionality.
|
||
|
dnl Please note that the actual code of the GNU gettext library is covered
|
||
|
dnl by the GNU Library General Public License, and the rest of the GNU
|
||
|
dnl gettext package package is covered by the GNU General Public License.
|
||
|
dnl They are *not* in the public domain.
|
||
|
|
||
|
dnl Authors:
|
||
|
dnl Ulrich Drepper <drepper@cygnus.com>, 1995-2000.
|
||
|
dnl Bruno Haible <haible@clisp.cons.org>, 2000-2003.
|
||
|
|
||
|
dnl Checks for all prerequisites of the po subdirectory.
|
||
|
AC_DEFUN([AM_PO_SUBDIRS],
|
||
|
[
|
||
|
AC_REQUIRE([AC_PROG_MAKE_SET])dnl
|
||
|
AC_REQUIRE([AC_PROG_INSTALL])dnl
|
||
|
AC_REQUIRE([AM_MKINSTALLDIRS])dnl
|
||
|
AC_REQUIRE([AM_NLS])dnl
|
||
|
|
||
|
dnl Perform the following tests also if --disable-nls has been given,
|
||
|
dnl because they are needed for "make dist" to work.
|
||
|
|
||
|
dnl Search for GNU msgfmt in the PATH.
|
||
|
dnl The first test excludes Solaris msgfmt and early GNU msgfmt versions.
|
||
|
dnl The second test excludes FreeBSD msgfmt.
|
||
|
AM_PATH_PROG_WITH_TEST(MSGFMT, msgfmt,
|
||
|
[$ac_dir/$ac_word --statistics /dev/null >/dev/null 2>&1 &&
|
||
|
(if $ac_dir/$ac_word --statistics /dev/null 2>&1 >/dev/null | grep usage >/dev/null; then exit 1; else exit 0; fi)],
|
||
|
:)
|
||
|
AC_PATH_PROG(GMSGFMT, gmsgfmt, $MSGFMT)
|
||
|
|
||
|
dnl Search for GNU xgettext 0.12 or newer in the PATH.
|
||
|
dnl The first test excludes Solaris xgettext and early GNU xgettext versions.
|
||
|
dnl The second test excludes FreeBSD xgettext.
|
||
|
AM_PATH_PROG_WITH_TEST(XGETTEXT, xgettext,
|
||
|
[$ac_dir/$ac_word --omit-header --copyright-holder= --msgid-bugs-address= /dev/null >/dev/null 2>&1 &&
|
||
|
(if $ac_dir/$ac_word --omit-header --copyright-holder= --msgid-bugs-address= /dev/null 2>&1 >/dev/null | grep usage >/dev/null; then exit 1; else exit 0; fi)],
|
||
|
:)
|
||
|
dnl Remove leftover from FreeBSD xgettext call.
|
||
|
rm -f messages.po
|
||
|
|
||
|
dnl Search for GNU msgmerge 0.11 or newer in the PATH.
|
||
|
AM_PATH_PROG_WITH_TEST(MSGMERGE, msgmerge,
|
||
|
[$ac_dir/$ac_word --update -q /dev/null /dev/null >/dev/null 2>&1], :)
|
||
|
|
||
|
dnl This could go away some day; the PATH_PROG_WITH_TEST already does it.
|
||
|
dnl Test whether we really found GNU msgfmt.
|
||
|
if test "$GMSGFMT" != ":"; then
|
||
|
dnl If it is no GNU msgfmt we define it as : so that the
|
||
|
dnl Makefiles still can work.
|
||
|
if $GMSGFMT --statistics /dev/null >/dev/null 2>&1 &&
|
||
|
(if $GMSGFMT --statistics /dev/null 2>&1 >/dev/null | grep usage >/dev/null; then exit 1; else exit 0; fi); then
|
||
|
: ;
|
||
|
else
|
||
|
GMSGFMT=`echo "$GMSGFMT" | sed -e 's,^.*/,,'`
|
||
|
AC_MSG_RESULT(
|
||
|
[found $GMSGFMT program is not GNU msgfmt; ignore it])
|
||
|
GMSGFMT=":"
|
||
|
fi
|
||
|
fi
|
||
|
|
||
|
dnl This could go away some day; the PATH_PROG_WITH_TEST already does it.
|
||
|
dnl Test whether we really found GNU xgettext.
|
||
|
if test "$XGETTEXT" != ":"; then
|
||
|
dnl If it is no GNU xgettext we define it as : so that the
|
||
|
dnl Makefiles still can work.
|
||
|
if $XGETTEXT --omit-header --copyright-holder= --msgid-bugs-address= /dev/null >/dev/null 2>&1 &&
|
||
|
(if $XGETTEXT --omit-header --copyright-holder= --msgid-bugs-address= /dev/null 2>&1 >/dev/null | grep usage >/dev/null; then exit 1; else exit 0; fi); then
|
||
|
: ;
|
||
|
else
|
||
|
AC_MSG_RESULT(
|
||
|
[found xgettext program is not GNU xgettext; ignore it])
|
||
|
XGETTEXT=":"
|
||
|
fi
|
||
|
dnl Remove leftover from FreeBSD xgettext call.
|
||
|
rm -f messages.po
|
||
|
fi
|
||
|
|
||
|
AC_OUTPUT_COMMANDS([
|
||
|
for ac_file in $CONFIG_FILES; do
|
||
|
# Support "outfile[:infile[:infile...]]"
|
||
|
case "$ac_file" in
|
||
|
*:*) ac_file=`echo "$ac_file"|sed 's%:.*%%'` ;;
|
||
|
esac
|
||
|
# PO directories have a Makefile.in generated from Makefile.in.in.
|
||
|
case "$ac_file" in */Makefile.in)
|
||
|
# Adjust a relative srcdir.
|
||
|
ac_dir=`echo "$ac_file"|sed 's%/[^/][^/]*$%%'`
|
||
|
ac_dir_suffix=/`echo "$ac_dir"|sed 's%^\./%%'`
|
||
|
ac_dots=`echo "$ac_dir_suffix"|sed 's%/[^/]*%../%g'`
|
||
|
# In autoconf-2.13 it is called $ac_given_srcdir.
|
||
|
# In autoconf-2.50 it is called $srcdir.
|
||
|
test -n "$ac_given_srcdir" || ac_given_srcdir="$srcdir"
|
||
|
case "$ac_given_srcdir" in
|
||
|
.) top_srcdir=`echo $ac_dots|sed 's%/$%%'` ;;
|
||
|
/*) top_srcdir="$ac_given_srcdir" ;;
|
||
|
*) top_srcdir="$ac_dots$ac_given_srcdir" ;;
|
||
|
esac
|
||
|
if test -f "$ac_given_srcdir/$ac_dir/POTFILES.in"; then
|
||
|
rm -f "$ac_dir/POTFILES"
|
||
|
test -n "$as_me" && echo "$as_me: creating $ac_dir/POTFILES" || echo "creating $ac_dir/POTFILES"
|
||
|
cat "$ac_given_srcdir/$ac_dir/POTFILES.in" | sed -e "/^#/d" -e "/^[ ]*\$/d" -e "s,.*, $top_srcdir/& \\\\," | sed -e "\$s/\(.*\) \\\\/\1/" > "$ac_dir/POTFILES"
|
||
|
POMAKEFILEDEPS="POTFILES.in"
|
||
|
# ALL_LINGUAS, POFILES, GMOFILES, UPDATEPOFILES, DUMMYPOFILES depend
|
||
|
# on $ac_dir but don't depend on user-specified configuration
|
||
|
# parameters.
|
||
|
if test -f "$ac_given_srcdir/$ac_dir/LINGUAS"; then
|
||
|
# The LINGUAS file contains the set of available languages.
|
||
|
if test -n "$OBSOLETE_ALL_LINGUAS"; then
|
||
|
test -n "$as_me" && echo "$as_me: setting ALL_LINGUAS in configure.in is obsolete" || echo "setting ALL_LINGUAS in configure.in is obsolete"
|
||
|
fi
|
||
|
ALL_LINGUAS_=`sed -e "/^#/d" "$ac_given_srcdir/$ac_dir/LINGUAS"`
|
||
|
# Hide the ALL_LINGUAS assigment from automake.
|
||
|
eval 'ALL_LINGUAS''=$ALL_LINGUAS_'
|
||
|
POMAKEFILEDEPS="$POMAKEFILEDEPS LINGUAS"
|
||
|
else
|
||
|
# The set of available languages was given in configure.in.
|
||
|
eval 'ALL_LINGUAS''=$OBSOLETE_ALL_LINGUAS'
|
||
|
fi
|
||
|
case "$ac_given_srcdir" in
|
||
|
.) srcdirpre= ;;
|
||
|
*) srcdirpre='$(srcdir)/' ;;
|
||
|
esac
|
||
|
POFILES=
|
||
|
GMOFILES=
|
||
|
UPDATEPOFILES=
|
||
|
DUMMYPOFILES=
|
||
|
for lang in $ALL_LINGUAS; do
|
||
|
POFILES="$POFILES $srcdirpre$lang.po"
|
||
|
GMOFILES="$GMOFILES $srcdirpre$lang.gmo"
|
||
|
UPDATEPOFILES="$UPDATEPOFILES $lang.po-update"
|
||
|
DUMMYPOFILES="$DUMMYPOFILES $lang.nop"
|
||
|
done
|
||
|
# CATALOGS depends on both $ac_dir and the user's LINGUAS
|
||
|
# environment variable.
|
||
|
INST_LINGUAS=
|
||
|
if test -n "$ALL_LINGUAS"; then
|
||
|
for presentlang in $ALL_LINGUAS; do
|
||
|
useit=no
|
||
|
if test "%UNSET%" != "$LINGUAS"; then
|
||
|
desiredlanguages="$LINGUAS"
|
||
|
else
|
||
|
desiredlanguages="$ALL_LINGUAS"
|
||
|
fi
|
||
|
for desiredlang in $desiredlanguages; do
|
||
|
# Use the presentlang catalog if desiredlang is
|
||
|
# a. equal to presentlang, or
|
||
|
# b. a variant of presentlang (because in this case,
|
||
|
# presentlang can be used as a fallback for messages
|
||
|
# which are not translated in the desiredlang catalog).
|
||
|
case "$desiredlang" in
|
||
|
"$presentlang"*) useit=yes;;
|
||
|
esac
|
||
|
done
|
||
|
if test $useit = yes; then
|
||
|
INST_LINGUAS="$INST_LINGUAS $presentlang"
|
||
|
fi
|
||
|
done
|
||
|
fi
|
||
|
CATALOGS=
|
||
|
if test -n "$INST_LINGUAS"; then
|
||
|
for lang in $INST_LINGUAS; do
|
||
|
CATALOGS="$CATALOGS $lang.gmo"
|
||
|
done
|
||
|
fi
|
||
|
test -n "$as_me" && echo "$as_me: creating $ac_dir/Makefile" || echo "creating $ac_dir/Makefile"
|
||
|
sed -e "/^POTFILES =/r $ac_dir/POTFILES" -e "/^# Makevars/r $ac_given_srcdir/$ac_dir/Makevars" -e "s|@POFILES@|$POFILES|g" -e "s|@GMOFILES@|$GMOFILES|g" -e "s|@UPDATEPOFILES@|$UPDATEPOFILES|g" -e "s|@DUMMYPOFILES@|$DUMMYPOFILES|g" -e "s|@CATALOGS@|$CATALOGS|g" -e "s|@POMAKEFILEDEPS@|$POMAKEFILEDEPS|g" "$ac_dir/Makefile.in" > "$ac_dir/Makefile"
|
||
|
for f in "$ac_given_srcdir/$ac_dir"/Rules-*; do
|
||
|
if test -f "$f"; then
|
||
|
case "$f" in
|
||
|
*.orig | *.bak | *~) ;;
|
||
|
*) cat "$f" >> "$ac_dir/Makefile" ;;
|
||
|
esac
|
||
|
fi
|
||
|
done
|
||
|
fi
|
||
|
;;
|
||
|
esac
|
||
|
done],
|
||
|
[# Capture the value of obsolete ALL_LINGUAS because we need it to compute
|
||
|
# POFILES, GMOFILES, UPDATEPOFILES, DUMMYPOFILES, CATALOGS. But hide it
|
||
|
# from automake.
|
||
|
eval 'OBSOLETE_ALL_LINGUAS''="$ALL_LINGUAS"'
|
||
|
# Capture the value of LINGUAS because we need it to compute CATALOGS.
|
||
|
LINGUAS="${LINGUAS-%UNSET%}"
|
||
|
])
|
||
|
])
|