mirror of
https://github.com/autc04/Retro68.git
synced 2024-09-08 20:55:01 +00:00
92 lines
2.9 KiB
Plaintext
92 lines
2.9 KiB
Plaintext
|
# progtest.m4 serial 3 (gettext-0.12)
|
||
|
dnl Copyright (C) 1996-2003 Free Software Foundation, Inc.
|
||
|
dnl This file is free software, distributed under the terms of the GNU
|
||
|
dnl General Public License. As a special exception to the GNU General
|
||
|
dnl Public License, this file may be distributed as part of a program
|
||
|
dnl that contains a configuration script generated by Autoconf, under
|
||
|
dnl the same distribution terms as the rest of that program.
|
||
|
dnl
|
||
|
dnl This file can can be used in projects which are not available under
|
||
|
dnl the GNU General Public License or the GNU Library General Public
|
||
|
dnl License but which still want to provide support for the GNU gettext
|
||
|
dnl functionality.
|
||
|
dnl Please note that the actual code of the GNU gettext library is covered
|
||
|
dnl by the GNU Library General Public License, and the rest of the GNU
|
||
|
dnl gettext package package is covered by the GNU General Public License.
|
||
|
dnl They are *not* in the public domain.
|
||
|
|
||
|
dnl Authors:
|
||
|
dnl Ulrich Drepper <drepper@cygnus.com>, 1996.
|
||
|
|
||
|
# Search path for a program which passes the given test.
|
||
|
|
||
|
dnl AM_PATH_PROG_WITH_TEST(VARIABLE, PROG-TO-CHECK-FOR,
|
||
|
dnl TEST-PERFORMED-ON-FOUND_PROGRAM [, VALUE-IF-NOT-FOUND [, PATH]])
|
||
|
AC_DEFUN([AM_PATH_PROG_WITH_TEST],
|
||
|
[
|
||
|
# Prepare PATH_SEPARATOR.
|
||
|
# The user is always right.
|
||
|
if test "${PATH_SEPARATOR+set}" != set; then
|
||
|
echo "#! /bin/sh" >conf$$.sh
|
||
|
echo "exit 0" >>conf$$.sh
|
||
|
chmod +x conf$$.sh
|
||
|
if (PATH="/nonexistent;."; conf$$.sh) >/dev/null 2>&1; then
|
||
|
PATH_SEPARATOR=';'
|
||
|
else
|
||
|
PATH_SEPARATOR=:
|
||
|
fi
|
||
|
rm -f conf$$.sh
|
||
|
fi
|
||
|
|
||
|
# Find out how to test for executable files. Don't use a zero-byte file,
|
||
|
# as systems may use methods other than mode bits to determine executability.
|
||
|
cat >conf$$.file <<_ASEOF
|
||
|
#! /bin/sh
|
||
|
exit 0
|
||
|
_ASEOF
|
||
|
chmod +x conf$$.file
|
||
|
if test -x conf$$.file >/dev/null 2>&1; then
|
||
|
ac_executable_p="test -x"
|
||
|
else
|
||
|
ac_executable_p="test -f"
|
||
|
fi
|
||
|
rm -f conf$$.file
|
||
|
|
||
|
# Extract the first word of "$2", so it can be a program name with args.
|
||
|
set dummy $2; ac_word=[$]2
|
||
|
AC_MSG_CHECKING([for $ac_word])
|
||
|
AC_CACHE_VAL(ac_cv_path_$1,
|
||
|
[case "[$]$1" in
|
||
|
[[\\/]]* | ?:[[\\/]]*)
|
||
|
ac_cv_path_$1="[$]$1" # Let the user override the test with a path.
|
||
|
;;
|
||
|
*)
|
||
|
ac_save_IFS="$IFS"; IFS=$PATH_SEPARATOR
|
||
|
for ac_dir in ifelse([$5], , $PATH, [$5]); do
|
||
|
IFS="$ac_save_IFS"
|
||
|
test -z "$ac_dir" && ac_dir=.
|
||
|
for ac_exec_ext in '' $ac_executable_extensions; do
|
||
|
if $ac_executable_p "$ac_dir/$ac_word$ac_exec_ext"; then
|
||
|
if [$3]; then
|
||
|
ac_cv_path_$1="$ac_dir/$ac_word$ac_exec_ext"
|
||
|
break 2
|
||
|
fi
|
||
|
fi
|
||
|
done
|
||
|
done
|
||
|
IFS="$ac_save_IFS"
|
||
|
dnl If no 4th arg is given, leave the cache variable unset,
|
||
|
dnl so AC_PATH_PROGS will keep looking.
|
||
|
ifelse([$4], , , [ test -z "[$]ac_cv_path_$1" && ac_cv_path_$1="$4"
|
||
|
])dnl
|
||
|
;;
|
||
|
esac])dnl
|
||
|
$1="$ac_cv_path_$1"
|
||
|
if test ifelse([$4], , [-n "[$]$1"], ["[$]$1" != "$4"]); then
|
||
|
AC_MSG_RESULT([$]$1)
|
||
|
else
|
||
|
AC_MSG_RESULT(no)
|
||
|
fi
|
||
|
AC_SUBST($1)dnl
|
||
|
])
|