mirror of
https://github.com/c64scene-ar/llvm-6502.git
synced 2024-12-13 04:30:23 +00:00
fb5e060f2b
With these changes, you can still run makellvm directly from your source tree as follows: % makellvm [toolname] ## looks for obj-root in default places (see below) or % makellvm -obj obj-root [toolname] ## specify obj-root explicitly. With the first from, `makellvm' checks the following places in order and uses the first one that contains the file `Makefile.config': (1) Your src-root directory (2) /localhome/$USER/llvm Other choices can be added to this list. git-svn-id: https://llvm.org/svn/llvm-project/llvm/trunk@8509 91177308-0d34-0410-b5e6-96231b3b80d8
116 lines
2.9 KiB
Tcsh
Executable File
116 lines
2.9 KiB
Tcsh
Executable File
#!/bin/csh -f
|
|
|
|
set pstatus = 0
|
|
onintr cleanup
|
|
alias usage 'echo "USAGE: $0:t [-h] [-n] [-obj obj-root] [gmake-flags] [VAR=...] [toolname (default: opt)]"; set pstatus = 1; goto cleanup'
|
|
|
|
set EXEC = opt
|
|
set GMAKE_OPTS = ""
|
|
set DEBUG = 0
|
|
|
|
set doit = 1
|
|
unset options_done
|
|
while ( !( $?options_done ) && ($#argv > 0))
|
|
switch ($argv[1])
|
|
case -h :
|
|
usage
|
|
case -f :
|
|
if ($#argv < 2) usage
|
|
shift argv; set MFILE = $argv[1]; shift argv; breaksw
|
|
case -n :
|
|
set doit = 0; shift argv; breaksw
|
|
case -obj :
|
|
set OBJROOT = $argv[1]; shift argv; shift argv; breaksw
|
|
case -d :
|
|
set doit = 0; set DEBUG = 1; shift argv; breaksw
|
|
case -* :
|
|
set GMAKE_OPTS = ( $GMAKE_OPTS $argv[1] ); shift argv; breaksw
|
|
default :
|
|
set optarg = `echo -n $argv[1] | sed 's/^[^=]*$//'`
|
|
if ($#optarg) then
|
|
set GMAKE_OPTS = ( $GMAKE_OPTS $optarg )
|
|
shift argv
|
|
else
|
|
set options_done
|
|
endif
|
|
breaksw
|
|
endsw
|
|
end
|
|
|
|
if ($#argv > 1) then
|
|
echo 'ERROR: More than one tool is not supported by "makellvm"'
|
|
usage
|
|
endif
|
|
if ($#argv > 0) then
|
|
set EXEC = $argv[1]
|
|
endif
|
|
if ($DEBUG) then
|
|
echo "DEBUG: EXEC = $EXEC"
|
|
endif
|
|
|
|
## Compute LLVMDIR: the root of the current LLVM tree.
|
|
## It is recorded in the variable LEVEL in Makefile, to compute it
|
|
##
|
|
if (! $?MFILE) then
|
|
if (-f GNUmakefile) then
|
|
set MFILE = GNUmakefile
|
|
else if (-f makefile) then
|
|
set MFILE = makefile
|
|
else
|
|
set MFILE = Makefile
|
|
endif
|
|
endif
|
|
if ($DEBUG) then
|
|
echo "DEBUG: MFILE = $MFILE"
|
|
endif
|
|
if (! -f $MFILE) then
|
|
echo "Missing or invalid makefile: $MFILE"
|
|
exit 1
|
|
endif
|
|
|
|
set LLVMDIR = `awk '/LEVEL[ ]*=/ {print $NF}' $MFILE`
|
|
if ($DEBUG) then
|
|
echo "DEBUG: LLVMDIR = $LLVMDIR"
|
|
endif
|
|
|
|
if ($#LLVMDIR == 0 || ! -d "$LLVMDIR") then
|
|
echo "Unable to find LLVM src-root directory or directory is invalid."
|
|
echo "Are you within a valid LLVM directory for running gmake?"
|
|
exit 1
|
|
endif
|
|
|
|
if ($?OBJROOT == 0) then
|
|
## Check if source root is obj-root by looking for Makefile.config there
|
|
if (-f ${LLVMDIR}/Makefile.config) then
|
|
set OBJROOT = ${LLVMDIR}
|
|
set BUILDROOT = .
|
|
else ## Otherwise assume a default location for OBJROOT
|
|
set OBJROOT = "/localhome/$USER/llvm"
|
|
set SRCROOT = `sh -c "cd $LLVMDIR; pwd | sed 's/\//\\\//g'"`
|
|
set CURSRCDIR = `echo $cwd | sed -e "s/${SRCROOT}//"`
|
|
set BUILDROOT = ${OBJROOT}/${CURSRCDIR}
|
|
unset SRCROOT CURSRCDIR
|
|
endif
|
|
echo "Using OBJ-ROOT = ${OBJROOT} (specify '-obj obj-root' to override)."
|
|
endif
|
|
if ($DEBUG) then
|
|
echo "DEBUG: BUILDROOT = $BUILDROOT"
|
|
endif
|
|
cd $BUILDROOT
|
|
|
|
set CMD = "gmake $GMAKE_OPTS && (cd $LLVMDIR/tools/$EXEC && gmake $GMAKE_OPTS)"
|
|
|
|
if ($doit == 1) then
|
|
csh -f -c "$CMD"
|
|
else
|
|
echo '(NOT EXECUTING) COMMAND:'
|
|
echo " $CMD"
|
|
endif
|
|
|
|
|
|
#=========================================================
|
|
# CODE TO BE EXECUTED IF INTERRUPT IS RECEIVED
|
|
#=========================================================
|
|
cleanup:
|
|
exit($pstatus)
|