mirror of
https://github.com/tjboldt/Apple2-IO-RPi.git
synced 2024-11-27 20:51:03 +00:00
aa5910cee8
* Added assemble.cmd for Windows.
In the long run, some (c)make-based cross-plafrom solution seems preferable.
* Fill up the menu page just like the other pages.
* Allow to assemble for different hardware types.
The first script parameter is used to set the ca65 symbol HW_TYPE. Without parameter, HW_TYPE is set to 0.
* Avoid unwanted i/o access.
Depending on the 6502, LDA addr,X and/or STA addr,X produce additional phantom reads. In order to avoid those phantom reads to do i/o access, I used the "classic" approach of moving those reads from page $C0 to page $BF.
* Made use of BIT instruction to access InputFlags from firmware.
Doing the same for access from disk-based software would require selfmodifying code as there's not bit <addr>,x instruction.
* Removed push/pop from GetByte.
After the replacing the rol instructions with bit instructions with a recent chnage, the only reason left to save a to the stack was setting the OutputFlags. But that can be done using x.
* Added InputFlags check for consistency.
* Added support for an alternative hardware type.
The new hardware type has simple UART-type interface. Beside the two data registers, there are only the two bits to indicate readability and writability of the data registers.
* Added another comminucation interface implementation.
Use ACM CDC (or another proprietary) USB serial device for communication.
Currently VID / PID of a Raspberry Pi Pico SDK CDC UART are hardcoded - see https://github.com/raspberrypi/usb-pid
* Revert "Avoid unwanted i/o access."
Neither the original hardware type nor the alternative hardware type have any read and write i/o port share addresses. Therefore phantom reads aren't an issue with those hardware types.
This reverts commit ae5cb754fb.
* Adapt to the different error signatures on Linux.
So far the code was only tested on Windows.
* Added implementation of the alternative hardware type.
The implemenation is based on a Raspberry Pi Pico - see https://github.com/a2retrosystems/A2retroNET
The new hardware type has a simple UART-type interface. Beside the two data registers, there are only the two bits to indicate readability and writability of the data registers.
* Modify the HD image for the alternative hardware type.
It is likely desirable to have two HD images for the two hardware types. And likely the apple2driver program should default to the right one based on its protocol setting. BUt given that the HD image(s) shouldn't be part of the actual Git repo anyhow, I don't do anything about this here and now.
* Fixed shell startup (?)
At least on the alternative hardware, this "blindly sending" a reset command causes the shell to be terminated right away:
The driver acknowldges the reset command with a zero byte - and that byte ends up being read by DumpOutput causing it to branch to endOutput.
Maybe that sending a reset command is beneficial on the original hardware. Then another .if is required. Or DumpOutput shouldn't quit on reading a zero byte - the shell handler doesn't seem to send it on purpose(?)
* Upate HD image with recent shell change.
* Fix shell shutdown (?)
At least on the alternative hardware, things happen this way:
1. The shell 'exit' command has ptyOut signal outputComplete and terminate. At this point, ptyIn is still blocked up to one second in ReadCharacter - and can therefore not react on outputComplete.
2. The outputComplete handler in ShellCommand sends a zero byte. This makes on the A2 DumpOutput return and the caller send a zero byte. ShellCommand must not return here as ptyIn is still blocked.
3. The zero byte from the A2 has ptyIn return from ReadCharacter, signal userCancelled and terminate.
4. ShellCommand can now return, but it must not send a zero byte, as the A2 is not expecting it - and will therefore later misinterpret it.
Maybe the original hardware needs another handling, then differentiation of behavior in shell.go becomes necessary.
* Moved boot text out of IIgs copyright message area.
Having the boot text start at the left border of the third line makes it look nice on the cold boot screen of all Apple II's - and there's where the user sees it for some time while waiting for the RPi to come up.
* Several adjustements:
- Get latest Go version as of now.
- Nowadays (?) GitHub 'git clone' seems to only work with a GitHub account. Therefore the zip download workaround. The becomes hopefully unnecessary soon with Go module magic.
- Use 'go mod tidy' to update .sum file for now.
- Error handling for an empty drive 2 is currently not exactly great, so download Total Replay for drive 2. Unfortunately there's no stable URL as of now.
- Use $USER and $HOME instead of hardcoded values.
- Removed deprecated syslog output directives.
* Added brief fork description.
* Added ProDOS-Utilities reference.
* Reverted back to using 'git clone'.
I've no idea why git acted up the other day :-( Now, everything is back to normal...
* Ignore Pico build directory.
* Updated from https://github.com/a2retrosystems/A2retroNET
* Updated from https://github.com/a2retrosystems/A2retroNET
At this point, nothing at all is done on an A2 reset. This can likely be improved. However, Apple2-IO-RPi doesn't seem to handle A2 reset exactly gracefully anyhow.
In general, it seems desirable to introduce some simple framing protocol - like SLIP - that allows to recover from an A2 reset in the middle of an Apple2-IO-RPi command execution.
Such a framing protocol would allow to introduce different frame types. One frame type could then be an A2 reset frame sent by the A2retroNET firmware.
* Make use of brand new stable Total Replay download URL.
Thanks to 4am :-)
* Fixed typos.
* Clone upstream ProDOS-Utilities.
My ProDOS-Utilities pull request was merged.
* Added support for boards without LED.
* Updated link.
* Adjusted to the current A2retroNET hardware.
* Removed support for the Pico W.
* Updated URL.
* Updated URL.
* Make use A2Pico library.
* Added link to A2Pico.
* Remove intermediates from repo.
* Build intermediates from Pico build.
* Have LED reflect status of logic ACM connection.
* Update upstream repo references.
* Adjust build instructions.
* Update README.md
* Fix build and update dependencies
* Fix binary comparison
* Fix firware bug on classic hardware
---------
Co-authored-by: Oliver Schmidt <ol.sc@web.de>
301 lines
4.1 KiB
NASM
Executable File
301 lines
4.1 KiB
NASM
Executable File
; Copyright Terence J. Boldt (c)2021-2024
|
|
; Use of this source code is governed by an MIT
|
|
; license that can be found in the LICENSE file.
|
|
|
|
; This file contains the source for the SHELL
|
|
; application that runs on the Apple II to talk
|
|
; to the Raspberry Pi
|
|
|
|
;ProDOS Zero Page
|
|
Command = $42 ;ProDOS Command
|
|
Unit = $43 ;ProDOS unit (SDDD0000)
|
|
BufferLo = $44
|
|
BufferHi = $45
|
|
BlockLo = $46
|
|
BlockHi = $47
|
|
|
|
; ProDOS Error Codes
|
|
IOError = $27
|
|
NoDevice = $28
|
|
WriteProtect = $2B
|
|
|
|
InputByte = $c08e
|
|
OutputByte = $c08d
|
|
InputFlags = $c08b
|
|
OutputFlags = $c087
|
|
|
|
ResetCommand = $00
|
|
ReadBlockCommand = $01
|
|
WriteBlockCommand = $02
|
|
GetTimeCommand = $03
|
|
ChangeDriveCommand = $04
|
|
ExecCommand = $05
|
|
LoadFileCommand = $06
|
|
SaveFileCommand = $07
|
|
MenuCommand = $08
|
|
ShellCommand = $09
|
|
|
|
InputString = $fd6a
|
|
StringBuffer = $0200
|
|
PrintChar = $fded
|
|
Keyboard = $c000
|
|
ClearKeyboard = $c010
|
|
Home = $fc58
|
|
Wait = $fca8
|
|
PromptChar = $33
|
|
Read80Col = $c01f
|
|
TextPage1 = $c054
|
|
TextPage2 = $c055
|
|
|
|
htab = $24
|
|
vtab = $25
|
|
BasL = $28
|
|
htab80 = $057b
|
|
BasCalc = $fbc1
|
|
|
|
LastChar = $06
|
|
SlotL = $fe
|
|
SlotH = $ff
|
|
ESC = $9b
|
|
|
|
.org $2000
|
|
ldx #$07 ; start at slot 7
|
|
DetectSlot:
|
|
ldy #$00
|
|
lda #$fc
|
|
sta SlotL
|
|
txa
|
|
ora #$c0
|
|
sta SlotH
|
|
lda (SlotL),y
|
|
bne nextSlot
|
|
iny
|
|
lda (SlotL),y
|
|
bne nextSlot
|
|
iny
|
|
lda (SlotL),y
|
|
cmp #$17
|
|
bne nextSlot
|
|
iny
|
|
lda (SlotL),y
|
|
cmp #$14
|
|
bne nextSlot
|
|
txa
|
|
asl
|
|
asl
|
|
asl
|
|
asl
|
|
tax
|
|
clc
|
|
bcc Init
|
|
nextSlot:
|
|
dex
|
|
bne DetectSlot
|
|
rts
|
|
|
|
Init:
|
|
lda #$8d
|
|
jsr $c300 ; force 80 columns
|
|
|
|
ldy #$00
|
|
PrintString:
|
|
lda Text,y
|
|
beq Start
|
|
ora #$80
|
|
jsr PrintChar
|
|
iny
|
|
bne PrintString
|
|
|
|
Start:
|
|
lda LastChar
|
|
pha
|
|
bit ClearKeyboard
|
|
; lda #ResetCommand
|
|
; jsr SendByte
|
|
lda #ShellCommand
|
|
jsr SendByte
|
|
jsr DumpOutput
|
|
pla
|
|
sta LastChar
|
|
rts
|
|
|
|
DumpOutput:
|
|
jsr GetByte
|
|
cmp #$00
|
|
beq endOutput
|
|
pha
|
|
jsr ClearCursor
|
|
pla
|
|
cmp #'H'
|
|
beq setColumn
|
|
cmp #'V'
|
|
beq setRow
|
|
cmp #'C'
|
|
beq clearScreen
|
|
cmp #'T'
|
|
beq setTop
|
|
cmp #'B'
|
|
beq setBottom
|
|
cmp #'U'
|
|
beq moveUp
|
|
jsr PrintChar
|
|
jsr SetCursor
|
|
jmp DumpOutput
|
|
endOutput:
|
|
rts
|
|
clearScreen:
|
|
jsr Home
|
|
jsr SetCursor
|
|
jmp DumpOutput
|
|
setColumn:
|
|
jsr GetByte
|
|
sta htab
|
|
sta htab80
|
|
jsr SetCursor
|
|
jmp DumpOutput
|
|
setRow:
|
|
jsr GetByte
|
|
sta vtab
|
|
jsr BasCalc
|
|
jsr SetCursor
|
|
jmp DumpOutput
|
|
setTop:
|
|
jsr GetByte
|
|
sta $22
|
|
jmp DumpOutput
|
|
setBottom:
|
|
jsr GetByte
|
|
sta $23
|
|
jmp DumpOutput
|
|
moveUp:
|
|
dec vtab
|
|
lda vtab
|
|
jsr BasCalc
|
|
jsr SetCursor
|
|
jmp DumpOutput
|
|
|
|
SendByte:
|
|
pha
|
|
waitWrite:
|
|
lda InputFlags,x
|
|
rol
|
|
rol
|
|
bcs waitWrite
|
|
pla
|
|
sta OutputByte,x
|
|
.if HW_TYPE = 0
|
|
lda #$1e ; set bit 0 low to indicate write started
|
|
sta OutputFlags,x
|
|
finishWrite:
|
|
lda InputFlags,x
|
|
rol
|
|
rol
|
|
bcc finishWrite
|
|
lda #$1f
|
|
sta OutputFlags,x
|
|
.endif
|
|
rts
|
|
|
|
GetByte:
|
|
.if HW_TYPE = 0
|
|
lda #$1d ;set read flag low
|
|
sta OutputFlags,x
|
|
.endif
|
|
waitRead:
|
|
lda InputFlags,x
|
|
rol
|
|
bcc readByte
|
|
bit Keyboard ;keypress will abort waiting to read
|
|
bpl waitRead
|
|
keyPressed:
|
|
lda InputFlags,x
|
|
rol
|
|
rol
|
|
bcs keyPressed
|
|
lda Keyboard ;send keypress to RPi
|
|
and #$7f
|
|
sta OutputByte,x
|
|
bit ClearKeyboard
|
|
.if HW_TYPE = 0
|
|
lda #$1c ;set write flag low too
|
|
sta OutputFlags,x
|
|
finishKeyPress:
|
|
lda InputFlags,x
|
|
rol
|
|
rol
|
|
bcc finishKeyPress
|
|
lda #$1d ;set flags back for reading
|
|
sta OutputFlags,x
|
|
.endif
|
|
jmp waitRead
|
|
readByte:
|
|
lda InputByte,x
|
|
.if HW_TYPE = 0
|
|
pha
|
|
lda #$1f ;set all flags high
|
|
sta OutputFlags,x
|
|
finishRead:
|
|
lda InputFlags,x
|
|
rol
|
|
bcc finishRead
|
|
pla
|
|
.endif
|
|
clc ;success
|
|
end:
|
|
rts
|
|
|
|
SetCursor:
|
|
lda htab80 ;get horizontal location / 2
|
|
lsr
|
|
tay
|
|
lda TextPage2
|
|
bcc setChar
|
|
lda TextPage1
|
|
setChar:
|
|
lda (BasL),y
|
|
sta LastChar ; save so ClearCursor will pick it up
|
|
cmp #$e0
|
|
bpl lowerCase
|
|
cmp #$c0
|
|
bpl upperCase
|
|
cmp #$a0
|
|
bpl symbol
|
|
cmp #$80
|
|
bpl noop
|
|
symbol:
|
|
lowerCase:
|
|
invert:
|
|
eor #$80
|
|
jmp storeChar
|
|
upperCase:
|
|
and #$1f
|
|
jmp storeChar
|
|
noop:
|
|
storeChar:
|
|
sta (BasL),y
|
|
lda TextPage1
|
|
rts
|
|
|
|
ClearCursor:
|
|
lda htab80 ;get horizontal location / 2
|
|
lsr
|
|
tay
|
|
lda TextPage2
|
|
bcc restoreChar
|
|
lda TextPage1
|
|
restoreChar:
|
|
lda LastChar
|
|
sta (BasL),y
|
|
lda TextPage1
|
|
rts
|
|
|
|
Text:
|
|
.if HW_TYPE = 0
|
|
.byte "Apple2-IO-RPi Shell Version 000F",$8d
|
|
.else
|
|
.byte "Apple2-IO-RPi Shell Version 800F",$8d
|
|
.endif
|
|
.byte "(c)2020-2024 Terence J. Boldt",$8d
|
|
.byte $8d
|
|
.byte $00
|