NEW
  AUTO 3,1
				.LIST OFF
*--------------------------------------
* DLG.New hParent,W,H,pTitle			5
*--------------------------------------
DLG.New			lda #S.OBJ.T.DLG
				jsr OBJ.Create
				bcs .9

				ldy #S.OBJ.pTitle
				jsr OBJ.PullWordY

				jsr OBJ.PullHW

				lda #S.OBJ.F.bTitle+S.OBJ.F.bHBorder+S.OBJ.F.bVBorder
				ldy #S.OBJ.F
				sta (ZPObjPtr),y

				>PULLA
				ldy #S.OBJ.hParent
				sta (ZPObjPtr),y

				>SYSCALL2 GetMemPtr
				>STYA ZPPtr2

				ldy #S.OBJ.W
				lda (ZPPtr2),y
				sec
				sbc (ZPObjPtr),y
				lsr
				ldy #S.OBJ.X1
				sta (ZPObjPtr),y

				ldy #S.OBJ.H
				lda (ZPPtr2),y
				sec
				sbc (ZPObjPtr),y
				lsr
				ldy #S.OBJ.Y1
				sta (ZPObjPtr),y

				jsr OBJ.SetX2Y2

				lda hObj
*				clc
				rts

.9				>POP 5
				rts
*--------------------------------------
MAN
SAVE usr/src/lib/libtui.s.dlg
LOAD usr/src/lib/libtui.s
ASM
