A2osX/BIN/CC.S.DIR.txt

NEW
  AUTO 3,1
*--------------------------------------
CC.DIR			jsr CC.GetNextCharNB
				bcs .99

				cmp #'!'				#!/bin/cc
				bne .1

				jmp CC.SkipLine

.1				>LDYA L.CC.DIRS
				jsr CC.LookupID
				bcs .91

				jmp (J.CC.DIRS,x)

.91				lda #E.CSYN
				sec
.99				rts
*--------------------------------------
CC.DIR.DEFINE	clc
				bit bPass2
				bmi .8
				
				jsr CC.CheckSpace
				bcs .99

				jsr CC.IsLetter
				bcs .90

				ldx #SYM.SC.DEFINE
				>LDA.G CC.hDefines
				jsr CC.SYM.NewKey
				bcs .99

				>STYA ZPPtr1			SymID

				jsr CC.SkipX

				jsr CC.CheckSpace
				bcs .99

				ldy #$ff

.1				iny
				lda (ZPLineBufPtr),y
				beq .2

				cmp #C.CR
				bne .1

				dey

.2				iny

				phy

				>PUSHB.G CC.hDefines
				>PUSHW ZPPtr1			SymID
				>PUSHW ZPLineBufPtr

				ply
				lda #0
				>PUSHYA					DataLen

				>SYSCALL SListAddData
				bcs .99

.8				jmp CC.SkipLine

.90				lda #E.CSYN
				sec
.99				rts
*--------------------------------------
CC.DIR.INCLUDE	lda #0					>STZ.G PathBuf
				sta (pData)

				jsr CC.CheckSpace
				bcs .99

				cmp #'"'
				beq .1

				cmp #'<'
				bne .90

				>PUSHW L.ENV.INCLUDE
				>PUSHW pData			>PUSHEA.G PathBuf
				>SYSCALL GetEnv
				bcs .90
				
				lda #'>'

.1				sta ArgIndex

				ldy #$ff

.2				iny
				lda (pData),y
				bne .2

.3				jsr CC.GetNextChar
				beq .90

				cmp ArgIndex
				beq .4

				sta (pData),y
				iny
				cpy #MLI.MAXPATH
				bne .3

.90				lda #E.CSYN
				sec
.99				rts

.4				phy
				jsr CC.GetNextChar		skip " or >
				ply

				lda #0
				sta (pData),y			terminate string
				
				dey
				lda (pData),y
				cmp #'h'
				bne .5

				bit bPass2
				bpl .5
				
				clc
				rts

.5				>LDYA pData
				jmp CC.FIO.FOpen
*--------------------------------------
MAN
SAVE usr/src/bin/cc.s.dir
LOAD usr/src/bin/cc.s
ASM