mirror of
https://github.com/A2osX/A2osX.git
synced 2025-02-13 13:30:36 +00:00
106 lines
2.0 KiB
Plaintext
106 lines
2.0 KiB
Plaintext
PR#3
|
||
PREFIX /A2OSX.BUILD
|
||
LOMEM $A00
|
||
INC 1
|
||
AUTO 6
|
||
*--------------------------------------
|
||
* EVT.GetEvents :
|
||
* IN :
|
||
* OUT :
|
||
* CS = no event, A = ERROR
|
||
* CC * event in YA
|
||
* (pEvent)
|
||
*--------------------------------------
|
||
EVT.GetEvents lda #EvtMgr.Table
|
||
sta pEvent point to start of event list
|
||
|
||
stz EvtMgr.Count reset Size
|
||
|
||
lda K.IrkMgr.VBL do we have IRQ enabled for VBL ?
|
||
bpl .10 no, regular poll
|
||
|
||
lda K.IrkMgr.VBLINT
|
||
beq .3 no
|
||
|
||
dec K.IrkMgr.VBLINT
|
||
bra .11
|
||
|
||
.10 lda VBL get VLINE status
|
||
tax
|
||
eor EvtMgr.VBLState
|
||
bpl .3 no change,no tick
|
||
txa
|
||
sta EvtMgr.VBLState save new
|
||
bpl .3 Up2down transition,no tick
|
||
|
||
.11 inc A2osX.TIMER16
|
||
bne .1
|
||
inc A2osX.TIMER16+1
|
||
|
||
.1 dec EvtMgr.HZ.CNT
|
||
bne .3 not yet 100ms
|
||
|
||
ldx A2osX.HZ
|
||
stx EvtMgr.HZ.CNT
|
||
|
||
lda #S.EVT.F.T10TH
|
||
|
||
dec EvtMgr.10TH.CNT
|
||
bne .2
|
||
|
||
ldx #10
|
||
stx EvtMgr.10TH.CNT
|
||
|
||
ora #S.EVT.F.T1SEC
|
||
|
||
.2 sta (pEvent)
|
||
jsr EVT.GetEvents.Add
|
||
.3
|
||
sec
|
||
lda EvtMgr.Count if 0, exit with CS (from cmp), and A=0 "no event"
|
||
beq .9
|
||
|
||
.8 clc
|
||
.9 rts
|
||
*--------------------------------------
|
||
EVT.GetEvents.Add
|
||
inc EvtMgr.Count Add one event to Queue
|
||
|
||
lda pEvent
|
||
clc
|
||
adc #S.EVT
|
||
sta pEvent
|
||
rts if CS, EVT queue full!!! ($100)
|
||
*--------------------------------------
|
||
EVT.DestroyEvent
|
||
lda (pEvent)
|
||
beq .9
|
||
|
||
bit #S.EVT.F.hMEM1
|
||
beq .1
|
||
|
||
pha
|
||
ldy #S.EVT.DATALO
|
||
lda (pEvent),y
|
||
jsr K.FreeMem.A
|
||
pla
|
||
|
||
.1 bit #S.EVT.F.hMEM2
|
||
beq .2
|
||
|
||
ldy #S.EVT.DATAHI
|
||
lda (pEvent),y
|
||
jsr K.FreeMem.A
|
||
|
||
.2 lda #0
|
||
sta (pEvent)
|
||
dec EvtMgr.Count
|
||
.9 rts
|
||
*--------------------------------------
|
||
EvtMgr.Idx .BS 1
|
||
*--------------------------------------
|
||
MAN
|
||
SAVE /A2OSX.SRC/SYS/KERNEL.S.EVT
|
||
LOAD /A2OSX.SRC/SYS/KERNEL.S
|
||
ASM
|