; Bunker/Sub part of Selena Age

; Ein U-Boot holt uns dann hier raus
; Und du bist der Kapitaen

; by deater (Vince Weaver) <vince@deater.net>

; Zero Page
	.include "zp.inc"
	.include "hardware.inc"
	.include "common_defines.inc"
	.include "common_routines.inc"

sub_start:
	;===================
	; init screen
	jsr	TEXT
	jsr	HOME
	bit	KEYRESET

	bit	SET_GR
	bit	PAGE0
	bit	LORES
	bit	FULLGR

	;=================
	; set up location
	;=================

	lda	#<locations
	sta	LOCATIONS_L
	lda	#>locations
	sta	LOCATIONS_H


	lda	#0
	sta	DRAW_PAGE
	sta	LEVEL_OVER

	; init cursor

	lda	#20
	sta	CURSOR_X
	sta	CURSOR_Y

	;=================
	; init vars

	; set up initial location

	jsr	change_location

	lda	#1
	sta	CURSOR_VISIBLE		; visible at first

	lda	#0
	sta	ANIMATE_FRAME

	; in theory can't be here unless sub is at starting place
	sta	SUB_LOCATION
	sta	SUB_DIRECTION

game_loop:
	;=================
	; reset things
	;=================

	lda	#0
	sta	IN_SPECIAL
	sta	IN_RIGHT
	sta	IN_LEFT

	;====================================
	; copy background to current page
	;====================================

	jsr	gr_copy_to_current

	;====================================
	; handle special-case forground logic
	;====================================

	lda	LOCATION

	cmp	#SUB_BOOK_OPEN
	beq	mist_book_animation

	cmp	#SUB_INSIDE_FRONT_MOVING
	beq	fg_draw_sub

	jmp	nothing_special

mist_book_animation:

	jsr	draw_mist_animation
	jmp	nothing_special

fg_draw_sub:
	jsr	draw_sub
	jmp	nothing_special

nothing_special:

	;====================================
	; draw pointer
	;====================================

	jsr	draw_pointer

	;====================================
	; page flip
	;====================================

	jsr	page_flip

	;====================================
	; handle keypress/joystick
	;====================================

	jsr	handle_keypress


	;====================================
	; inc frame count
	;====================================

	inc	FRAMEL
	bne	room_frame_no_oflo
	inc	FRAMEH
room_frame_no_oflo:

	;====================================
	; check level over
	;====================================

	lda	LEVEL_OVER
	bne	really_exit
	jmp	game_loop

really_exit:
	jmp	end_level



	;===================================
	; goto selena
	;	go back out bunker door
        ;===================================

goto_selena:
	lda	#$ff
	sta	LEVEL_OVER

	lda     #SELENA_BUNKER		; outside bunker door
	sta	LOCATION

	lda	#DIRECTION_N
	sta	DIRECTION

	lda	#LOAD_SELENA
	sta	WHICH_LOAD

	rts



	;===============================
	; draw mist book animation
	;===============================

draw_mist_animation:
	; handle animated linking book

	lda	ANIMATE_FRAME
	cmp	#6
	bcc	mist_book_good			; blt

	lda	#0
	sta	ANIMATE_FRAME

mist_book_good:

	asl
	tay
	lda	mist_movie,Y
	sta	INL
	lda	mist_movie+1,Y
	sta	INH

	lda	#24
	sta	XPOS
	lda	#12
	sta	YPOS

	jsr	put_sprite_crop

	lda	FRAMEL
	and	#$f
	bne	done_animate_mist_book

	inc	ANIMATE_FRAME

done_animate_mist_book:
	rts


	;==========================
	; includes
	;==========================

	; level graphics
	.include	"graphics_sub/sub_graphics.inc"

	; puzzles
	.include	"sub_puzzle.s"

	; linking books
	.include	"link_book_mist.s"

	; level data
	.include	"leveldata_sub.inc"

	; sound
	.include	"simple_sounds.s"





