TO TTREE :N
TPAIR :N RT 45 TPAIR :N BK :N * 3
END

TO TPAIR :N
TREE :N RT 180 TREE :N SETH 0
END

TO TREE :LENGTH
IF :LENGTH < 2 [STOP]
LT 45 FD :LENGTH
TREE :LENGTH / 2
BK :LENGTH RT 90 FD :LENGTH
TREE :LENGTH / 2
BK :LENGTH LT 45
END

TO CTREE
PU
MAKE "X ((RANDOM 200) - 100)
MAKE "Y ((RANDOM 100) - 50)
MAKE "XY SENTENCE :X :Y
SETPOS :XY
PD
TTREE (RANDOM 7) + 4
SETBG RANDOM 7
END

TO DSR
CS
PU SETPOS [-45 75]
PD SETH 180
FD 100 RT 90 FD 50 RT 90 FD 50 RT 90 FD 50
PU SETPOS [25 25] LT 180
PD FD 50 LT 90 FD 25 LT 90 FD 50 RT 90 FD 25 RT 90 FD 50
PU SETPOS [45 -25]
PD RT 90 FD 50 RT 90 FD 50
PU SETPOS [-110 -45]
PD FD 220
LT 90 PU FD 10 LT 45
REPEAT 6 [WAIT 15 RT 90 WAIT 15 LT 90]
END

TO SUN
SETPC 4
PU
SETPOS [-110 80]
PD
REPEAT 36 [RT 5 FD 2 RT 5]
REPEAT 9 [RT 40 PU SETPOS [-100 80] FD 25 PD BK 10]
END

TO WATER
PU SETPC 5 SETPOS [140 0]
PD SETH 180 FD 119 RT 90 FD 280 RT 90 FD 119
RT 45
REPEAT 20 [FD 10 RT 90 FD 10 LT 90]
BK 10 FILL
END

TO BOAT
PU
SETPC 3
SETH 90
SETPOS [0 20]
PD
FD 50 RT 135 FD 35 RT 45
PU FD 50 PD
RT 45 FD 35 RT 135 FD 50
LT 90
FD 75 RT 30
SETPC 1
REPEAT 3 [RT 120 FD 70]
END

TO FISH
PU SETPOS [0 -50]
PD SETPC 1 REPEAT 40 [FD 1 RT 3] RT 90
REPEAT 40 [FD 1 RT 3]
END

TO MOVEFISH
MAKE "X ((RANDOM 280) - 140)
MAKE "Y (-(RANDOM 100))
MAKE "XY SENTENCE :X :Y
SETPOS :XY
WAIT 60
END

TO OCEAN
CS
SUN
BOAT
WATER
FISH
SETH 90 PU
REPEAT 5 [MOVEFISH]
END

TO POLYSPI4 :S :A :D :L
IF :S < :L [STOP]
FD :S RT :A
POLYSPI4 (:S - :D) :A :D :L
END

TO WARGAMES
REPEAT 4 [PRINT "]
SS
SETCURSOR [12 21] PRINT [DEMOSCENE GAMBIT]
HT PU
.CALL 22810
WAIT 60
SETPOS [-70 10] SETH 0 ST PD
REPEAT 36 [FD 2 RT 4]
SETH 90
FD 10 RT 90
POLYSPI4 3 18 0.05 0.5
HT
WAIT 60
FS
END

TO POLY
CS FS ST
SETH 0
PU SETX -120 PD
POLYSPI4 100 122 2 1
PU SETPOS [10 -100] PD
SETH 0 POLYSPI4 100 88 2 1
HT
WAIT 180
END

TO BIRD :X :Y
PU SETX :X SETY :Y
PD SETH 10
REPEAT 42 [FD 0.5 RT 3]
LT 90
REPEAT 42 [FD 0.5 RT 3]
END

TO MYST
CS HT
SETBG 1
.CALL 23084
SETPC 0 ST
BIRD -75 75
BIRD 0 100
SETPC 1
HT WAIT 60 ST
END

TO CREDITS
SS
REPEAT 4 [PRINT "]
SETCURSOR [1 21] PRINT [CODE:  DEATER]
SETCURSOR [15 21] PRINT [\-\=DESIRE\=\-]
SETCURSOR [28 21] PRINT [MUSIC: mA2E]
SETCURSOR [12 23] PRINT [APPLE II FOREVER]
.CALL 7653
END

TO DEMO
CS FS ST
.BLOAD "MA2E.PT3 4096
.BLOAD "MUSIC 19456
.BLOAD "MAP 2048
.CALL 19456
DSR
OCEAN
POLY
WARGAMES
MYST
CS SETBG 0
REPEAT 4 [ CTREE ]
CREDITS
END

MAKE "STARTUP [DEMO]
