diff --git a/interlace_demo/Makefile b/interlace_demo/Makefile
new file mode 100644
index 00000000..c2bee1d0
--- /dev/null
+++ b/interlace_demo/Makefile
@@ -0,0 +1,41 @@
+include ../Makefile.inc
+
+DOS33 = ../dos33fs-utils/dos33
+PNG_TO_40x96 = ../gr-utils/png_to_40x96
+PNG_TO_40x48D = ../gr-utils/png_to_40x48d
+
+
+all:	interlace.dsk
+
+interlace.dsk:	INTERLACE HELLO
+	$(DOS33) -y interlace.dsk SAVE A HELLO
+	$(DOS33) -y interlace.dsk BSAVE -a 0x1000 INTERLACE
+
+####
+
+HELLO:  hello.bas
+	../asoft_basic-utils/tokenize_asoft < hello.bas > HELLO
+
+
+####
+
+INTERLACE:	interlace.o
+	ld65 -o INTERLACE interlace.o -C ../linker_scripts/apple2_1000.inc
+
+interlace.o:	interlace.s gr_copy.s \
+	k_40_48d.inc
+	ca65 -o interlace.o interlace.s -l interlace.lst
+
+####
+
+k_40_48d.inc:	k_40_48d.png
+	$(PNG_TO_40x48D) asm k_40_48d.png k > k_40_48d.inc
+
+###
+
+
+install:	
+
+
+clean:		
+		rm -f *~ *.o *.lst *.inc INTERLACE HELLO
diff --git a/interlace_demo/gr_copy.s b/interlace_demo/gr_copy.s
new file mode 100644
index 00000000..acd83f6f
--- /dev/null
+++ b/interlace_demo/gr_copy.s
@@ -0,0 +1,58 @@
+	;=========================================================
+	; gr_copy_to_current, 40x48 version
+	;=========================================================
+	; copy 0xc00 to DRAW_PAGE
+	;
+	; 45 + 2 + 120*(8*9 + 5) -1 + 6 = 9292
+
+gr_copy_to_current:
+
+	lda	DRAW_PAGE					; 3
+	clc							; 2
+	adc	#$4						; 2
+	sta	gr_copy_line+5					; 4
+	sta	gr_copy_line+11					; 4
+	adc	#$1						; 2
+	sta	gr_copy_line+17					; 4
+	sta	gr_copy_line+23					; 4
+	adc	#$1						; 2
+	sta	gr_copy_line+29					; 4
+	sta	gr_copy_line+35					; 4
+	adc	#$1						; 2
+	sta	gr_copy_line+41					; 4
+	sta	gr_copy_line+47					; 4
+							;===========
+							;	45
+
+	ldy	#119		; for early ones, copy 120 bytes	; 2
+
+gr_copy_line:
+	lda	$C00,Y		; load a byte (self modified)		; 4
+	sta	$400,Y		; store a byte (self modified)		; 5
+
+	lda	$C80,Y		; load a byte (self modified)		; 4
+	sta	$480,Y		; store a byte (self modified)		; 5
+
+	lda	$D00,Y		; load a byte (self modified)		; 4
+	sta	$500,Y		; store a byte (self modified)		; 5
+
+	lda	$D80,Y		; load a byte (self modified)		; 4
+	sta	$580,Y		; store a byte (self modified)		; 5
+
+	lda	$E00,Y		; load a byte (self modified)		; 4
+	sta	$600,Y		; store a byte (self modified)		; 5
+
+	lda	$E80,Y		; load a byte (self modified)		; 4
+	sta	$680,Y		; store a byte (self modified)		; 5
+
+	lda	$F00,Y		; load a byte (self modified)		; 4
+	sta	$700,Y		; store a byte (self modified)		; 5
+
+	lda	$F80,Y		; load a byte (self modified)		; 4
+	sta	$780,Y		; store a byte (self modified)		; 5
+
+	dey			; decrement pointer			; 2
+	bpl	gr_copy_line	;					; 2nt/3
+
+	rts								; 6
+
diff --git a/interlace_demo/hello.bas b/interlace_demo/hello.bas
new file mode 100644
index 00000000..2dc04efe
--- /dev/null
+++ b/interlace_demo/hello.bas
@@ -0,0 +1,2 @@
+  10  PRINT "INTERLACE V0.1"
+ 100  PRINT  CHR$ (4)"BRUN INTERLACE"
diff --git a/interlace_demo/interlace.dsk b/interlace_demo/interlace.dsk
new file mode 100644
index 00000000..3990e6ca
Binary files /dev/null and b/interlace_demo/interlace.dsk differ
diff --git a/interlace_demo/interlace.s b/interlace_demo/interlace.s
new file mode 100644
index 00000000..1d1013b2
--- /dev/null
+++ b/interlace_demo/interlace.s
@@ -0,0 +1,350 @@
+; Display a 40x48d lo-res image
+
+; Uses the 40x48d page1/page2 every-1-scanline pageflip mode
+
+; by deater (Vince Weaver) <vince@deater.net>
+
+; Zero Page
+FRAMEBUFFER	= $00	; $00 - $0F
+YPOS		= $10
+YPOS_SIN	= $11
+CH		= $24
+CV		= $25
+GBASL		= $26
+GBASH		= $27
+BASL		= $28
+BASH		= $29
+FRAME		= $60
+BLARGH		= $69
+DRAW_PAGE	= $EE
+LASTKEY		= $F1
+PADDLE_STATUS	= $F2
+TEMP		= $FA
+WHICH		= $FB
+
+; Soft Switches
+KEYPRESS= $C000
+KEYRESET= $C010
+SET_GR	= $C050 ; Enable graphics
+FULLGR	= $C052	; Full screen, no text
+PAGE0	= $C054 ; Page0
+PAGE1	= $C055 ; Page1
+LORES	= $C056	; Enable LORES graphics
+PADDLE_BUTTON0 = $C061
+PADDL0	= $C064
+PTRIG	= $C070
+
+; ROM routines
+
+TEXT	= $FB36				;; Set text mode
+HOME	= $FC58				;; Clear the text screen
+WAIT	= $FCA8				;; delay 1/2(26+27A+5A^2) us
+
+MAX	= 1
+
+	lda	#$ff
+	sta	WHICH
+
+start_over:
+	inc	WHICH
+	lda	WHICH
+	cmp	#MAX
+	bne	in_range
+	lda	#0
+	sta	WHICH
+
+in_range:
+
+	;===================
+	; init screen
+	jsr	TEXT
+	jsr	HOME
+	bit	KEYRESET
+
+	;===================
+	; init vars
+
+	lda	#0
+	sta	DRAW_PAGE
+
+	;=============================
+	; Load graphic page0
+
+	lda	#$0c
+	sta	BASH
+	lda	#$00
+	sta	BASL                    ; load image to $c00
+
+	lda	WHICH
+	asl
+	asl				; which*4
+	tay
+
+	lda	pictures,Y
+	sta	GBASL
+	lda	pictures+1,Y
+	sta	GBASH
+	jsr	load_rle_gr
+
+	lda	#4
+	sta	DRAW_PAGE
+
+	jsr	gr_copy_to_current	; copy to page1
+
+	; GR part
+	bit	PAGE1
+	bit	LORES							; 4
+	bit	SET_GR							; 4
+	bit	FULLGR							; 4
+
+	jsr	wait_until_keypressed
+
+
+	;=============================
+	; Load graphic page1
+
+	lda	#$0c
+	sta	BASH
+	lda	#$00
+	sta	BASL                    ; load image to $c00
+
+	lda	WHICH
+	asl
+	asl				; which*4
+	tay
+
+	lda	pictures+2,Y
+	sta	GBASL
+	lda	pictures+3,Y
+	sta	GBASH
+	jsr	load_rle_gr
+
+	lda	#0
+	sta	DRAW_PAGE
+
+	jsr	gr_copy_to_current
+
+	; GR part
+	bit	PAGE0
+
+	jsr	wait_until_keypressed
+
+
+	;==============================
+	; setup graphics for vapor lock
+	;==============================
+
+	; Clear Page0
+	lda	#$0
+	sta	DRAW_PAGE
+	lda	#$44
+	jsr	clear_gr
+
+	; Make screen half green
+	lda	#$11
+	ldy	#24
+	jsr	clear_page_loop
+
+
+	;=====================================================
+	; attempt vapor lock
+	;  by reading the "floating bus" we can see most recently
+	;  written value of the display
+	; we look for $55 (which is the grey line)
+	;=====================================================
+	; See:
+	;	Have an Apple Split by Bob Bishop
+        ;	Softalk, October 1982
+
+	; Challenges: each scan line scans 40 bytes.
+	; The blanking happens at the *beginning*
+	; So 65 bytes are scanned, starting at adress of the line - 25
+
+	; the scan takes 8 cycles, look for 4 repeats of the value
+	; to avoid false positive found if the horiz blanking is mirroring
+	; the line (max 3 repeats in that case)
+
+vapor_lock_loop:		; first make sure we have all zeroes
+	LDA #$11
+zxloop:
+	LDX #$04
+wiloop:
+	CMP $C051
+	BNE zxloop
+	DEX
+	BNE wiloop
+
+	LDA #$44		; now look for our border color (4 times)
+zloop:
+	LDX #$04
+qloop:
+	CMP $C051
+	BNE zloop
+	DEX
+	BNE qloop
+
+	; found first line of black after green, at up to line 26 on screen
+        ; so we want roughly 22 lines * 4 = 88*65 = 5720 + 4550 = 10270
+	; - 65 (for the scanline we missed) = 10205 - 12 = 10193
+
+	jsr	gr_copy_to_current		; 6+ 9292
+	; 10193 - 9298 = 895
+	; Fudge factor (unknown) -30 = 865
+
+	; GR part
+	bit	LORES							; 4
+	bit	SET_GR							; 4
+	bit	FULLGR							; 4
+
+	; Try X=88 Y=2 cycles=893 R2
+
+	nop
+        ldy     #2							; 2
+loopA:
+        ldx	#88							; 2
+loopB:
+        dex                                                             ; 2
+        bne     loopB                                                   ; 2nt/3
+
+        dey                                                             ; 2
+        bne     loopA                                                   ; 2nt/3
+
+        jmp     display_loop
+.align  $100
+
+
+	;================================================
+	; Display Loop
+	;================================================
+	; each scan line 65 cycles
+	;       1 cycle each byte (40cycles) + 25 for horizontal
+	;       Total of 12480 cycles to draw screen
+	; Vertical blank = 4550 cycles (70 scan lines)
+	; Total of 17030 cycles to get back to where was
+
+	; We want to alternate between page1 and page2 every 65 cycles
+        ;       vblank = 4550 cycles to do scrolling
+
+
+	; 2 + 48*(  (4+2+25*(2+3)) + (4+2+23*(2+3)+4+5)) + 9)
+	;     48*[(6+125)-1] + [(6+115+10)-1]
+
+display_loop:
+
+	ldy	#96						; 2
+
+outer_loop:
+
+	bit	PAGE0						; 4
+	ldx	#12		; 65 cycles with PAGE0		; 2
+page0_loop:			; delay 61+bit
+	dex							; 2
+	bne	page0_loop					; 2/3
+
+
+	; bit(4) -1(fallthrough) + loop*5 -1(fallthrouh)+4 extra = 61
+	; 5L = 55
+
+	bit	PAGE1						; 4
+	ldx	#11		; 65 cycles with PAGE1		; 2
+				;
+page1_loop:			; delay 115+(7 loop)+4 (bit)+4(extra)
+	dex							; 2
+	bne	page1_loop					; 2/3
+
+	dey							; 2
+	bne	outer_loop					; 2/3
+
+
+
+	;======================================================
+	; We have 4550 cycles in the vblank, use them wisely
+	;======================================================
+	; do_nothing should be      4550+1 -2-9 -7= 4533
+
+	jsr	do_nothing				; 6
+
+	lda	KEYPRESS				; 4
+	bpl	no_keypress				; 3
+	jmp	start_over
+no_keypress:
+
+	jmp	display_loop				; 3
+
+
+
+	;=================================
+	; do nothing
+	;=================================
+	; and take 4533-6 = 4527 cycles to do it
+do_nothing:
+
+	; Try X=4 Y=174 cycles=4525 R2
+
+	nop	; 2
+
+	ldy	#174							; 2
+loop1:
+	ldx	#4							; 2
+loop2:
+	dex								; 2
+	bne	loop2							; 2nt/3
+
+	dey								; 2
+	bne	loop1							; 2nt/3
+
+
+	rts							; 6
+
+
+
+	;==================================
+	; HLINE
+	;==================================
+
+	; Color in A
+	; Y has which line
+hline:
+	pha							; 3
+	ldx	gr_offsets,y					; 4+
+	stx	hline_loop+1					; 4
+	lda	gr_offsets+1,y					; 4+
+	clc							; 2
+	adc	DRAW_PAGE					; 3
+	sta	hline_loop+2					; 4
+	pla							; 4
+	ldx	#39						; 2
+hline_loop:
+	sta	$5d0,X		; 38				; 5
+	dex							; 2
+	bpl	hline_loop					; 2nt/3
+	rts							; 6
+
+	;==========================
+	; Clear gr screen
+	;==========================
+	; Color in A
+clear_gr:
+	ldy	#46
+clear_page_loop:
+	jsr	hline
+	dey
+	dey
+	bpl	clear_page_loop
+	rts
+
+gr_offsets:
+	.word	$400,$480,$500,$580,$600,$680,$700,$780
+	.word	$428,$4a8,$528,$5a8,$628,$6a8,$728,$7a8
+	.word	$450,$4d0,$550,$5d0,$650,$6d0,$750,$7d0
+
+
+.include "../asm_routines/gr_unrle.s"
+.include "../asm_routines/keypress.s"
+.include "gr_copy.s"
+
+pictures:
+	.word k_low,k_high
+
+.include "k_40_48d.inc"
+
diff --git a/interlace_demo/k_40_48d.png b/interlace_demo/k_40_48d.png
new file mode 100644
index 00000000..9f1c501b
Binary files /dev/null and b/interlace_demo/k_40_48d.png differ