From a2990d38c2730deaf662ac2c8877098bfe6eac36 Mon Sep 17 00:00:00 2001
From: Vince Weaver <vince@deater.net>
Date: Thu, 9 May 2024 23:48:49 -0400
Subject: [PATCH] keen: story with up works

---
 games/keen/delay_a.s    |  25 ++++
 games/keen/story.s      |  88 +++++++++----
 games/keen/vapor_lock.s | 273 ++++++++++++++++++++++++++++++++++++++++
 3 files changed, 360 insertions(+), 26 deletions(-)
 create mode 100644 games/keen/delay_a.s
 create mode 100644 games/keen/vapor_lock.s

diff --git a/games/keen/delay_a.s b/games/keen/delay_a.s
new file mode 100644
index 00000000..2d0802da
--- /dev/null
+++ b/games/keen/delay_a.s
@@ -0,0 +1,25 @@
+; From http://6502org.wikidot.com/software-delay
+
+; 25+A cycles (including JSR), 19 bytes (excluding JSR)
+;
+; The branches must not cross page boundaries!
+;
+
+			;       Cycles              Accumulator         Carry flag
+			; 0  1  2  3  4  5  6          (hex)           0 1 2 3 4 5 6
+
+;	jsr	delay_a	; 6  6  6  6  6  6  6   00 01 02 03 04 05 06
+
+dly0:	sbc	#7
+delay_a:cmp	#7	; 2  2  2  2  2  2  2   00 01 02 03 04 05 06   0 0 0 0 0 0 0
+	bcs	dly0	; 2  2  2  2  2  2  2   00 01 02 03 04 05 06   0 0 0 0 0 0 0
+	lsr		; 2  2  2  2  2  2  2   00 00 01 01 02 02 03   0 1 0 1 0 1 0
+	bcs	dly1	; 2  3  2  3  2  3  2   00 00 01 01 02 02 03   0 1 0 1 0 1 0
+dly1:	beq	dly2	; 3  3  2  2  2  2  2   00 00 01 01 02 02 03   0 1 0 1 0 1 0
+	lsr		;       2  2  2  2  2         00 00 01 01 01       1 1 0 0 1
+	beq	dly3	;       3  3  2  2  2         00 00 01 01 01       1 1 0 0 1
+	bcc	dly3	;             3  3  2               01 01 01           0 0 1
+dly2:	bne	dly3	; 2  2              3   00 00             01   0 1         0
+dly3:	rts		; 6  6  6  6  6  6  6   00 00 00 00 01 01 01   0 1 1 1 0 0 1
+	;
+	; Total cycles:	 25 26 27 28 29 30 31
diff --git a/games/keen/story.s b/games/keen/story.s
index 66fbe3e6..c14b037b 100644
--- a/games/keen/story.s
+++ b/games/keen/story.s
@@ -18,11 +18,15 @@ keen_story_start:
 
 	bit	KEYRESET
 
-	bit	SET_GR
+	bit	SET_TEXT
 	bit	PAGE1
-	bit	HIRES
 	bit	FULLGR
 
+;	bit	SET_GR
+;	bit	PAGE1
+;	bit	HIRES
+;	bit	FULLGR
+
 	;===================
 	; Load story data
 	;===================
@@ -53,17 +57,40 @@ load_background:
 	jsr	full_decomp
 
 
-	jsr	wait_until_keypress
-
-
-	bit	SET_TEXT
-	bit	PAGE1
+;	bit	SET_TEXT
+;	bit	PAGE1
 
 	lda	#<story_data
 	sta	START_LINE_L
 	lda	#>story_data
 	sta	START_LINE_H
 
+	jsr	vapor_lock
+
+	; in theory at roughly 7410 cycles here (line 114)
+	; we want to be at line 192 (12480)
+
+	; 12480 - 7410 = 5070
+
+	; want to delay 5070 cycles
+
+	; experimentally want about 9 less?
+
+	; 5070 - 4 - 8 = 5058/9 = 562 -(9) = 561
+	; 561 / 256 = 2 r 49
+
+	nop
+	nop
+	nop
+	nop
+
+
+	lda	#2							; 2
+	ldy	#49							; 2
+	jsr	delay_loop
+
+
+
 	;===========================
 	; main loop
 	;===========================
@@ -227,16 +254,18 @@ done_key7:
 	nop
 done_key41:
 	inc	$00	; nop5
-	lda	$00	; nop3
-done_key_49:
+	nop
+	nop
+done_key_50:
 	inc	$00	; nop5
-	lda	$00	; nop3
+	nop
 done_key_57:
 	inc	$00	; nop5
 	inc	$00	; nop5
+	lda	$00	; nop3
+done_key_70:
+	nop
 	nop
-done_key_69:
-	inc	$00	; nop5
 	nop
 done_key_76:
 
@@ -318,8 +347,8 @@ test4:
 
 do_up_w:
 ; 27
-	nop
-	nop
+	nop								; 2
+	nop								; 2
 do_up_up:
 ; 31
 	lda	START_LINE_H						; 3
@@ -328,40 +357,42 @@ do_up_up:
 ; 38
 	lda	START_LINE_L						; 3
 	cmp	#<story_data						; 2
-	beq	up_done_46							; 2/3
+	beq	up_done_47						; 2/3
 	bne	up_ok_ok	; bra					; 3
 ; 48
 
 .align $100
 
 up_ok:
-; 39
+; 39+1 cross page = 40
 	inc	$0	; nop5
-	nop		; nop2
-	nop		; nop2
+	nop
+	nop
 
-; 48
+; 48+1 cross page = 49
 up_ok_ok:
+; 49
 	sec								; 2
 	lda	START_LINE_L						; 3
 	beq	to_prev_page						; 2/3
-; 55
+; 56
 	ldy	$0	; nop3						; 3
 	sbc	#40							; 2
 	jmp	up_done							; 3
-; 63
+; 64
 
 to_prev_page:
-; 56
+; 57
 	dec	START_LINE_H						; 5
 	lda	#200							; 2
 up_done:
-; 63 / 63
+; 64 / 64
 	sta	START_LINE_L						; 3
-	jmp	done_key_69						; 3
+	jmp	done_key_70						; 3
 
-up_done_46:
-	jmp	done_key_49						; 3
+up_done_47:
+; 47 (crossed page)
+	jmp	done_key_50						; 3
 
 	;=================================
 	; handle down pressed
@@ -444,6 +475,8 @@ real_done_with_story:
 	.include	"gr_fast_clear.s"
 	.include	"text_print.s"
 
+	.include	"vapor_lock.s"
+
 ;	.include	"lc_detect.s"
 
 
@@ -485,3 +518,6 @@ delay_loop:
 	bcs	delay_loop
 delay_12:
 	rts
+
+
+.include "delay_a.s"
diff --git a/games/keen/vapor_lock.s b/games/keen/vapor_lock.s
new file mode 100644
index 00000000..f3c21ab8
--- /dev/null
+++ b/games/keen/vapor_lock.s
@@ -0,0 +1,273 @@
+; This took a while to track down
+; On Apple II/II+ the horiz blanking addr are $1000 higher than on IIe
+; So on II+ were outside video area, so unlikely to be our set value
+;	(unless I foolishly use $ff which some uninitialized mem is set to)
+; Lots of this color fiddling is to make sure you don't accidentally
+;	get runs of colors on IIe due to the horiz blank
+
+; 0-5 aqua 6-12 = grey, 13 - 20 = yellow, 21-23 = aqua rainbow 14
+;
+;
+;16	0	YA
+;17	1	YA
+;18	2	YA
+;19	3	YA
+;20	4	YA
+;21	5	AA
+;22	6	AG
+;23	7	AG
+;0	8	AG
+;1	9	AG
+;2	10	AG
+;3	11	AG
+;4	12	AG
+;5	13	AY ****
+;6	14	GY RAINBOW
+;7	15	GY
+;8	16	GY
+;9	17	GY
+;10	18	GY
+;11	19	GY
+;12	20	GY
+;13	21	YA
+;14	22	YA
+;15	23	YA
+
+
+
+	;==============================
+	; setup graphics for vapor lock
+	;==============================
+vapor_lock:
+
+	; Clear Page0
+	lda	#$0
+	sta	DRAW_PAGE
+	lda	#$ee				; full screen white $ff
+	jsr	clear_gr
+
+	lda	#$dd
+	ldy	#20
+	jsr	clear_page_loop			; make bottom half yellow $dd
+
+	lda	#$aa
+	ldy	#12
+	jsr	clear_page_loop			; make middle grey2 $aa
+
+	lda	#$ee
+	ldy	#5
+	jsr	clear_page_loop			; make top half aqua $ee
+
+	; set up a rainbow to aid in exact lock
+
+	ldy	#00
+rainbow_loop:
+	tya
+	sta	$728+20,Y
+	iny
+	cpy	#20
+	bne	rainbow_loop
+
+;btt:
+;	jmp	btt
+
+
+	;=====================================================
+	; attempt vapor lock
+	;  by reading the "floating bus" we can see most recently
+	;  written value of the display
+	;=====================================================
+	; See:
+	;	Have an Apple Split by Bob Bishop
+        ;	Softalk, October 1982
+
+	; Challenges: each scan line scans 40 bytes.
+	; The blanking happens at the *beginning*
+	; So 65 bytes are scanned, starting at adress of the line - 25
+
+	; the scan takes 8 cycles, look for 4 repeats of the value
+	; to avoid false positive found if the horiz blanking is mirroring
+	; the line (max 3 repeats in that case)
+
+vapor_lock_loop:
+
+	; first make sure we have a full line of $aa
+
+	lda	#$aa							; 2
+zxloop:
+	ldx	#$04							; 2
+wiloop:
+	cmp	$C052		; read the floating bus			; 4
+	bne	zxloop		; if not, start from scratch		; 2/3
+	dex			; we were, dec				; 2
+	bne	wiloop		; if not 4 of them, restart		; 3/2
+
+	; if we get here we read 4 proper pixels, 11 apart (2+4+2+2+3)
+	; 0 11 22 33, clock at 34
+	; 1 12 23 34, clock at 35
+	; 2 13 24 35, clock at 36
+	; 3 14 25 36, clock at 37
+	; 4 15 26 37, clock at 38
+	; 5 16 27 38, clock at 39
+	; 6 17 28 39, clock at 40
+
+
+;                                 X          X          X          X
+;                                  X          X          X          X
+;                                   X          X          X          X
+;                                    X          X          X          X
+;                                     X          X          X          X
+;                                      X          X          X          X
+;                                       X          X          X          X
+;	0123456789012345678901234 0123456789012345678901234567890123456789
+;                 1         2               1         2         3
+;	hsync                     pixels
+;       XXXXXXXXXXXXXXXXXXXXXXXXX 4444444444444444444444444444440123456789
+
+	; now look for the color change that
+	; happens at line 13*8 = 104
+
+	lda	#$dd							; 2
+zloop:
+	ldx	#$04							; 2
+qloop:
+	cmp	$C052		; read floating bus			; 4
+	bne	zloop							; 2/3
+	dex								; 2
+	bne	qloop							; 3/2
+								;============
+								;	11
+
+	; Found it!
+	; if we get here we read 4 proper pixels, 11 apart (2+4+2+2+3)
+	; 0 11 22 33, clock at 34
+	; 1 12 23 34, clock at 35
+	; 2 13 24 35, clock at 36
+	; 3 14 25 36, clock at 37
+	; 4 15 26 37, clock at 38
+	; 5 16 27 38, clock at 39
+	; 6 17 28 39, clock at 40
+
+
+
+
+;btt:
+;	jmp	btt
+
+	; In theory near end of line 104
+
+	; now skip ahead 8 lines and read from the rainbow pattern we set
+	; up to find our exact location
+
+	; delay 65 * 8 = 520
+	; we back off a few to make sure we're not in the horiz blank
+	; try to delay 510
+
+	; *NOTE* sometimes we end up going one (or rarely, two??) lines too far
+	; so instead try going 7 lines ahead, and if still dd then one more
+
+	; so single step until we get a rainbow color
+
+	; go to next line, -10
+	lda	#28				; 2
+	jsr	delay_a				; delay 25+28 = 53
+						; total delay = 55
+
+vl_try_again:
+	lda	#29				; 2
+	jsr	delay_a				; delay 25+29 = 54
+						; total delay = 56
+
+
+
+	lda	$C052				; 4
+	cmp	#$dd				; 2
+	beq	vl_try_again			; 3
+						; -1
+
+
+	; now near end of line 112
+	;lda	$0	; nop to match old code	; 3
+;	nop	; nop to match old code	; 2
+
+	lda	$C052				; 4
+;kbb:
+;	jmp	kbb
+
+        ; we are in theory on line $728 = 14*8 = 112
+        ; so 112*65 = 7280 cycles from start
+
+        ; we are actualy 25+20+A pixels in
+        ; 7325+A
+
+        ; Our goal is line 114 at 7410 cycles
+	; 7410 - 7325 = 85
+
+        ; so kill 85-A cycles
+	; -6 to do subtraction
+	; -6 for rts
+	; -25 for delay_a overhead
+
+        eor	#$ff				; 2
+        sec					; 2
+        adc	#48				; 2
+
+	jsr	delay_a				; should total 48 cycles
+
+
+done_vapor_lock:
+	rts                                                     ; 6
+
+
+	;==================================
+	; Vapor HLINE
+	;==================================
+	; FIXME: merge with generic hline code?
+	; Color in A
+	; Y has which line
+hline:
+	pha							; 3
+	ldx	gr_offsets_low,y				; 4+
+	stx	hline_loop+1					; 4
+	lda	gr_offsets_high,y				; 4+
+	clc							; 2
+	adc	DRAW_PAGE					; 3
+	sta	hline_loop+2					; 4
+	pla							; 4
+	ldx	#39						; 2
+hline_loop:
+	sta	$5d0,X		; 38				; 5
+	dex							; 2
+	bpl	hline_loop					; 2nt/3
+	rts							; 6
+
+
+	;==========================
+	; Clear gr screen
+	;==========================
+        ; Color in A
+clear_gr:
+	ldy	#23
+clear_page_loop:
+	jsr	hline
+	dey
+	bpl	clear_page_loop
+	rts
+
+
+
+	; Some random related work
+	; Docs:
+	;	Lancaster
+	;	Bishop
+	;	Sather
+
+	; Vaguely relevant but no help with the Apple II+ issue
+	;
+	;	Eamon: Screen display and timing synchronization
+	;		on the Apple IIe and Apple IIgs
+	;
+	;	Adams: Visually presented verbal stimuli by assembly
+	;		language on the Apple II computer.
+	;	Cavanagh and Anstis: Visual psychophysics on the
+	;		Apple II: Getting started