mist_hgr: some more files

games/mist_hgr/audio/HOWTO

@@ -0,0 +1,8 @@
+pt3 file
+
+	found a theme.mid somewhere
+	ran it through 
+		ptmid -d6 theme.mid theme.mod
+	on Dosbox
+	then manually converted from mod to pt3
+

games/mist_hgr/lc_detect.s

@@ -0,0 +1,40 @@
+; Code from TotalReplay by 4am and qkumba
+
+;------------------------------------------------------------------------------
+; Has64K
+; Checks whether computer has functioning language card (64K)
+;
+; in:    none
+; out:   C clear if 64K detected
+;        C set if 64K not detected
+;        all other flags and registers clobbered
+;        ROM in memory (not LC RAM bank)
+;------------------------------------------------------------------------------
+
+detect_language_card:
+
+	; enable language card
+	; READ_RAM1_WRITE_RAM1
+
+	bit	$C08B
+	bit	$C08B
+
+	lda	#$AA			; test #1 for $D0 page
+	sta	$D000
+	eor	$D000
+	bne	no_lc
+	lsr	$D000			; test #2 for $D0 page
+	lda	#$55
+	eor	$D000
+	bne	no_lc
+	clc
+	bcc	done_detect
+
+no_lc:
+	sec
+
+done_detect:
+	; READ_ROM_NO_WRITE
+	bit	$C08A
+
+	rts

games/mist_hgr/mist_title.s

@@ -549,7 +549,7 @@ really_exit:
 
 	.include	"link_book_mist_dock.s"
 
-	.include	"common_sprites.inc"
+;	.include	"common_sprites.inc"
 
 	.include	"leveldata_title.inc"
 

games/mist_hgr/pt3_lib_detect_model.s

@@ -0,0 +1,63 @@
+	;===========================
+	; Check Apple II model
+	;===========================
+	; this is mostly for IIc support
+	; as it does interrupts differently
+
+	; ' ' ($20) = Apple II
+	; '+' ($2B) = Apple II+
+	; 'E' ($45) = Apple IIe
+	; 'C' ($43) = Apple IIc
+	; 'G' ($47) = Apple IIgs
+
+
+detect_appleii_model:
+	lda	#' '
+
+	ldx	$FBB3
+				; II is $38
+				; J-plus is $C9
+				; II+ is $EA (so is III)
+				; IIe and newer is $06
+
+	cpx	#$38
+	beq	done_apple_detect
+
+	lda	#'+'
+	cpx	#$EA
+	beq	done_apple_detect
+
+	; TODO: check for J-plus or III?
+
+	cpx	#$06
+	bne	done_apple_detect
+
+apple_iie_or_newer:
+
+
+
+	ldx	$FBC0		; $EA on a IIe
+				; $E0 on a IIe enhanced
+				; $00 on a IIc/IIc+
+
+				; $FE1F = $60, IIgs
+
+	beq	apple_iic
+
+	lda	#'E'
+	cpx	#$EA
+	beq	done_apple_detect
+	cpx	#$E0
+	beq	done_apple_detect
+
+	; assume GS?
+
+	lda	#'G'
+	bne	done_apple_detect
+
+apple_iic:
+	lda	#'C'
+
+done_apple_detect:
+	sta	APPLEII_MODEL
+	rts