prog8/compiler/build.gradle

buildscript {
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
    }
}

plugins {
    // id "org.jetbrains.kotlin.jvm" version $kotlinVersion
    id 'application'
    id 'org.jetbrains.dokka' version "0.9.18"
    id 'com.github.johnrengelman.shadow' version '5.1.0'
    id 'java'
}

apply plugin: "kotlin"
apply plugin: "java"


repositories {
    mavenLocal()
    mavenCentral()
    jcenter()
}

def prog8version = rootProject.file('compiler/res/version.txt').text.trim()

dependencies {
    implementation project(':parser')
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk8:$kotlinVersion"
    // implementation "org.jetbrains.kotlin:kotlin-reflect:$kotlinVersion"
    // runtime "org.jetbrains.kotlin:kotlin-reflect:$kotlinVersion"
    runtime 'org.antlr:antlr4-runtime:4.7.2'
    runtime project(':parser')

    testImplementation "org.jetbrains.kotlin:kotlin-test-junit5:$kotlinVersion"
    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.3.2'
    testImplementation 'org.hamcrest:hamcrest-junit:2.0.0.0'

    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.3.2'
}

compileKotlin {
    kotlinOptions {
        jvmTarget = "1.8"
        verbose = true
        // freeCompilerArgs += "-XXLanguage:+NewInference"
    }
}

compileTestKotlin {
    kotlinOptions {
        jvmTarget = "1.8"
    }
}

sourceSets {
    main {
        java {
            srcDirs = ["${project.projectDir}/src"]
        }
        resources {
            srcDirs = ["${project.projectDir}/res"]
        }
    }
    test {
        java {
            srcDirs = ["${project.projectDir}/test"]
        }
    }
}

startScripts.enabled = true

application {
    mainClassName = 'prog8.CompilerMainKt'
    applicationName = 'p8compile'
}

artifacts {
    archives shadowJar
}


shadowJar {
    baseName = 'prog8compiler'
    version = prog8version
    // minimize()
}


test {
    // Enable JUnit 5 (Gradle 4.6+).
    useJUnitPlatform()

    // Always run tests, even when nothing changed.
    dependsOn 'cleanTest'

    // Show test results.
    testLogging {
        events "passed", "skipped", "failed"
    }
}


dokka {
    outputFormat = 'html'
    outputDirectory = "$buildDir/kdoc"
}