experimental Commodore PET target

README.md

@@ -74,6 +74,8 @@ What does Prog8 provide?
 - "c64": Commodore-64  (6502 like CPU)
 - "c128": Commodore-128  (6502 like CPU - the Z80 cpu mode is not supported)
 - "cx16": [CommanderX16](https://www.commanderx16.com)  (65c02 CPU)
+- "pet32": Commodore PET (experimental)
+- "atari": Atari 8 bit such as 800XL (experimental)
 - If you only use standard kernal and prog8 library routines, it is possible to compile the *exact same program* for different machines (just change the compiler target flag)
 
 

codeCore/src/prog8/code/target/PETTarget.kt

@@ -0,0 +1,20 @@
+package prog8.code.target
+
+import prog8.code.core.Encoding
+import prog8.code.core.ICompilationTarget
+import prog8.code.core.IMemSizer
+import prog8.code.core.IStringEncoding
+import prog8.code.target.cbm.CbmMemorySizer
+import prog8.code.target.pet.PETMachineDefinition
+
+
+class PETTarget: ICompilationTarget, IStringEncoding by Encoder, IMemSizer by CbmMemorySizer {
+    override val name = NAME
+    override val machine = PETMachineDefinition()
+    override val supportedEncodings = setOf(Encoding.PETSCII, Encoding.SCREENCODES)
+    override val defaultEncoding = Encoding.PETSCII
+
+    companion object {
+        const val NAME = "pet32"
+    }
+}

codeCore/src/prog8/code/target/pet/PETMachineDefinition.kt

@@ -0,0 +1,55 @@
+package prog8.code.target.pet
+
+import prog8.code.core.*
+import prog8.code.target.C64Target
+import prog8.code.target.cbm.Mflpt5
+import java.nio.file.Path
+
+
+class PETMachineDefinition: IMachineDefinition {
+
+    override val cpu = CpuType.CPU6502
+
+    override val FLOAT_MAX_POSITIVE = Mflpt5.FLOAT_MAX_POSITIVE
+    override val FLOAT_MAX_NEGATIVE = Mflpt5.FLOAT_MAX_NEGATIVE
+    override val FLOAT_MEM_SIZE = Mflpt5.FLOAT_MEM_SIZE
+    override val PROGRAM_LOAD_ADDRESS = 0x0401u
+
+    override val BSSHIGHRAM_START = 0xffffu
+    override val BSSHIGHRAM_END = 0xffffu
+
+    override lateinit var zeropage: Zeropage
+    override lateinit var golden: GoldenRam
+
+    override fun getFloatAsmBytes(num: Number) = Mflpt5.fromNumber(num).makeFloatFillAsm()
+
+    override fun importLibs(compilerOptions: CompilationOptions, compilationTargetName: String): List<String> {
+        return if (compilerOptions.launcher == CbmPrgLauncherType.BASIC || compilerOptions.output == OutputType.PRG)
+            listOf("syslib")
+        else
+            emptyList()
+    }
+
+    override fun launchEmulator(selectedEmulator: Int, programNameWithPath: Path) {
+        if(selectedEmulator!=1) {
+            System.err.println("The pet target only supports the main emulator (Vice).")
+            return
+        }
+
+        println("\nStarting PET emulator...")
+        val viceMonlist = C64Target.viceMonListName(programNameWithPath.toString())
+        val cmdline = listOf("xpet", "-model", "4032", "-ramsize", "32", "-videosize", "40", "-silent", "-moncommands", viceMonlist,
+                "-autostartprgmode", "1", "-autostart-warp", "-autostart", "${programNameWithPath}.prg")
+        val processb = ProcessBuilder(cmdline).inheritIO()
+        val process=processb.start()
+        process.waitFor()
+    }
+
+    override fun isIOAddress(address: UInt): Boolean = address in 0xe800u..0xe8ffu
+
+    override fun initializeMemoryAreas(compilerOptions: CompilationOptions) {
+        zeropage = PETZeropage(compilerOptions)
+        // there's no golden ram.
+    }
+
+}

codeCore/src/prog8/code/target/pet/PETZeropage.kt

@@ -0,0 +1,58 @@
+package prog8.code.target.pet
+
+import prog8.code.core.CompilationOptions
+import prog8.code.core.InternalCompilerException
+import prog8.code.core.Zeropage
+import prog8.code.core.ZeropageType
+
+
+// reference: http://www.zimmers.net/cbmpics/cbm/PETx/petmem.txt
+
+class PETZeropage(options: CompilationOptions) : Zeropage(options) {
+
+    override val SCRATCH_B1 = 0xb3u      // temp storage for a single byte
+    override val SCRATCH_REG = 0xb4u     // temp storage for a register, must be B1+1
+    override val SCRATCH_W1 = 0xb6u      // temp storage 1 for a word
+    override val SCRATCH_W2 = 0xb8u      // temp storage 2 for a word
+
+    init {
+        if (options.floats) {
+            throw InternalCompilerException("PET target doesn't yet support floating point routines")
+        }
+
+        if (options.floats && options.zeropage !in arrayOf(
+                ZeropageType.FLOATSAFE,
+                ZeropageType.BASICSAFE,
+                ZeropageType.DONTUSE
+            ))
+            throw InternalCompilerException("when floats are enabled, zero page type should be 'floatsafe' or 'basicsafe' or 'dontuse'")
+
+        when (options.zeropage) {
+            ZeropageType.FULL -> {
+                free.addAll(0x00u..0xffu)
+                free.removeAll(listOf(0x8du, 0x8eu, 0x8fu, 0x97u, 0x98u, 0x99u, 0x9au, 0x9bu, 0x9eu, 0xa7u, 0xa8u, 0xa9u, 0xaau))        // these are updated/used by IRQ
+            }
+            ZeropageType.KERNALSAFE -> {
+                free.addAll(0x00u..0xffu)
+                free.removeAll(listOf(0x8du, 0x8eu, 0x8fu, 0x97u, 0x98u, 0x99u, 0x9au, 0x9bu, 0x9eu, 0xa7u, 0xa8u, 0xa9u, 0xaau))        // these are updated/used by IRQ
+            }
+            ZeropageType.FLOATSAFE,
+            ZeropageType.BASICSAFE -> {
+                free.addAll(0xb3u..0xbau)       // TODO more?
+            }
+            ZeropageType.DONTUSE -> {
+                free.clear()  // don't use zeropage at all
+            }
+        }
+
+        val distinctFree = free.distinct()
+        free.clear()
+        free.addAll(distinctFree)
+
+        removeReservedFromFreePool()
+    }
+
+    override fun allocateCx16VirtualRegisters() {
+        TODO("Not known if C128 can put the virtual regs in ZP")
+    }
+}

codeGenCpu6502/src/prog8/codegen/cpu6502/AssemblyProgram.kt

@@ -22,7 +22,7 @@ internal class AssemblyProgram(
         val assemblerCommand: List<String>
 
         when (compTarget.name) {
-            in setOf("c64", "c128", "cx16") -> {
+            in setOf("c64", "c128", "cx16", "pet32") -> {
                 // CBM machines .prg generation.
 
                 // add "-Wlong-branch"  to see warnings about conversion of branch instructions to jumps (default = do this silently)

compiler/res/prog8lib/c128/syslib.p8

@@ -335,7 +335,7 @@ asmsub  init_system()  {
     ; This means that the BASIC, KERNAL and CHARGEN ROMs are banked in,
     ; the VIC, SID and CIA chips are reset, screen is cleared, and the default IRQ is set.
     ; Also a different color scheme is chosen to identify ourselves a little.
-    ; Uppercase charset is activated, and all three registers set to 0, status flags cleared.
+    ; Uppercase charset is activated.
     %asm {{
         sei
         cld

compiler/res/prog8lib/c128/textio.p8

@@ -1,4 +1,4 @@
-; Prog8 definitions for the Text I/O and Screen routines for the Commodore-64
+; Prog8 definitions for the Text I/O and Screen routines for the Commodore-128
 
 %import syslib
 %import conv

compiler/res/prog8lib/c64/syslib.p8

@@ -300,7 +300,7 @@ asmsub  init_system()  {
     ; This means that the BASIC, KERNAL and CHARGEN ROMs are banked in,
     ; the VIC, SID and CIA chips are reset, screen is cleared, and the default IRQ is set.
     ; Also a different color scheme is chosen to identify ourselves a little.
-    ; Uppercase charset is activated, and all three registers set to 0, status flags cleared.
+    ; Uppercase charset is activated.
     %asm {{
         sei
         cld

compiler/res/prog8lib/pet32/syslib.p8

@@ -0,0 +1,407 @@
+; Prog8 definitions for the Commodore PET
+; Including memory registers, I/O registers, Basic and Kernal subroutines.
+
+cbm {
+    ; Commodore (CBM) common variables, vectors and kernal routines
+    %option no_symbol_prefixing
+
+        &ubyte  TIME_HI         = $8d       ; software jiffy clock, hi byte
+        &ubyte  TIME_MID        = $8e       ;  .. mid byte
+        &ubyte  TIME_LO         = $8f       ;    .. lo byte. Updated by IRQ every 1/60 sec
+        &ubyte  STATUS          = $96       ; kernal status variable for I/O
+
+        &uword  CINV            = $0090     ; IRQ vector (in ram)
+        &uword  CBINV           = $0092     ; BRK vector (in ram)
+        &uword  NMINV           = $0094     ; NMI vector (in ram)
+
+        &uword  NMI_VEC         = $FFFA     ; 6502 nmi vector, determined by the kernal if banked in
+        &uword  RESET_VEC       = $FFFC     ; 6502 reset vector, determined by the kernal if banked in
+        &uword  IRQ_VEC         = $FFFE     ; 6502 interrupt vector, determined by the kernal if banked in
+
+        ; the default addresses for the character screen chars and colors
+        const  uword  Screen    = $8000     ; to have this as an array[40*25] the compiler would have to support array size > 255
+
+
+romsub $FFC6 = CHKIN(ubyte logical @ X) clobbers(A,X) -> bool @Pc    ; define an input channel
+romsub $FFC9 = CHKOUT(ubyte logical @ X) clobbers(A,X)          ; define an output channel
+romsub $FFCC = CLRCHN() clobbers(A,X)                           ; restore default devices
+romsub $FFCF = CHRIN() clobbers(X, Y) -> ubyte @ A              ; input a character (for keyboard, read a whole line from the screen) A=byte read.
+romsub $FFD2 = CHROUT(ubyte char @ A)                           ; output a character
+
+}
+
+sys {
+    ; ------- lowlevel system routines --------
+    %option no_symbol_prefixing
+
+    const ubyte target = 32         ;  compilation target specifier.  64 = C64, 128 = C128,  16 = CommanderX16, 32=PET
+
+asmsub  init_system()  {
+    ; Initializes the machine to a sane starting state.
+    ; Called automatically by the loader program logic.
+    ; Uppercase charset is activated.
+    %asm {{
+        sei
+        cld
+        lda  #142
+        jsr  cbm.CHROUT     ; uppercase
+        lda  #147
+        jsr  cbm.CHROUT     ; clear screen
+        clc
+        clv
+        cli
+        rts
+    }}
+}
+
+asmsub  init_system_phase2()  {
+    %asm {{
+        rts     ; no phase 2 steps on the PET
+    }}
+}
+
+asmsub  cleanup_at_exit() {
+    ; executed when the main subroutine does rts
+    %asm {{
+        rts
+    }}
+}
+
+    asmsub  reset_system()  {
+        ; Soft-reset the system back to initial power-on Basic prompt.
+        %asm {{
+            sei
+            lda  #0
+            sta  $ff00      ; default bank 15
+            jmp  (cbm.RESET_VEC)
+        }}
+    }
+
+    asmsub waitvsync() clobbers(A) {
+        ; --- busy wait till the next vsync has occurred (approximately), without depending on custom irq handling.
+        ;     TODO: on PET this now simply waits until the next jiffy clock update
+        %asm {{
+            lda  #1
+            ldy  #0
+            jmp  wait
+        }}
+    }
+
+    asmsub wait(uword jiffies @AY) {
+        ; --- wait approximately the given number of jiffies (1/60th seconds) (N or N+1)
+        ;     note: the system irq handler has to be active for this to work as it depends on the system jiffy clock
+        %asm {{
+            stx  P8ZP_SCRATCH_B1
+            sta  P8ZP_SCRATCH_W1
+            sty  P8ZP_SCRATCH_W1+1
+
+_loop       lda  P8ZP_SCRATCH_W1
+            ora  P8ZP_SCRATCH_W1+1
+            bne  +
+            ldx  P8ZP_SCRATCH_B1
+            rts
+
++           lda  cbm.TIME_LO
+            sta  P8ZP_SCRATCH_B1
+-           lda  cbm.TIME_LO
+            cmp  P8ZP_SCRATCH_B1
+            beq  -
+
+            lda  P8ZP_SCRATCH_W1
+            bne  +
+            dec  P8ZP_SCRATCH_W1+1
++           dec  P8ZP_SCRATCH_W1
+            jmp  _loop
+        }}
+    }
+
+    asmsub internal_stringcopy(uword source @R0, uword target @AY) clobbers (A,Y) {
+        ; Called when the compiler wants to assign a string value to another string.
+        %asm {{
+		sta  P8ZP_SCRATCH_W1
+		sty  P8ZP_SCRATCH_W1+1
+		lda  cx16.r0
+		ldy  cx16.r0+1
+		jmp  prog8_lib.strcpy
+        }}
+    }
+
+    asmsub memcopy(uword source @R0, uword target @R1, uword count @AY) clobbers(A,X,Y) {
+        ; note: only works for NON-OVERLAPPING memory regions!
+        ; note: can't be inlined because is called from asm as well
+        %asm {{
+            ldx  cx16.r0
+            stx  P8ZP_SCRATCH_W1        ; source in ZP
+            ldx  cx16.r0+1
+            stx  P8ZP_SCRATCH_W1+1
+            ldx  cx16.r1
+            stx  P8ZP_SCRATCH_W2        ; target in ZP
+            ldx  cx16.r1+1
+            stx  P8ZP_SCRATCH_W2+1
+            cpy  #0
+            bne  _longcopy
+
+            ; copy <= 255 bytes
+            tay
+            bne  _copyshort
+            rts     ; nothing to copy
+
+_copyshort
+            ; decrease source and target pointers so we can simply index by Y
+            lda  P8ZP_SCRATCH_W1
+            bne  +
+            dec  P8ZP_SCRATCH_W1+1
++           dec  P8ZP_SCRATCH_W1
+            lda  P8ZP_SCRATCH_W2
+            bne  +
+            dec  P8ZP_SCRATCH_W2+1
++           dec  P8ZP_SCRATCH_W2
+
+-           lda  (P8ZP_SCRATCH_W1),y
+            sta  (P8ZP_SCRATCH_W2),y
+            dey
+            bne  -
+            rts
+
+_longcopy
+            sta  P8ZP_SCRATCH_B1        ; lsb(count) = remainder in last page
+            tya
+            tax                         ; x = num pages (1+)
+            ldy  #0
+-           lda  (P8ZP_SCRATCH_W1),y
+            sta  (P8ZP_SCRATCH_W2),y
+            iny
+            bne  -
+            inc  P8ZP_SCRATCH_W1+1
+            inc  P8ZP_SCRATCH_W2+1
+            dex
+            bne  -
+            ldy  P8ZP_SCRATCH_B1
+            bne  _copyshort
+            rts
+        }}
+    }
+
+    asmsub memset(uword mem @R0, uword numbytes @R1, ubyte value @A) clobbers(A,X,Y) {
+        %asm {{
+            ldy  cx16.r0
+            sty  P8ZP_SCRATCH_W1
+            ldy  cx16.r0+1
+            sty  P8ZP_SCRATCH_W1+1
+            ldx  cx16.r1
+            ldy  cx16.r1+1
+            jmp  prog8_lib.memset
+        }}
+    }
+
+    asmsub memsetw(uword mem @R0, uword numwords @R1, uword value @AY) clobbers(A,X,Y) {
+        %asm {{
+            ldx  cx16.r0
+            stx  P8ZP_SCRATCH_W1
+            ldx  cx16.r0+1
+            stx  P8ZP_SCRATCH_W1+1
+            ldx  cx16.r1
+            stx  P8ZP_SCRATCH_W2
+            ldx  cx16.r1+1
+            stx  P8ZP_SCRATCH_W2+1
+            jmp  prog8_lib.memsetw
+        }}
+    }
+
+    inline asmsub read_flags() -> ubyte @A {
+        %asm {{
+        php
+        pla
+        }}
+    }
+
+    inline asmsub clear_carry() {
+        %asm {{
+        clc
+        }}
+    }
+
+    inline asmsub set_carry() {
+        %asm {{
+        sec
+        }}
+    }
+
+    inline asmsub clear_irqd() {
+        %asm {{
+        cli
+        }}
+    }
+
+    inline asmsub set_irqd() {
+        %asm {{
+        sei
+        }}
+    }
+
+    inline asmsub irqsafe_set_irqd() {
+        %asm {{
+        php
+        sei
+        }}
+    }
+
+    inline asmsub irqsafe_clear_irqd() {
+        %asm {{
+        plp
+        }}
+    }
+
+    inline asmsub exit(ubyte returnvalue @A) {
+        ; -- immediately exit the program with a return code in the A register
+        %asm {{
+            ldx  prog8_lib.orig_stackpointer
+            txs
+            rts		; return to original caller
+        }}
+    }
+
+    inline asmsub progend() -> uword @AY {
+        %asm {{
+            lda  #<prog8_program_end
+            ldy  #>prog8_program_end
+        }}
+    }
+
+}
+
+cx16 {
+    %option no_symbol_prefixing
+
+    ; the sixteen virtual 16-bit registers that the CX16 has defined in the zeropage
+    ; they are simulated on the PET as well but their location in memory is different
+    ; (because there's no room for them in the zeropage)
+    ; we select the top page of RAM (assume 32Kb)
+    &uword r0  = $7fe0
+    &uword r1  = $7fe2
+    &uword r2  = $7fe4
+    &uword r3  = $7fe6
+    &uword r4  = $7fe8
+    &uword r5  = $7fea
+    &uword r6  = $7fec
+    &uword r7  = $7fee
+    &uword r8  = $7ff0
+    &uword r9  = $7ff2
+    &uword r10 = $7ff4
+    &uword r11 = $7ff6
+    &uword r12 = $7ff8
+    &uword r13 = $7ffa
+    &uword r14 = $7ffc
+    &uword r15 = $7ffe
+
+    &word r0s  = $7fe0
+    &word r1s  = $7fe2
+    &word r2s  = $7fe4
+    &word r3s  = $7fe6
+    &word r4s  = $7fe8
+    &word r5s  = $7fea
+    &word r6s  = $7fec
+    &word r7s  = $7fee
+    &word r8s  = $7ff0
+    &word r9s  = $7ff2
+    &word r10s = $7ff4
+    &word r11s = $7ff6
+    &word r12s = $7ff8
+    &word r13s = $7ffa
+    &word r14s = $7ffc
+    &word r15s = $7ffe
+
+    &ubyte r0L  = $7fe0
+    &ubyte r1L  = $7fe2
+    &ubyte r2L  = $7fe4
+    &ubyte r3L  = $7fe6
+    &ubyte r4L  = $7fe8
+    &ubyte r5L  = $7fea
+    &ubyte r6L  = $7fec
+    &ubyte r7L  = $7fee
+    &ubyte r8L  = $7ff0
+    &ubyte r9L  = $7ff2
+    &ubyte r10L = $7ff4
+    &ubyte r11L = $7ff6
+    &ubyte r12L = $7ff8
+    &ubyte r13L = $7ffa
+    &ubyte r14L = $7ffc
+    &ubyte r15L = $7ffe
+
+    &ubyte r0H  = $7fe1
+    &ubyte r1H  = $7fe3
+    &ubyte r2H  = $7fe5
+    &ubyte r3H  = $7fe7
+    &ubyte r4H  = $7fe9
+    &ubyte r5H  = $7feb
+    &ubyte r6H  = $7fed
+    &ubyte r7H  = $7fef
+    &ubyte r8H  = $7ff1
+    &ubyte r9H  = $7ff3
+    &ubyte r10H = $7ff5
+    &ubyte r11H = $7ff7
+    &ubyte r12H = $7ff9
+    &ubyte r13H = $7ffb
+    &ubyte r14H = $7ffd
+    &ubyte r15H = $7fff
+
+    &byte r0sL  = $7fe0
+    &byte r1sL  = $7fe2
+    &byte r2sL  = $7fe4
+    &byte r3sL  = $7fe6
+    &byte r4sL  = $7fe8
+    &byte r5sL  = $7fea
+    &byte r6sL  = $7fec
+    &byte r7sL  = $7fee
+    &byte r8sL  = $7ff0
+    &byte r9sL  = $7ff2
+    &byte r10sL = $7ff4
+    &byte r11sL = $7ff6
+    &byte r12sL = $7ff8
+    &byte r13sL = $7ffa
+    &byte r14sL = $7ffc
+    &byte r15sL = $7ffe
+
+    &byte r0sH  = $7fe1
+    &byte r1sH  = $7fe3
+    &byte r2sH  = $7fe5
+    &byte r3sH  = $7fe7
+    &byte r4sH  = $7fe9
+    &byte r5sH  = $7feb
+    &byte r6sH  = $7fed
+    &byte r7sH  = $7fef
+    &byte r8sH  = $7ff1
+    &byte r9sH  = $7ff3
+    &byte r10sH = $7ff5
+    &byte r11sH = $7ff7
+    &byte r12sH = $7ff9
+    &byte r13sH = $7ffb
+    &byte r14sH = $7ffd
+    &byte r15sH = $7fff
+
+    asmsub save_virtual_registers() clobbers(A,Y) {
+        %asm {{
+            ldy  #31
+    -       lda  cx16.r0,y
+            sta  _cx16_vreg_storage,y
+            dey
+            bpl  -
+            rts
+
+    _cx16_vreg_storage
+            .word 0,0,0,0,0,0,0,0
+            .word 0,0,0,0,0,0,0,0
+        }}
+    }
+
+    asmsub restore_virtual_registers() clobbers(A,Y) {
+        %asm {{
+            ldy  #31
+    -       lda  save_virtual_registers._cx16_vreg_storage,y
+            sta  cx16.r0,y
+            dey
+            bpl  -
+            rts
+        }}
+    }
+}

compiler/res/prog8lib/pet32/textio.p8

@@ -0,0 +1,439 @@
+; Prog8 definitions for the Text I/O and Screen routines for the Commodore PET
+
+%import syslib
+%import conv
+
+
+txt {
+    %option no_symbol_prefixing
+
+const ubyte DEFAULT_WIDTH = 40
+const ubyte DEFAULT_HEIGHT = 25
+
+
+sub  clear_screen() {
+    txt.chrout(147)
+}
+
+sub home() {
+    txt.chrout(19)
+}
+
+sub nl() {
+    txt.chrout('\n')
+}
+
+sub spc() {
+    txt.chrout(' ')
+}
+
+asmsub column(ubyte col @A) clobbers(A, X, Y) {
+    ; ---- set the cursor on the given column (starting with 0) on the current line
+    %asm {{
+        sec
+        jsr  cbm.PLOT
+        tay
+        clc
+        jmp  cbm.PLOT
+    }}
+}
+
+asmsub  fill_screen (ubyte char @ A) clobbers(A)  {
+	; ---- fill the character screen with the given fill character
+
+	%asm {{
+		jmp  clear_screenchars
+        }}
+
+}
+
+asmsub  clear_screenchars (ubyte char @ A) clobbers(Y)  {
+	; ---- clear the character screen with the given fill character (leaves colors)
+	;      (assumes screen matrix is at the default address)
+	%asm {{
+		ldy  #250
+-		sta  cbm.Screen+250*0-1,y
+		sta  cbm.Screen+250*1-1,y
+		sta  cbm.Screen+250*2-1,y
+		sta  cbm.Screen+250*3-1,y
+		dey
+		bne  -
+		rts
+        }}
+}
+
+sub lowercase() {
+    txt.chrout(14)
+}
+
+sub uppercase() {
+    txt.chrout(142)
+}
+
+asmsub  scroll_left  () clobbers(A, X, Y)  {
+	; ---- scroll the whole screen 1 character to the left
+	;      contents of the rightmost column are unchanged, you should clear/refill this yourself
+
+	%asm {{
+		ldx  #0
+		ldy  #38
+-
+        .for row=0, row<=24, row+=1
+            lda  cbm.Screen + 40*row + 1,x
+            sta  cbm.Screen + 40*row + 0,x
+        .next
+		inx
+		dey
+		bpl  -
+
+		rts
+	}}
+}
+
+asmsub  scroll_right  () clobbers(A,X)  {
+	; ---- scroll the whole screen 1 character to the right
+	;      contents of the leftmost column are unchanged, you should clear/refill this yourself
+	%asm {{
+		ldx  #38
+-
+        .for row=0, row<=24, row+=1
+            lda  cbm.Screen + 40*row + 0,x
+            sta  cbm.Screen + 40*row + 1,x
+        .next
+		dex
+		bpl  -
+
+		rts
+	}}
+}
+
+asmsub  scroll_up  () clobbers(A,X)  {
+	; ---- scroll the whole screen 1 character up
+	;      contents of the bottom row are unchanged, you should refill/clear this yourself
+	%asm {{
+		ldx #39
+-
+        .for row=1, row<=24, row+=1
+            lda  cbm.Screen + 40*row,x
+            sta  cbm.Screen + 40*(row-1),x
+        .next
+		dex
+		bpl  -
+
+		rts
+	}}
+}
+
+asmsub  scroll_down  () clobbers(A,X)  {
+	; ---- scroll the whole screen 1 character down
+	;      contents of the top row are unchanged, you should refill/clear this yourself
+	%asm {{
+		ldx #39
+-
+        .for row=23, row>=0, row-=1
+            lda  cbm.Screen + 40*row,x
+            sta  cbm.Screen + 40*(row+1),x
+        .next
+		dex
+		bpl  -
+
+		rts
+	}}
+}
+
+romsub $FFD2 = chrout(ubyte char @ A)    ; for consistency. You can also use cbm.CHROUT directly ofcourse.
+
+asmsub  print (str text @ AY) clobbers(A,Y)  {
+	; ---- print null terminated string from A/Y
+	; note: the compiler contains an optimization that will replace
+	;       a call to this subroutine with a string argument of just one char,
+	;       by just one call to cbm.CHROUT of that single char.
+	%asm {{
+		sta  P8ZP_SCRATCH_B1
+		sty  P8ZP_SCRATCH_REG
+		ldy  #0
+-		lda  (P8ZP_SCRATCH_B1),y
+		beq  +
+		jsr  cbm.CHROUT
+		iny
+		bne  -
++		rts
+	}}
+}
+
+asmsub  print_ub0  (ubyte value @ A) clobbers(A,X,Y)  {
+	; ---- print the ubyte in A in decimal form, with left padding 0s (3 positions total)
+	%asm {{
+		jsr  conv.ubyte2decimal
+		pha
+		tya
+		jsr  cbm.CHROUT
+		pla
+		jsr  cbm.CHROUT
+		txa
+		jmp  cbm.CHROUT
+	}}
+}
+
+asmsub  print_ub  (ubyte value @ A) clobbers(A,X,Y)  {
+	; ---- print the ubyte in A in decimal form, without left padding 0s
+	%asm {{
+		jsr  conv.ubyte2decimal
+_print_byte_digits
+		pha
+		cpy  #'0'
+		beq  +
+		tya
+		jsr  cbm.CHROUT
+		pla
+		jsr  cbm.CHROUT
+		jmp  _ones
++       pla
+        cmp  #'0'
+        beq  _ones
+        jsr  cbm.CHROUT
+_ones   txa
+		jmp  cbm.CHROUT
+	}}
+}
+
+asmsub  print_b  (byte value @ A) clobbers(A,X,Y)  {
+	; ---- print the byte in A in decimal form, without left padding 0s
+	%asm {{
+		pha
+		cmp  #0
+		bpl  +
+		lda  #'-'
+		jsr  cbm.CHROUT
++		pla
+		jsr  conv.byte2decimal
+		jmp  print_ub._print_byte_digits
+	}}
+}
+
+asmsub  print_ubhex  (ubyte value @ A, bool prefix @ Pc) clobbers(A,X,Y)  {
+	; ---- print the ubyte in A in hex form (if Carry is set, a radix prefix '$' is printed as well)
+	%asm {{
+		bcc  +
+		pha
+		lda  #'$'
+		jsr  cbm.CHROUT
+		pla
++		jsr  conv.ubyte2hex
+		jsr  cbm.CHROUT
+		tya
+		jmp  cbm.CHROUT
+	}}
+}
+
+asmsub  print_ubbin  (ubyte value @ A, bool prefix @ Pc) clobbers(A,X,Y)  {
+	; ---- print the ubyte in A in binary form (if Carry is set, a radix prefix '%' is printed as well)
+	%asm {{
+		sta  P8ZP_SCRATCH_B1
+		bcc  +
+		lda  #'%'
+		jsr  cbm.CHROUT
++		ldy  #8
+-		lda  #'0'
+		asl  P8ZP_SCRATCH_B1
+		bcc  +
+		lda  #'1'
++		jsr  cbm.CHROUT
+		dey
+		bne  -
+		rts
+	}}
+}
+
+asmsub  print_uwbin  (uword value @ AY, bool prefix @ Pc) clobbers(A,X,Y)  {
+	; ---- print the uword in A/Y in binary form (if Carry is set, a radix prefix '%' is printed as well)
+	%asm {{
+		pha
+		tya
+		jsr  print_ubbin
+		pla
+		clc
+		jmp  print_ubbin
+	}}
+}
+
+asmsub  print_uwhex  (uword value @ AY, bool prefix @ Pc) clobbers(A,X,Y)  {
+	; ---- print the uword in A/Y in hexadecimal form (4 digits)
+	;      (if Carry is set, a radix prefix '$' is printed as well)
+	%asm {{
+		pha
+		tya
+		jsr  print_ubhex
+		pla
+		clc
+		jmp  print_ubhex
+	}}
+}
+
+asmsub  print_uw0  (uword value @ AY) clobbers(A,X,Y)  {
+	; ---- print the uword in A/Y in decimal form, with left padding 0s (5 positions total)
+	%asm {{
+		jsr  conv.uword2decimal
+		ldy  #0
+-		lda  conv.uword2decimal.decTenThousands,y
+        beq  +
+		jsr  cbm.CHROUT
+		iny
+		bne  -
++		rts
+	}}
+}
+
+asmsub  print_uw  (uword value @ AY) clobbers(A,X,Y)  {
+	; ---- print the uword in A/Y in decimal form, without left padding 0s
+	%asm {{
+		jsr  conv.uword2decimal
+		ldy  #0
+-		lda  conv.uword2decimal.decTenThousands,y
+		beq  _allzero
+		cmp  #'0'
+		bne  _gotdigit
+		iny
+		bne  -
+
+_gotdigit
+		jsr  cbm.CHROUT
+		iny
+		lda  conv.uword2decimal.decTenThousands,y
+		bne  _gotdigit
+		rts
+_allzero
+        lda  #'0'
+        jmp  cbm.CHROUT
+	}}
+}
+
+asmsub  print_w  (word value @ AY) clobbers(A,X,Y)  {
+	; ---- print the (signed) word in A/Y in decimal form, without left padding 0's
+	%asm {{
+		cpy  #0
+		bpl  +
+		pha
+		lda  #'-'
+		jsr  cbm.CHROUT
+		tya
+		eor  #255
+		tay
+		pla
+		eor  #255
+		clc
+		adc  #1
+		bcc  +
+		iny
++		jmp  print_uw
+	}}
+}
+
+asmsub  input_chars  (uword buffer @ AY) clobbers(A) -> ubyte @ Y  {
+	; ---- Input a string (max. 80 chars) from the keyboard. Returns length in Y. (string is terminated with a 0 byte as well)
+	;      It assumes the keyboard is selected as I/O channel!
+
+	%asm {{
+		sta  P8ZP_SCRATCH_W1
+		sty  P8ZP_SCRATCH_W1+1
+		ldy  #0				; char counter = 0
+-		jsr  cbm.CHRIN
+		cmp  #$0d			; return (ascii 13) pressed?
+		beq  +				; yes, end.
+		sta  (P8ZP_SCRATCH_W1),y	; else store char in buffer
+		iny
+		bne  -
++		lda  #0
+		sta  (P8ZP_SCRATCH_W1),y	; finish string with 0 byte
+		rts
+
+	}}
+}
+
+asmsub  setchr  (ubyte col @X, ubyte row @Y, ubyte character @A) clobbers(A, Y)  {
+	; ---- sets the character in the screen matrix at the given position
+	%asm {{
+		pha
+		tya
+		asl  a
+		tay
+		lda  _screenrows+1,y
+		sta  _mod+2
+		txa
+		clc
+		adc  _screenrows,y
+		sta  _mod+1
+		bcc  +
+		inc  _mod+2
++		pla
+_mod		sta  $ffff		; modified
+		rts
+
+_screenrows	.word  $8000 + range(0, 1000, 40)
+	}}
+}
+
+asmsub  getchr  (ubyte col @A, ubyte row @Y) clobbers(Y) -> ubyte @ A {
+	; ---- get the character in the screen matrix at the given location
+	%asm  {{
+		pha
+		tya
+		asl  a
+		tay
+		lda  setchr._screenrows+1,y
+		sta  _mod+2
+		pla
+		clc
+		adc  setchr._screenrows,y
+		sta  _mod+1
+		bcc  _mod
+		inc  _mod+2
+_mod		lda  $ffff		; modified
+		rts
+	}}
+}
+
+sub  setcc  (ubyte column, ubyte row, ubyte char)  {
+	; ---- set char at the given position on the screen
+	%asm {{
+  		lda  row
+		asl  a
+		tay
+		lda  setchr._screenrows+1,y
+		sta  _charmod+2
+		lda  setchr._screenrows,y
+		clc
+		adc  column
+		sta  _charmod+1
+		bcc  +
+		inc  _charmod+2
++		lda  char
+_charmod	sta  $ffff		; modified
+		rts
+	}}
+}
+
+asmsub  plot  (ubyte col @ Y, ubyte row @ X) {
+	%asm  {{
+		clc
+		jmp  cbm.PLOT
+	}}
+}
+
+asmsub width() clobbers(X,Y) -> ubyte @A {
+    ; -- returns the text screen width (number of columns)
+    %asm {{
+        lda  $d5
+        rts
+    }}
+}
+
+asmsub height() clobbers(X, Y) -> ubyte @A {
+    ; -- returns the text screen height (number of rows)
+    %asm {{
+        lda  #25
+        rts
+    }}
+}
+
+}

compiler/src/prog8/CompilerMain.kt

@@ -48,7 +48,7 @@ private fun compileMain(args: Array<String>): Boolean {
     val sourceDirs by cli.option(ArgType.String, fullName="srcdirs", description = "list of extra paths, separated with ${File.pathSeparator}, to search in for imported modules").multiple().delimiter(File.pathSeparator)
     val includeSourcelines by cli.option(ArgType.Boolean, fullName = "sourcelines", description = "include original Prog8 source lines in generated asm code")
     val splitWordArrays by cli.option(ArgType.Boolean, fullName = "splitarrays", description = "treat all word arrays as tagged with @split to make them lsb/msb split in memory")
-    val compilationTarget by cli.option(ArgType.String, fullName = "target", description = "target output of the compiler (one of '${C64Target.NAME}', '${C128Target.NAME}', '${Cx16Target.NAME}', '${AtariTarget.NAME}', '${VMTarget.NAME}') (required)")
+    val compilationTarget by cli.option(ArgType.String, fullName = "target", description = "target output of the compiler (one of '${C64Target.NAME}', '${C128Target.NAME}', '${Cx16Target.NAME}', '${AtariTarget.NAME}', '${PETTarget.NAME}', '${VMTarget.NAME}') (required)")
     val startVm by cli.option(ArgType.Boolean, fullName = "vm", description = "load and run a .p8ir IR source file in the VM")
     val watchMode by cli.option(ArgType.Boolean, fullName = "watch", description = "continuous compilation mode (watch for file changes)")
     val varsHighBank by cli.option(ArgType.Int, fullName = "varshigh", description = "put uninitialized variables in high memory area instead of at the end of the program. On the cx16 target the value specifies the HiRAM bank to use, on other systems this value is ignored.")
@@ -83,7 +83,7 @@ private fun compileMain(args: Array<String>): Boolean {
             return false
         }
 
-        if (compilationTarget !in setOf(C64Target.NAME, C128Target.NAME, Cx16Target.NAME, AtariTarget.NAME, VMTarget.NAME)) {
+        if (compilationTarget !in setOf(C64Target.NAME, C128Target.NAME, Cx16Target.NAME, AtariTarget.NAME, PETTarget.NAME, VMTarget.NAME)) {
             System.err.println("Invalid compilation target: $compilationTarget")
             return false
         }

compiler/src/prog8/compiler/Compiler.kt

@@ -52,6 +52,7 @@ fun compileProgram(args: CompilerArguments): CompilationResult? {
             C64Target.NAME -> C64Target()
             C128Target.NAME -> C128Target()
             Cx16Target.NAME -> Cx16Target()
+            PETTarget.NAME -> PETTarget()
             AtariTarget.NAME -> AtariTarget()
             VMTarget.NAME -> VMTarget()
             else -> throw IllegalArgumentException("invalid compilation target")

docs/source/compiling.rst

@@ -113,8 +113,8 @@ One or more .p8 module files
 
 ``-target <compilation target>``
     Sets the target output of the compiler. This option is required.
-    ``c64`` = Commodore 64, ``c128`` = Commodore 128, ``cx16`` = Commander X16, ``atari`` = Atari 800 XL,
-    ``virtual`` = builtin virtual machine.
+    ``c64`` = Commodore 64, ``c128`` = Commodore 128, ``cx16`` = Commander X16, ``pet32`` - Commodore PET model 4032,
+    ``atari`` = Atari 800 XL, ``virtual`` = builtin virtual machine.
 
 ``-srcdirs <pathlist>``
     Specify a list of extra paths (separated with ':'), to search in for imported modules.

docs/source/libraries.rst

@@ -35,7 +35,7 @@ as ROM/Kernal subroutine definitions, memory location constants, and utility sub
 Many of these definitions overlap for the C64 and Commander X16 targets so it is still possible
 to write programs that work on both targets without modifications.
 
-This module is usually imported automatically and can provide definitions in the ``sys``, ``c64``, ``cx16``, ``c128``, ``atari`` blocks
+This module is usually imported automatically and can provide definitions in the ``sys``, ``cbm``, ``c64``, ``cx16``, ``c128``, ``atari`` blocks
 depending on the chosen compilation target. Read the `syslib source code <https://github.com/irmen/prog8/tree/master/compiler/res/prog8lib>`_ for the correct compilation target to see exactly what is there.
 
 

docs/source/targetsystem.rst

@@ -14,6 +14,7 @@ Currently these machines can be selected as a compilation target (via the ``-tar
 - 'c64': the Commodore 64
 - 'cx16': the `Commander X16 <https://www.commanderx16.com/>`_
 - 'c128': the Commodore 128  (*limited support*)
+- 'pet32': the Commodore PET 4032  (*experimental support*)
 - 'atari': the Atari 800 XL  (*experimental support*)
 - 'virtual': a builtin virtual machine
 

docs/source/todo.rst

@@ -48,6 +48,7 @@ Libraries:
 
 - fix the problems in atari target, and flesh out its libraries.
 - c128 target: make syslib more complete (missing kernal routines)?
+- pet32 target: make syslib more complete (missing kernal routines)?
 - c64: make the graphics.BITMAP_ADDRESS configurable (VIC banking)
 
 

gradle.properties

@@ -5,4 +5,4 @@ org.gradle.daemon=true
 kotlin.code.style=official
 javaVersion=11
 kotlinVersion=1.9.0
-version=9.3
+version=9.4-SNAPSHOT