prog8/compiler/build.gradle

plugins {
    id 'java'
    id 'application'
    id "org.jetbrains.kotlin.jvm" version "1.4.30"
    id 'org.jetbrains.dokka' version "0.9.18"
    id 'com.github.johnrengelman.shadow' version '6.1.0'
}

targetCompatibility = 11
sourceCompatibility = 11

repositories {
    mavenLocal()
    mavenCentral()
    maven { url "https://kotlin.bintray.com/kotlinx" }
}

def prog8version = rootProject.file('compiler/res/version.txt').text.trim()

dependencies {
    implementation project(':compilerAst')
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk8"
    // implementation "org.jetbrains.kotlin:kotlin-reflect"
    implementation 'org.jetbrains.kotlinx:kotlinx-cli:0.3.1'
    // implementation 'net.razorvine:ksim65:1.8'
    // implementation "com.github.hypfvieh:dbus-java:3.2.4"

    testImplementation "org.jetbrains.kotlin:kotlin-test-junit5"
    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.3.2'
    testImplementation 'org.hamcrest:hamcrest-junit:2.0.0.0'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.3.2'
}

compileKotlin {
    kotlinOptions {
        jvmTarget = "11"
        useIR = true
        // verbose = true
        // freeCompilerArgs += "-XXLanguage:+NewInference"
    }
}

compileTestKotlin {
    kotlinOptions {
        jvmTarget = "11"
        useIR = true
    }
}

sourceSets {
    main {
        java {
            srcDirs = ["${project.projectDir}/src"]
        }
        resources {
            srcDirs = ["${project.projectDir}/res"]
        }
    }
    test {
        java {
            srcDirs = ["${project.projectDir}/test"]
        }
    }
}

startScripts.enabled = true

application {
    mainClass = 'prog8.CompilerMainKt'
    mainClassName = 'prog8.CompilerMainKt'  // deprecated
    applicationName = 'p8compile'
}

artifacts {
    archives shadowJar
}


shadowJar {
    archiveBaseName = 'prog8compiler'
    archiveVersion = prog8version
    // minimize()
}


test {
    // Enable JUnit 5 (Gradle 4.6+).
    useJUnitPlatform()

    // Always run tests, even when nothing changed.
    dependsOn 'cleanTest'

    // Show test results.
    testLogging {
        events "skipped", "failed"
    }
}


dokka {
    outputFormat = 'html'
    outputDirectory = "$buildDir/kdoc"
}

task wrapper(type: Wrapper) {
    gradleVersion = '6.7'
}