From 5fca4ad4f2070812d4ee3c091ffe12b844e9eb9a Mon Sep 17 00:00:00 2001
From: 4am <a2_4am@sent.com>
Date: Fri, 4 Sep 2020 14:07:41 -0400
Subject: [PATCH] add HGR 2-bit fizzle [thanks John B.]

---
 res/FX.CONF                 |  3 +-
 src/fx/fx.hgr.2bit.fizzle.a | 77 +++++++++++++++++++++++++++++++++++++
 2 files changed, 79 insertions(+), 1 deletion(-)
 create mode 100644 src/fx/fx.hgr.2bit.fizzle.a

diff --git a/res/FX.CONF b/res/FX.CONF
index 4c7c30e26..c6aeffb87 100644
--- a/res/FX.CONF
+++ b/res/FX.CONF
@@ -8,7 +8,7 @@ SOFT.UD
 HEART.IN
 CRYSTAL
 STAR.RIPPLE
-BIT.FIZZLE
+BIT2.FIZZLE
 MEETINTHEMIDDLE
 APPLE.IN
 FLOWER.RAD.RIP
@@ -24,6 +24,7 @@ STAR
 FLOWER.IN
 R.BY.PIXEL
 WAVY.IRIS
+BIT.FIZZLE
 APPLE
 MANDELBROT.RIP
 SOFT.L
diff --git a/src/fx/fx.hgr.2bit.fizzle.a b/src/fx/fx.hgr.2bit.fizzle.a
new file mode 100644
index 000000000..af8a3d69d
--- /dev/null
+++ b/src/fx/fx.hgr.2bit.fizzle.a
@@ -0,0 +1,77 @@
+;license:MIT
+;(c) 2017-2020 by qkumba/4am/John Brooks
+
+!cpu 6502
+!to "build/FX/BIT2.FIZZLE",plain
+*=$6000
+
+addrs     = $6100         ; [256 bytes]
+copymasks = $6200         ; [128 bytes]
+
+         jsr   swapzp
+         ldx   #0
+         lda   #%00000011
+--       ldy   #$20
+         ora   #%10000000
+-        sta   copymasks, x
+         inx
+         dey
+         bne   -
+         asl
+         asl
+         bne   --
+         clc
+         ldx   #0
+--       ldy   #$20
+         tya
+-        sta   addrs, x
+         adc   #1
+         inx
+         dey
+         bne   -
+         txa
+         bne   --
+         jsr   $0
+swapzp   ldx   #(end-start-1)
+-        lda   $0, x
+         pha
+         lda   start, x
+         sta   $0, x
+         pla
+         sta   start, x
+         dex
+         bpl   -
+         rts
+
+start
+!pseudopc 0 {
+; in: X,Y=0
+loop     txa
+loop1    eor   #$60
+         tax
+loop2    lda   addrs, x
+         sta   <dst+2
+         eor   #$60
+         sta   <src+2
+         lda   (<dst+1), y
+src      eor   $FD00, y
+         and   copymasks, x
+         eor   (<dst+1), y
+dst      sta   $FD00, y
+         txa
+         lsr
+         tax
+         tya
+         ror
+         tay
+         bcc   loop2
+         bne   loop
+         bit   $C000
+         bmi   exit
+         txa
+         bne   loop1
+exit     lda   $4000
+         sta   $2000
+         rts
+}
+end