;license:MIT
;(c) 2019 by qkumba/Frank M.

!cpu 6502
!to "build/PRELAUNCH.INDEXED/MD",plain
*=$106

    !source "src/prelaunch/common.a"

         +USES_TEXT_PAGE_2
         inc   $3F4       ; reboot on reset
         clc
         bcc   cheat3

cheat2
         jsr   $20d

cheat64
         lda   #$a5
         sta   $1da7
         sta   $9bf
         rts

cheat1
         ldy   #<cheat2
         sty   $209
         ldy   #>cheat2
         sty   $20a
         bne   $19e

cheat3

         lda   #$60
         sta   $83f
         jsr   $800

         +GET_MACHINE_STATUS
         and   #CHEATS_ENABLED
         pha

+        lda   $847
         beq   cheat48

         lda   #$60
         sta   $d15
         jsr   $ce8

         pla
         beq   +

         lda   #<cheat4
         sta   $d137
         lda   #>cheat4
         sta   $d138

+        lda   #<fixgs
         sta   $89ee
         lda   #>fixgs
         sta   $89ef
         jmp   $d100

cheat4
         jsr   $d13b
         jmp   cheat64

cheat48
         pla
         beq   +
         lda   #<cheat1
         sta   $1040
         lda   #>cheat1
         sta   $1041
+        jmp   $1000

fixgs
         sei
         jmp   $08b2

!if * > $1C0 {
  !error "code is too large, ends at ", *
}