;license:MIT
;(c) 2021-2022 by Frank M., qkumba

!cpu 6502
!to "build/PRELAUNCH.INDEXED/STARBALL",plain
*=$106

    !source "src/prelaunch/common.a"

         +ENABLE_ACCEL
         lda   #<hook
         sta   $A1E+1
         lda   #>hook
         sta   $A1E+2
         jmp   $800       ; decompress

hook     ldx   #0
         stx   $9E52
         inx
         stx   $9E53      ; reset vector fix

         +READ_RAM2_NO_WRITE
         lda   MachineStatus
         and   #CHEATS_ENABLED
         beq   +
         lda   #<callback
         sta   $BD07
         lda   #>callback
         sta   $BD08
+
         jsr   DisableAccelerator
         +READ_ROM_NO_WRITE
         jmp   $9D84

callback
         pla
         pla
         jsr   $BD5F
         jsr   $BD09
         lda   $B7EC
         cmp   #$15
         bne   +
         ldx   $B7ED
         dex
         bne   +
         lda   #$ad
         sta   $96DE      ; patch - don't decrease balls
+        clc
         rts

!if * > $1C0 {
  !error "code is too large, ends at ", *
}