mirror of
https://github.com/autc04/Retro68.git
synced 2024-11-24 07:31:32 +00:00
93 lines
3.2 KiB
Plaintext
93 lines
3.2 KiB
Plaintext
|
# mmap(2) blacklisting. Some platforms provide the mmap library routine
|
||
|
|
# but don't support all of the features we need from it.
|
||
|
|
AC_DEFUN([AC_FUNC_MMAP_BLACKLIST],
|
||
|
|
[
|
||
|
|
AC_CHECK_HEADER([sys/mman.h],
|
||
|
|
[libffi_header_sys_mman_h=yes], [libffi_header_sys_mman_h=no])
|
||
|
|
AC_CHECK_FUNC([mmap], [libffi_func_mmap=yes], [libffi_func_mmap=no])
|
||
|
|
if test "$libffi_header_sys_mman_h" != yes \
|
||
|
|
|| test "$libffi_func_mmap" != yes; then
|
||
|
|
ac_cv_func_mmap_file=no
|
||
|
|
ac_cv_func_mmap_dev_zero=no
|
||
|
|
ac_cv_func_mmap_anon=no
|
||
|
|
else
|
||
|
|
AC_CACHE_CHECK([whether read-only mmap of a plain file works],
|
||
|
|
ac_cv_func_mmap_file,
|
||
|
|
[# Add a system to this blacklist if
|
||
|
|
# mmap(0, stat_size, PROT_READ, MAP_PRIVATE, fd, 0) doesn't return a
|
||
|
|
# memory area containing the same data that you'd get if you applied
|
||
|
|
# read() to the same fd. The only system known to have a problem here
|
||
|
|
# is VMS, where text files have record structure.
|
||
|
|
case "$host_os" in
|
||
|
|
vms* | ultrix*)
|
||
|
|
ac_cv_func_mmap_file=no ;;
|
||
|
|
*)
|
||
|
|
ac_cv_func_mmap_file=yes;;
|
||
|
|
esac])
|
||
|
|
AC_CACHE_CHECK([whether mmap from /dev/zero works],
|
||
|
|
ac_cv_func_mmap_dev_zero,
|
||
|
|
[# Add a system to this blacklist if it has mmap() but /dev/zero
|
||
|
|
# does not exist, or if mmapping /dev/zero does not give anonymous
|
||
|
|
# zeroed pages with both the following properties:
|
||
|
|
# 1. If you map N consecutive pages in with one call, and then
|
||
|
|
# unmap any subset of those pages, the pages that were not
|
||
|
|
# explicitly unmapped remain accessible.
|
||
|
|
# 2. If you map two adjacent blocks of memory and then unmap them
|
||
|
|
# both at once, they must both go away.
|
||
|
|
# Systems known to be in this category are Windows (all variants),
|
||
|
|
# VMS, and Darwin.
|
||
|
|
case "$host_os" in
|
||
|
|
vms* | cygwin* | pe | mingw* | darwin* | ultrix* | hpux10* | hpux11.00)
|
||
|
|
ac_cv_func_mmap_dev_zero=no ;;
|
||
|
|
*)
|
||
|
|
ac_cv_func_mmap_dev_zero=yes;;
|
||
|
|
esac])
|
||
|
|
|
||
|
|
# Unlike /dev/zero, the MAP_ANON(YMOUS) defines can be probed for.
|
||
|
|
AC_CACHE_CHECK([for MAP_ANON(YMOUS)], ac_cv_decl_map_anon,
|
||
|
|
[AC_TRY_COMPILE(
|
||
|
|
[#include <sys/types.h>
|
||
|
|
#include <sys/mman.h>
|
||
|
|
#include <unistd.h>
|
||
|
|
|
||
|
|
#ifndef MAP_ANONYMOUS
|
||
|
|
#define MAP_ANONYMOUS MAP_ANON
|
||
|
|
#endif
|
||
|
|
],
|
||
|
|
[int n = MAP_ANONYMOUS;],
|
||
|
|
ac_cv_decl_map_anon=yes,
|
||
|
|
ac_cv_decl_map_anon=no)])
|
||
|
|
|
||
|
|
if test $ac_cv_decl_map_anon = no; then
|
||
|
|
ac_cv_func_mmap_anon=no
|
||
|
|
else
|
||
|
|
AC_CACHE_CHECK([whether mmap with MAP_ANON(YMOUS) works],
|
||
|
|
ac_cv_func_mmap_anon,
|
||
|
|
[# Add a system to this blacklist if it has mmap() and MAP_ANON or
|
||
|
|
# MAP_ANONYMOUS, but using mmap(..., MAP_PRIVATE|MAP_ANONYMOUS, -1, 0)
|
||
|
|
# doesn't give anonymous zeroed pages with the same properties listed
|
||
|
|
# above for use of /dev/zero.
|
||
|
|
# Systems known to be in this category are Windows, VMS, and SCO Unix.
|
||
|
|
case "$host_os" in
|
||
|
|
vms* | cygwin* | pe | mingw* | sco* | udk* )
|
||
|
|
ac_cv_func_mmap_anon=no ;;
|
||
|
|
*)
|
||
|
|
ac_cv_func_mmap_anon=yes;;
|
||
|
|
esac])
|
||
|
|
fi
|
||
|
|
fi
|
||
|
|
|
||
|
|
if test $ac_cv_func_mmap_file = yes; then
|
||
|
|
AC_DEFINE(HAVE_MMAP_FILE, 1,
|
||
|
|
[Define if read-only mmap of a plain file works.])
|
||
|
|
fi
|
||
|
|
if test $ac_cv_func_mmap_dev_zero = yes; then
|
||
|
|
AC_DEFINE(HAVE_MMAP_DEV_ZERO, 1,
|
||
|
|
[Define if mmap of /dev/zero works.])
|
||
|
|
fi
|
||
|
|
if test $ac_cv_func_mmap_anon = yes; then
|
||
|
|
AC_DEFINE(HAVE_MMAP_ANON, 1,
|
||
|
|
[Define if mmap with MAP_ANON(YMOUS) works.])
|
||
|
|
fi
|
||
|
|
])
|