/*
	 Copyright 2017 Wolfgang Thaller.

	 This file is part of Retro68.

	 Retro68 is free software: you can redistribute it and/or modify
	 it under the terms of the GNU General Public License as published by
	 the Free Software Foundation, either version 3 of the License, or
	 (at your option) any later version.

	 Retro68 is distributed in the hope that it will be useful,
	 but WITHOUT ANY WARRANTY; without even the implied warranty of
	 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
	 GNU General Public License for more details.

	 You should have received a copy of the GNU General Public License
	 along with Retro68.  If not, see <http://www.gnu.org/licenses/>.
*/

#include "Elf2Mac.h"

#include <fstream>

const char * defaultLdScript = R"ld(/* ld script for Elf2Mac */
ENTRY( _start )
SECTIONS
{
   .text :	{
    _stext = . ;
        */libretrocrt.a:*(.text*)
       *(.text*)

       *(.stub)
       *(.gnu.linkonce.t*)
       *(.glue_7t)
       *(.glue_7)
       *(.jcr)
       . = ALIGN (4) ;
       __init_section = . ;
       KEEP (*(.init))
       __init_section_end = . ;
       __fini_section = . ;
       KEEP (*(.fini))
       __fini_section_end = . ;

       *(.eh_frame_hdr)
       KEEP(*(.eh_frame))
       KEEP(*(.gcc_except_table))
       KEEP(*(.gcc_except_table.*))
       . = ALIGN(0x4) ;
       _etext = . ;
   }
   .data : {
       _sdata = . ;
               *(.got.plt)
               *(.got)
               FILL(0) ;
               . = ALIGN(0x20) ;
               LONG(-1)
       . = ALIGN(0x20) ;
       *(.rodata)
       *(.rodata1)
       *(.rodata.*)
       *(.gnu.linkonce.r*)
       *(.data)
       *(.data1)
       *(.data.*)
       *(.gnu.linkonce.d*)

               . = ALIGN(4) ;
       /* gcc uses crtbegin.o to find the start of
          the constructors, so we make sure it is
          first.  Because this is a wildcard, it
          doesn't matter if the user does not
          actually link against crtbegin.o; the
          linker won't look for a file to match a
          wildcard.  The wildcard also means that it
          doesn't matter which directory crtbegin.o
          is in.  */
       KEEP (*crtbegin*.o(.ctors))
       /* We don't want to include the .ctor section from
          from the crtend.o file until after the sorted ctors.
          The .ctor section from the crtend file contains the
          end of ctors marker and it must be last */
       KEEP (*(EXCLUDE_FILE (*crtend*.o ) .ctors))
       KEEP (*(SORT(.ctors.*)))
       KEEP (*(.ctors))
       KEEP (*crtbegin*.o(.dtors))
       KEEP (*(EXCLUDE_FILE (*crtend*.o ) .dtors))
       KEEP (*(SORT(.dtors.*)))
       KEEP (*(.dtors))

       *(.tm_clone_table)
        . = ALIGN(0x4);
       _edata = . ;
   }
   .bss ALIGN(0x4) : {
               _sbss = .;
               *(.dynsbss)
               *(.sbss)
               *(.sbss.*)
               *(.scommon)
               *(.dynbss)
               *(.bss)
               *(.bss.*)
               *(.bss*)
               *(.gnu.linkonce.b*)
               *(COMMON)
               . = ALIGN(0x10) ;
               _ebss = . ;
   }
       /DISCARD/ : { *(.note.GNU-stack) }
       /* Stabs debugging sections.    */
       .stab 0 : { *(.stab) }
       .stabstr 0 : { *(.stabstr) }
       .stab.excl 0 : { *(.stab.excl) }
       .stab.exclstr 0 : { *(.stab.exclstr) }
       .stab.index 0 : { *(.stab.index) }
       .stab.indexstr 0 : { *(.stab.indexstr) }
       .comment 0 : { *(.comment) }
       /* DWARF debug sections.
          Symbols in the DWARF debugging sections are relative to the beginning
          of the section so we begin them at 0.  */
       /* DWARF 1 */
       .debug          0 : { *(.debug) }
       .line           0 : { *(.line) }
       /* GNU DWARF 1 extensions */
       .debug_srcinfo  0 : { *(.debug_srcinfo) }
       .debug_sfnames  0 : { *(.debug_sfnames) }
       /* DWARF 1.1 and DWARF 2 */
       .debug_aranges  0 : { *(.debug_aranges) }
       .debug_pubnames 0 : { *(.debug_pubnames) }
       /* DWARF 2 */
       .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
       .debug_abbrev   0 : { *(.debug_abbrev) }
       .debug_line     0 : { *(.debug_line) }
       .debug_frame    0 : { *(.debug_frame) }
       .debug_str      0 : { *(.debug_str) }
       .debug_loc      0 : { *(.debug_loc) }
       .debug_macinfo  0 : { *(.debug_macinfo) }
       /* SGI/MIPS DWARF 2 extensions */
       .debug_weaknames 0 : { *(.debug_weaknames) }
       .debug_funcnames 0 : { *(.debug_funcnames) }
       .debug_typenames 0 : { *(.debug_typenames) }
       .debug_varnames  0 : { *(.debug_varnames) }

   /* /DISCARD/ : { *(*) } */
}

)ld";


void CreateLdScript(std::ofstream& out)
{
	out << defaultLdScript;
}