mirror of
https://github.com/kanjitalk755/macemu.git
synced 2024-09-29 06:54:33 +00:00
1b5a3a6069
command checking on MacOS X.
1262 lines
40 KiB
Plaintext
1262 lines
40 KiB
Plaintext
dnl Process this file with autoconf to produce a configure script.
|
|
dnl Written in 2002 by Christian Bauer et al.
|
|
|
|
AC_INIT([Basilisk II], 1.0, [Christian.Bauer@uni-mainz.de], BasiliskII)
|
|
AC_CONFIG_SRCDIR(main_unix.cpp)
|
|
AC_PREREQ(2.52)
|
|
AC_CONFIG_HEADER(config.h)
|
|
|
|
dnl Aliases for PACKAGE and VERSION macros.
|
|
AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE_NAME", [Define this program name.])
|
|
AC_DEFINE_UNQUOTED(VERSION, "$PACKAGE_VERSION", [Define this program version.])
|
|
|
|
dnl Some systems do not put corefiles in the currect directory, avoid saving
|
|
dnl cores for the configure tests since some are intended to dump core.
|
|
ulimit -c 0
|
|
|
|
dnl Video options.
|
|
AC_ARG_ENABLE(xf86-dga, [ --enable-xf86-dga use the XFree86 DGA extension [default=yes]], [WANT_XF86_DGA=$enableval], [WANT_XF86_DGA=yes])
|
|
AC_ARG_ENABLE(xf86-vidmode, [ --enable-xf86-vidmode use the XFree86 VidMode extension [default=yes]], [WANT_XF86_VIDMODE=$enableval], [WANT_XF86_VIDMODE=yes])
|
|
AC_ARG_ENABLE(fbdev-dga, [ --enable-fbdev-dga use direct frame buffer access via /dev/fb [default=yes]], [WANT_FBDEV_DGA=$enableval], [WANT_FBDEV_DGA=yes])
|
|
AC_ARG_ENABLE(vosf, [ --enable-vosf enable video on SEGV signals [default=yes]], [WANT_VOSF=$enableval], [WANT_VOSF=yes])
|
|
|
|
dnl SDL options.
|
|
AC_ARG_ENABLE(sdl-video, [ --enable-sdl-video use SDL for video graphics [default=no]], [WANT_SDL_VIDEO=$enableval], [WANT_SDL_VIDEO=no])
|
|
|
|
dnl JIT compiler options.
|
|
AC_ARG_ENABLE(jit-compiler, [ --enable-jit-compiler enable JIT compiler [default=no]], [WANT_JIT=$enableval], [WANT_JIT=no])
|
|
AC_ARG_ENABLE(jit-debug, [ --enable-jit-debug activate native code disassemblers [default=no]], [WANT_JIT_DEBUG=$enableval], [WANT_JIT_DEBUG=no])
|
|
|
|
dnl FPU emulation core.
|
|
AC_ARG_ENABLE(fpe,
|
|
[ --enable-fpe=FPE specify which fpu emulator to use [default=auto]],
|
|
[ case "$enableval" in
|
|
dnl default is always ieee, if architecture has this fp format
|
|
auto) FPE_CORE_TEST_ORDER="ieee uae";;
|
|
ieee) FPE_CORE_TEST_ORDER="ieee";;
|
|
uae) FPE_CORE_TEST_ORDER="uae";;
|
|
x86) FPE_CORE_TEST_ORDER="x86";;
|
|
*) AC_MSG_ERROR([--enable-fpe takes only one of the following values: auto, x86, ieee, uae]);;
|
|
esac
|
|
],
|
|
[ FPE_CORE_TEST_ORDER="ieee uae"
|
|
])
|
|
|
|
dnl Addressing modes.
|
|
AC_ARG_ENABLE(addressing,
|
|
[ --enable-addressing=AM specify the addressing mode to use [default=fastest]],
|
|
[ case "$enableval" in
|
|
real) ADDRESSING_TEST_ORDER="real";;
|
|
direct) ADDRESSING_TEST_ORDER="direct";;
|
|
banks) ADDRESSING_TEST_ORDER="banks";;
|
|
fastest)ADDRESSING_TEST_ORDER="direct banks";;
|
|
*) AC_MSG_ERROR([--enable-addressing takes only one of the following values: fastest, real, direct, banks]);;
|
|
esac
|
|
],
|
|
[ ADDRESSING_TEST_ORDER="direct banks"
|
|
])
|
|
|
|
dnl External packages.
|
|
AC_ARG_WITH(esd, [ --with-esd support ESD for sound under Linux/FreeBSD [default=yes]], [WANT_ESD=$withval], [WANT_ESD=yes])
|
|
AC_ARG_WITH(gtk, [ --with-gtk use GTK user interface [default=yes]], [WANT_GTK=$withval], [WANT_GTK=yes])
|
|
AC_ARG_WITH(mon, [ --with-mon use mon as debugger [default=yes]], [WANT_MON=$withval], [WANT_MON=yes])
|
|
|
|
dnl Canonical system information.
|
|
AC_CANONICAL_HOST
|
|
AC_CANONICAL_TARGET
|
|
|
|
dnl Target OS type (target is host if not cross-compiling).
|
|
case "$target_os" in
|
|
linux*) OS_TYPE=linux;;
|
|
netbsd*) OS_TYPE=netbsd;;
|
|
freebsd*) OS_TYPE=freebsd;;
|
|
solaris*) OS_TYPE=solaris;;
|
|
darwin*) OS_TYPE=darwin;;
|
|
*) OS_TYPE=`echo $target_os | sed -e 's/-/_/g' | sed -e 's/\./_/g'`;;
|
|
esac
|
|
DEFINES="$DEFINES -DOS_$OS_TYPE"
|
|
|
|
dnl Target CPU type.
|
|
HAVE_I386=no
|
|
HAVE_M68K=no
|
|
HAVE_SPARC=no
|
|
HAVE_POWERPC=no
|
|
HAVE_X86_64=no
|
|
case "$target_cpu" in
|
|
i386* | i486* | i586* | i686* | i786* ) HAVE_I386=yes;;
|
|
m68k* ) HAVE_M68K=yes;;
|
|
sparc* ) HAVE_SPARC=yes;;
|
|
powerpc* ) HAVE_POWERPC=yes;;
|
|
x86_64* ) HAVE_X86_64=yes;;
|
|
esac
|
|
|
|
dnl Checks for programs.
|
|
AC_PROG_CC
|
|
AC_PROG_CC_C_O
|
|
AC_PROG_CPP
|
|
AC_PROG_CXX
|
|
AC_PROG_MAKE_SET
|
|
AC_PROG_INSTALL
|
|
|
|
dnl We use mon if possible.
|
|
MONSRCS=
|
|
if [[ "x$WANT_MON" = "xyes" ]]; then
|
|
AC_MSG_CHECKING(for mon)
|
|
mon_srcdir=../../../mon/src
|
|
if grep mon_init $mon_srcdir/mon.h >/dev/null 2>/dev/null; then
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(ENABLE_MON, 1, [Define if using "mon".])
|
|
MONSRCS="$mon_srcdir/mon.cpp $mon_srcdir/mon_6502.cpp $mon_srcdir/mon_z80.cpp $mon_srcdir/mon_cmd.cpp $mon_srcdir/mon_disass.cpp $mon_srcdir/mon_ppc.cpp $mon_srcdir/mon_lowmem.cpp $mon_srcdir/disass/floatformat.c $mon_srcdir/disass/i386-dis.c $mon_srcdir/disass/m68k-dis.c $mon_srcdir/disass/m68k-opc.c"
|
|
CXXFLAGS="$CXXFLAGS -I$mon_srcdir -I$mon_srcdir/disass"
|
|
AC_CHECK_LIB(ncurses, tgetent, ,
|
|
AC_CHECK_LIB(termcap, tgetent, ,
|
|
AC_CHECK_LIB(termlib, tgetent, ,
|
|
AC_CHECK_LIB(terminfo, tgetent, ,
|
|
AC_CHECK_LIB(Hcurses, tgetent, ,
|
|
AC_CHECK_LIB(curses, tgetent))))))
|
|
AC_CHECK_LIB(readline, readline)
|
|
else
|
|
AC_MSG_RESULT(no)
|
|
AC_MSG_WARN([Could not find mon, ignoring --with-mon.])
|
|
WANT_MON=no
|
|
fi
|
|
fi
|
|
|
|
dnl Checks for libraries.
|
|
AC_CHECK_LIB(posix4, sem_init)
|
|
AC_CHECK_LIB(rt, timer_create)
|
|
|
|
dnl Do we need SDL?
|
|
WANT_SDL=no
|
|
SDL_SUPPORT="none"
|
|
if [[ "x$WANT_SDL_VIDEO" = "xyes" ]]; then
|
|
WANT_SDL=yes
|
|
WANT_XF86_DGA=no
|
|
WANT_XF86_VIDMODE=no
|
|
WANT_FBDEV_DGA=no
|
|
SDL_SUPPORT="video"
|
|
fi
|
|
if [[ "x$WANT_SDL" = "xyes" ]]; then
|
|
AC_PATH_PROG(sdl_config, "sdl-config")
|
|
if [[ -n "$sdl_config" ]]; then
|
|
sdl_cflags=`$sdl_config --cflags`
|
|
sdl_libs=`$sdl_config --libs`
|
|
CFLAGS="$CFLAGS $sdl_cflags"
|
|
CXXFLAGS="$CXXFLAGS $sdl_cflags"
|
|
LIBS="$LIBS $sdl_libs"
|
|
else
|
|
WANT_SDL=no
|
|
fi
|
|
fi
|
|
|
|
dnl We need X11, if not using SDL.
|
|
if [[ "x$WANT_SDL" = "xno" ]]; then
|
|
AC_PATH_XTRA
|
|
if [[ "x$no_x" = "xyes" ]]; then
|
|
AC_MSG_ERROR([You need X11 to run Basilisk II.])
|
|
fi
|
|
CFLAGS="$CFLAGS $X_CFLAGS"
|
|
CXXFLAGS="$CXXFLAGS $X_CFLAGS"
|
|
LIBS="$LIBS $X_PRE_LIBS $X_LIBS -lX11 -lXext $X_EXTRA_LIBS"
|
|
fi
|
|
|
|
dnl We want pthreads. Try libpthread first, then libc_r (FreeBSD), then PTL.
|
|
HAVE_PTHREADS=yes
|
|
AC_CHECK_LIB(pthread, pthread_create, , [
|
|
AC_CHECK_LIB(c_r, pthread_create, , [
|
|
AC_CHECK_LIB(PTL, pthread_create, , [
|
|
HAVE_PTHREADS=no
|
|
])
|
|
])
|
|
])
|
|
if [[ "x$HAVE_PTHREADS" = "xyes" ]]; then
|
|
AC_DEFINE(HAVE_PTHREADS, 1, [Define if pthreads are available.])
|
|
fi
|
|
AC_CHECK_FUNCS(pthread_cancel)
|
|
AC_CHECK_FUNCS(pthread_mutexattr_setprotocol)
|
|
AC_CHECK_FUNCS(pthread_mutexattr_settype)
|
|
AC_CHECK_FUNCS(pthread_mutexattr_setpshared)
|
|
|
|
dnl If POSIX.4 semaphores are not available, we emulate them with pthread mutexes.
|
|
SEMSRC=
|
|
AC_CHECK_FUNCS(sem_init, , [
|
|
if test "x$HAVE_PTHREADS" = "xyes"; then
|
|
SEMSRC=posix_sem.cpp
|
|
fi
|
|
])
|
|
|
|
dnl We use DGA (XFree86 or fbdev) if possible.
|
|
if [[ "x$WANT_XF86_DGA" = "xyes" ]]; then
|
|
AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension, [
|
|
AC_DEFINE(ENABLE_XF86_DGA, 1, [Define if using XFree86 DGA extension.])
|
|
LIBS="$LIBS -lXxf86dga"
|
|
if [[ "x$WANT_FBDEV_DGA" = "xyes" ]]; then
|
|
AC_MSG_WARN([Cannot have both --enable-xf86-dga and --enable-fbdev-dga, ignoring --enable-fbdev-dga.])
|
|
WANT_FBDEV_DGA=no
|
|
fi
|
|
], [
|
|
AC_MSG_WARN([Could not find XFree86 DGA extension, ignoring --enable-xf86-dga.])
|
|
WANT_XF86_DGA=no
|
|
])
|
|
fi
|
|
if [[ "x$WANT_FBDEV_DGA" = "xyes" ]]; then
|
|
AC_DEFINE(ENABLE_FBDEV_DGA, 1, [Define if using DGA with framebuffer device.])
|
|
fi
|
|
|
|
dnl We use XFree86 VidMode if possible.
|
|
if [[ "x$WANT_XF86_VIDMODE" = "xyes" ]]; then
|
|
AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension, [
|
|
AC_DEFINE(ENABLE_XF86_VIDMODE, 1, [Define if using XFree86 DGA extension.])
|
|
LIBS="$LIBS -lXxf86vm"
|
|
], [
|
|
AC_MSG_WARN([Could not find XFree86 VidMode extension, ignoring --enable-xf86-vidmode.])
|
|
WANT_XF86_VIDMODE=no
|
|
])
|
|
fi
|
|
|
|
dnl We use GTK+ if possible.
|
|
UISRCS=../dummy/prefs_editor_dummy.cpp
|
|
if [[ "x$WANT_GTK" = "xyes" ]]; then
|
|
AM_PATH_GTK(1.2.0, [
|
|
AC_DEFINE(ENABLE_GTK, 1, [Define if using GTK.])
|
|
CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
|
|
LIBS="$LIBS $GTK_LIBS"
|
|
UISRCS=prefs_editor_gtk.cpp
|
|
dnl somehow, <gnome-i18n.h> would redefine gettext() to nothing if
|
|
dnl ENABLE_NLS is not set, thusly conflicting with C++ <string> which
|
|
dnl includes <libintl.h>
|
|
AM_GNU_GETTEXT
|
|
B2_PATH_GNOMEUI([
|
|
AC_DEFINE(HAVE_GNOMEUI, 1, [Define if libgnomeui is available.])
|
|
CXXFLAGS="$CXXFLAGS $GNOMEUI_CFLAGS"
|
|
LIBS="$LIBS $GNOMEUI_LIBS"
|
|
], [])
|
|
], [
|
|
AC_MSG_WARN([Could not find GTK+, disabling user interface.])
|
|
WANT_GTK=no
|
|
])
|
|
fi
|
|
|
|
dnl We use ESD if possible.
|
|
if [[ "x$WANT_ESD" = "xyes" ]]; then
|
|
AM_PATH_ESD(0.2.8, [
|
|
AC_DEFINE(ENABLE_ESD, 1, [Define is using ESD.])
|
|
CFLAGS="$CFLAGS $ESD_CFLAGS"
|
|
CXXFLAGS="$CXXFLAGS $ESD_CFLAGS"
|
|
LIBS="$LIBS $ESD_LIBS"
|
|
], [
|
|
AC_MSG_WARN([Could not find ESD, disabling ESD support.])
|
|
WANT_ESD=no
|
|
])
|
|
fi
|
|
|
|
dnl We use 64-bit file size support if possible.
|
|
AC_SYS_LARGEFILE
|
|
|
|
dnl Checks for header files.
|
|
AC_HEADER_STDC
|
|
AC_CHECK_HEADERS(unistd.h fcntl.h sys/types.h sys/time.h sys/mman.h mach/mach.h)
|
|
AC_CHECK_HEADERS(readline.h history.h readline/readline.h readline/history.h)
|
|
AC_CHECK_HEADERS(linux/if.h linux/if_tun.h net/if.h net/if_tun.h)
|
|
|
|
dnl Checks for typedefs, structures, and compiler characteristics.
|
|
AC_C_BIGENDIAN
|
|
AC_C_CONST
|
|
AC_C_INLINE
|
|
AC_CHECK_SIZEOF(short, 2)
|
|
AC_CHECK_SIZEOF(int, 4)
|
|
AC_CHECK_SIZEOF(long, 4)
|
|
AC_CHECK_SIZEOF(long long, 8)
|
|
AC_CHECK_SIZEOF(float, 4)
|
|
AC_CHECK_SIZEOF(double, 8)
|
|
AC_CHECK_SIZEOF(long double, 12)
|
|
AC_CHECK_SIZEOF(void *, 4)
|
|
AC_TYPE_OFF_T
|
|
AC_CHECK_TYPES(loff_t)
|
|
AC_CHECK_TYPES(caddr_t)
|
|
AC_TYPE_SIZE_T
|
|
AC_TYPE_SIGNAL
|
|
AC_HEADER_TIME
|
|
AC_STRUCT_TM
|
|
|
|
dnl Check whether sys/socket.h defines type socklen_t.
|
|
dnl (extracted from ac-archive/Miscellaneous)
|
|
AC_CACHE_CHECK([for socklen_t],
|
|
ac_cv_type_socklen_t, [
|
|
AC_TRY_COMPILE([
|
|
#include <sys/types.h>
|
|
#include <sys/socket.h>
|
|
], [socklen_t len = 42; return 0;],
|
|
ac_cv_type_socklen_t=yes, ac_cv_type_socklen_t=no,
|
|
dnl When cross-compiling, do not assume anything.
|
|
ac_cv_type_socklen_t="guessing no"
|
|
)
|
|
])
|
|
if [[ "x$ac_cv_type_socklen_t" != "xyes" ]]; then
|
|
AC_DEFINE(socklen_t, int, [Define to 'int' if <sys/types.h> doesn't define.])
|
|
fi
|
|
|
|
dnl Checks for library functions.
|
|
AC_CHECK_FUNCS(strdup cfmakeraw)
|
|
AC_CHECK_FUNCS(clock_gettime timer_create)
|
|
AC_CHECK_FUNCS(sigaction signal)
|
|
AC_CHECK_FUNCS(mmap mprotect munmap)
|
|
AC_CHECK_FUNCS(vm_allocate vm_deallocate vm_protect)
|
|
|
|
dnl Darwin seems to define mach_task_self() instead of task_self().
|
|
AC_CHECK_FUNCS(mach_task_self task_self)
|
|
|
|
dnl Check for headers and functions related to pty support (sshpty.c)
|
|
dnl From openssh-3.2.2p1 configure.ac
|
|
|
|
AC_CHECK_HEADERS(strings.h login.h sys/bsdtty.h sys/stat.h util.h pty.h)
|
|
AC_CHECK_FUNCS(_getpty vhangup strlcpy)
|
|
|
|
case "$host" in
|
|
*-*-hpux10.26)
|
|
disable_ptmx_check=yes
|
|
;;
|
|
*-*-linux*)
|
|
no_dev_ptmx=1
|
|
;;
|
|
mips-sony-bsd|mips-sony-newsos4)
|
|
AC_DEFINE(HAVE_NEWS4, 1, [Define if you are on NEWS-OS (additions from openssh-3.2.2p1, for sshpty.c).])
|
|
;;
|
|
*-*-sco3.2v4*)
|
|
no_dev_ptmx=1
|
|
;;
|
|
*-*-sco3.2v5*)
|
|
no_dev_ptmx=1
|
|
;;
|
|
esac
|
|
|
|
if test -z "$no_dev_ptmx" ; then
|
|
if test "x$disable_ptmx_check" != "xyes" ; then
|
|
AC_CHECK_FILE([/dev/ptmx],
|
|
[
|
|
AC_DEFINE_UNQUOTED(HAVE_DEV_PTMX, 1, [Define if you have /dev/ptmx.])
|
|
have_dev_ptmx=1
|
|
]
|
|
)
|
|
fi
|
|
fi
|
|
AC_CHECK_FILE([/dev/ptc],
|
|
[
|
|
AC_DEFINE_UNQUOTED(HAVE_DEV_PTS_AND_PTC, 1, [Define if you have /dev/ptc.])
|
|
have_dev_ptc=1
|
|
]
|
|
)
|
|
|
|
dnl (end of code from openssh-3.2.2p1 configure.ac)
|
|
|
|
|
|
dnl Select system-dependant source files.
|
|
SERIALSRC=serial_unix.cpp
|
|
ETHERSRC=../dummy/ether_dummy.cpp
|
|
SCSISRC=../dummy/scsi_dummy.cpp
|
|
AUDIOSRC=../dummy/audio_dummy.cpp
|
|
EXTRASYSSRCS=
|
|
CAN_NATIVE_M68K=no
|
|
case "$target_os" in
|
|
linux*)
|
|
ETHERSRC=ether_unix.cpp
|
|
AUDIOSRC=audio_oss_esd.cpp
|
|
SCSISRC=Linux/scsi_linux.cpp
|
|
;;
|
|
freebsd*)
|
|
ETHERSRC=ether_unix.cpp
|
|
AUDIOSRC=audio_oss_esd.cpp
|
|
DEFINES="$DEFINES -DBSD_COMP"
|
|
CXXFLAGS="$CXXFLAGS -fpermissive"
|
|
dnl Check for the CAM library
|
|
AC_CHECK_LIB(cam, cam_open_btl, HAVE_LIBCAM=yes, HAVE_LIBCAM=no)
|
|
if [[ "x$HAVE_LIBCAM" = "xno" ]]; then
|
|
AC_MSG_WARN([Cannot find libcam for SCSI management, disabling SCSI support.])
|
|
else
|
|
dnl Check for the sys kernel includes
|
|
AC_CHECK_HEADER(camlib.h)
|
|
if [[ "x$ac_cv_header_camlib_h" = "xno" ]]; then
|
|
dnl In this case I should fix this thing including a "patch"
|
|
dnl to access directly to the functions in the kernel :) --Orlando
|
|
AC_MSG_WARN([Cannot find includes for CAM library, disabling SCSI support.])
|
|
else
|
|
SCSISRC=FreeBSD/scsi_freebsd.cpp
|
|
LIBS="$LIBS -lcam"
|
|
DEFINES="$DEFINES -DCAM"
|
|
fi
|
|
fi
|
|
;;
|
|
netbsd*)
|
|
CAN_NATIVE_M68K=yes
|
|
;;
|
|
solaris*)
|
|
AUDIOSRC=Solaris/audio_solaris.cpp
|
|
DEFINES="$DEFINES -DBSD_COMP -D_POSIX_PTHREAD_SEMANTICS"
|
|
;;
|
|
irix*)
|
|
ETHERSRC=ether_unix.cpp
|
|
AUDIOSRC=Irix/audio_irix.cpp
|
|
EXTRASYSSRCS=Irix/unaligned.c
|
|
dnl IRIX headers work fine, but somehow don't define or use "STDC_HEADERS"
|
|
DEFINES="$DEFINES -DCRTSCTS=CNEW_RTSCTS -DB230400=B115200 -DSTDC_HEADERS"
|
|
LIBS="$LIBS -laudio"
|
|
WANT_ESD=no
|
|
|
|
dnl Check if our compiler supports -IPA (MIPSPro)
|
|
HAVE_IPA=no
|
|
ocflags="$CFLAGS"
|
|
CFLAGS=`echo "$CFLAGS -IPA" | sed -e "s/-g//g"`
|
|
AC_MSG_CHECKING(if "-IPA" works)
|
|
dnl Do a test compile of an empty function
|
|
AC_TRY_COMPILE(,, [AC_MSG_RESULT(yes); HAVE_IPA=yes], AC_MSG_RESULT(no))
|
|
CFLAGS="$ocflags"
|
|
|
|
;;
|
|
esac
|
|
dnl SDL overrides
|
|
if [[ "x$WANT_SDL" = "xyes" ]]; then
|
|
AC_DEFINE(USE_SDL, 1, [Define to enble SDL support])
|
|
fi
|
|
if [[ "x$WANT_SDL_VIDEO" = "xyes" ]]; then
|
|
VIDEOSRCS="../SDL/video_sdl.cpp ../dummy/clip_dummy.cpp"
|
|
AC_DEFINE(USE_SDL_VIDEO, 1, [Define to enable SDL video graphics support])
|
|
else
|
|
VIDEOSRCS="video_x.cpp clip_unix.cpp"
|
|
fi
|
|
|
|
dnl Use 68k CPU natively?
|
|
WANT_NATIVE_M68K=no
|
|
if [[ "x$HAVE_M68K" = "xyes" -a "x$CAN_NATIVE_M68K" = "xyes" ]]; then
|
|
AC_DEFINE(ENABLE_NATIVE_M68K, 1, [Define if using native 68k mode.])
|
|
WANT_NATIVE_M68K=yes
|
|
fi
|
|
|
|
if [[ "x$HAVE_PTHREADS" = "xno" ]]; then
|
|
dnl Serial, ethernet and audio support needs pthreads
|
|
AC_MSG_WARN([You don't have pthreads, disabling serial, ethernet and audio support.])
|
|
SERIALSRC=../dummy/serial_dummy.cpp
|
|
ETHERSRC=../dummy/ether_dummy.cpp
|
|
AUDIOSRC=../dummy/audio_dummy.cpp
|
|
fi
|
|
SYSSRCS="$VIDEOSRCS $SERIALSRC $ETHERSRC $SCSISRC $AUDIOSRC $SEMSRC $UISRCS $MONSRCS $EXTRASYSSRCS"
|
|
|
|
dnl Define a macro that translates a yesno-variable into a C macro definition
|
|
dnl to be put into the config.h file
|
|
dnl $1 -- the macro to define
|
|
dnl $2 -- the value to translate
|
|
dnl $3 -- template name
|
|
AC_DEFUN(AC_TRANSLATE_DEFINE, [
|
|
if [[ "x$2" = "xyes" -o "x$2" = "xguessing yes" ]]; then
|
|
AC_DEFINE($1, 1, $3)
|
|
fi
|
|
])
|
|
|
|
dnl Check that the host supports TUN/TAP devices
|
|
AC_CACHE_CHECK([whether TUN/TAP is supported],
|
|
ac_cv_tun_tap_support, [
|
|
AC_TRY_COMPILE([
|
|
#if defined(HAVE_LINUX_IF_H) && defined(HAVE_LINUX_IF_TUN_H)
|
|
#include <linux/if.h>
|
|
#include <linux/if_tun.h>
|
|
#endif
|
|
#if defined(HAVE_NET_IF_H) && defined(HAVE_NET_IF_TUN_H)
|
|
#include <net/if.h>
|
|
#include <net/if_tun.h>
|
|
#endif
|
|
], [
|
|
struct ifreq ifr;
|
|
memset(&ifr, 0, sizeof(ifr));
|
|
ifr.ifr_flags = IFF_TAP | IFF_NO_PI;
|
|
],
|
|
ac_cv_tun_tap_support=yes, ac_cv_tun_tap_support=no
|
|
)
|
|
])
|
|
AC_TRANSLATE_DEFINE(ENABLE_TUNTAP, "$ac_cv_tun_tap_support",
|
|
[Define if your system supports TUN/TAP devices.])
|
|
|
|
dnl Various checks if the system supports vm_allocate() and the like functions.
|
|
have_mach_vm=no
|
|
if [[ "x$ac_cv_func_vm_allocate" = "xyes" -a "x$ac_cv_func_vm_deallocate" = "xyes" -a \
|
|
"x$ac_cv_func_vm_protect" = "xyes" ]]; then
|
|
have_mach_vm=yes
|
|
fi
|
|
AC_TRANSLATE_DEFINE(HAVE_MACH_VM, "$have_mach_vm",
|
|
[Define if your system has a working vm_allocate()-based memory allocator.])
|
|
|
|
dnl Check that vm_allocate(), vm_protect() work
|
|
if [[ "x$have_mach_vm" = "xyes" ]]; then
|
|
|
|
AC_CACHE_CHECK([whether vm_protect works],
|
|
ac_cv_vm_protect_works, [
|
|
AC_LANG_SAVE
|
|
AC_LANG_CPLUSPLUS
|
|
ac_cv_vm_protect_works=yes
|
|
dnl First the tests that should segfault
|
|
for test_def in NONE_READ NONE_WRITE READ_WRITE; do
|
|
AC_TRY_RUN([
|
|
#define CONFIGURE_TEST_VM_MAP
|
|
#define TEST_VM_PROT_$test_def
|
|
#include "vm_alloc.cpp"
|
|
], ac_cv_vm_protect_works=no, rm -f core,
|
|
dnl When cross-compiling, do not assume anything
|
|
ac_cv_vm_protect_works="guessing no"
|
|
)
|
|
done
|
|
AC_TRY_RUN([
|
|
#define CONFIGURE_TEST_VM_MAP
|
|
#define TEST_VM_PROT_RDWR_WRITE
|
|
#include "vm_alloc.cpp"
|
|
], , ac_cv_vm_protect_works=no,
|
|
dnl When cross-compiling, do not assume anything
|
|
ac_cv_vm_protect_works="guessing no"
|
|
)
|
|
AC_LANG_RESTORE
|
|
]
|
|
)
|
|
|
|
dnl Remove support for vm_allocate() if vm_protect() does not work
|
|
if [[ "x$have_mach_vm" = "xyes" ]]; then
|
|
case $ac_cv_vm_protect_works in
|
|
*yes) have_mach_vm=yes;;
|
|
*no) have_mach_vm=no;;
|
|
esac
|
|
fi
|
|
AC_TRANSLATE_DEFINE(HAVE_MACH_VM, "$have_mach_vm",
|
|
[Define if your system has a working vm_allocate()-based memory allocator.])
|
|
|
|
fi dnl HAVE_MACH_VM
|
|
|
|
dnl Various checks if the system supports mmap() and the like functions.
|
|
dnl ... and Mach memory allocators are not supported
|
|
have_mmap_vm=no
|
|
if [[ "x$ac_cv_func_mmap" = "xyes" -a "x$ac_cv_func_munmap" = "xyes" -a \
|
|
"x$ac_cv_func_mprotect" = "xyes" ]]; then
|
|
if [[ "x$have_mach_vm" = "xno" ]]; then
|
|
have_mmap_vm=yes
|
|
fi
|
|
fi
|
|
AC_TRANSLATE_DEFINE(HAVE_MMAP_VM, "$have_mmap_vm",
|
|
[Define if your system has a working mmap()-based memory allocator.])
|
|
|
|
dnl Check that mmap() and associated functions work.
|
|
if [[ "x$have_mmap_vm" = "xyes" ]]; then
|
|
|
|
dnl Check if we have a working anonymous mmap()
|
|
AC_CACHE_CHECK([whether mmap supports MAP_ANON],
|
|
ac_cv_mmap_anon, [
|
|
AC_LANG_SAVE
|
|
AC_LANG_CPLUSPLUS
|
|
AC_TRY_RUN([
|
|
#define HAVE_MMAP_ANON
|
|
#define CONFIGURE_TEST_VM_MAP
|
|
#define TEST_VM_MMAP_ANON
|
|
#include "vm_alloc.cpp"
|
|
], ac_cv_mmap_anon=yes, ac_cv_mmap_anon=no,
|
|
dnl When cross-compiling, do not assume anything.
|
|
ac_cv_mmap_anon="guessing no"
|
|
)
|
|
AC_LANG_RESTORE
|
|
]
|
|
)
|
|
AC_TRANSLATE_DEFINE(HAVE_MMAP_ANON, "$ac_cv_mmap_anon",
|
|
[Define if <sys/mman.h> defines MAP_ANON and mmap()'ing with MAP_ANON works.])
|
|
|
|
AC_CACHE_CHECK([whether mmap supports MAP_ANONYMOUS],
|
|
ac_cv_mmap_anonymous, [
|
|
AC_LANG_SAVE
|
|
AC_LANG_CPLUSPLUS
|
|
AC_TRY_RUN([
|
|
#define HAVE_MMAP_ANONYMOUS
|
|
#define CONFIGURE_TEST_VM_MAP
|
|
#define TEST_VM_MMAP_ANON
|
|
#include "vm_alloc.cpp"
|
|
], ac_cv_mmap_anonymous=yes, ac_cv_mmap_anonymous=no,
|
|
dnl When cross-compiling, do not assume anything.
|
|
ac_cv_mmap_anonymous="guessing no"
|
|
)
|
|
AC_LANG_RESTORE
|
|
]
|
|
)
|
|
AC_TRANSLATE_DEFINE(HAVE_MMAP_ANONYMOUS, "$ac_cv_mmap_anonymous",
|
|
[Define if <sys/mman.h> defines MAP_ANONYMOUS and mmap()'ing with MAP_ANONYMOUS works.])
|
|
|
|
AC_CACHE_CHECK([whether mprotect works],
|
|
ac_cv_mprotect_works, [
|
|
AC_LANG_SAVE
|
|
AC_LANG_CPLUSPLUS
|
|
ac_cv_mprotect_works=yes
|
|
dnl First the tests that should segfault
|
|
for test_def in NONE_READ NONE_WRITE READ_WRITE; do
|
|
AC_TRY_RUN([
|
|
#define CONFIGURE_TEST_VM_MAP
|
|
#define TEST_VM_PROT_$test_def
|
|
#include "vm_alloc.cpp"
|
|
], ac_cv_mprotect_works=no, rm -f core,
|
|
dnl When cross-compiling, do not assume anything
|
|
ac_cv_mprotect_works="guessing no"
|
|
)
|
|
done
|
|
AC_TRY_RUN([
|
|
#define CONFIGURE_TEST_VM_MAP
|
|
#define TEST_VM_PROT_RDWR_WRITE
|
|
#include "vm_alloc.cpp"
|
|
], , ac_cv_mprotect_works=no,
|
|
dnl When cross-compiling, do not assume anything
|
|
ac_cv_mprotect_works="guessing no"
|
|
)
|
|
AC_LANG_RESTORE
|
|
]
|
|
)
|
|
|
|
dnl Remove support for mmap() if mprotect() does not work
|
|
if [[ "x$have_mmap_vm" = "xyes" ]]; then
|
|
case $ac_cv_mprotect_works in
|
|
*yes) have_mmap_vm=yes;;
|
|
*no) have_mmap_vm=no;;
|
|
esac
|
|
fi
|
|
AC_TRANSLATE_DEFINE(HAVE_MMAP_VM, $have_mmap_vm,
|
|
[Define if your system has a working mmap()-based memory allocator.])
|
|
|
|
fi dnl HAVE_MMAP_VM
|
|
|
|
dnl Check if we can modify the __PAGEZERO segment for use as Low Memory
|
|
AC_CACHE_CHECK([whether __PAGEZERO can be Low Memory area 0x0000-0x2000],
|
|
ac_cv_pagezero_hack, [
|
|
ac_cv_pagezero_hack=no
|
|
if AC_TRY_COMMAND([Darwin/testlmem.sh 0x2000]); then
|
|
ac_cv_pagezero_hack=yes
|
|
dnl might as well skip the test for mmap-able low memory
|
|
ac_cv_can_map_lm=no
|
|
fi
|
|
])
|
|
AC_TRANSLATE_DEFINE(PAGEZERO_HACK, "$ac_cv_pagezero_hack",
|
|
[Define if the __PAGEZERO Mach-O Low Memory Globals hack works on this system.])
|
|
|
|
dnl Check if we can mmap 0x2000 bytes from 0x0000
|
|
AC_CACHE_CHECK([whether we can map Low Memory area 0x0000-0x2000],
|
|
ac_cv_can_map_lm, [
|
|
AC_LANG_SAVE
|
|
AC_LANG_CPLUSPLUS
|
|
AC_TRY_RUN([
|
|
#include "vm_alloc.cpp"
|
|
int main(void) { /* returns 0 if we could map the lowmem globals */
|
|
volatile char * lm = 0;
|
|
if (vm_init() < 0) exit(1);
|
|
if (vm_acquire_fixed(0, 0x2000) < 0) exit(1);
|
|
lm[0] = 'z';
|
|
if (vm_release((char *)lm, 0x2000) < 0) exit(1);
|
|
vm_exit(); exit(0);
|
|
}
|
|
], ac_cv_can_map_lm=yes, ac_cv_can_map_lm=no,
|
|
dnl When cross-compiling, do not assume anything.
|
|
ac_cv_can_map_lm="guessing no"
|
|
)
|
|
AC_LANG_RESTORE
|
|
]
|
|
)
|
|
|
|
dnl Check signal handlers need to be reinstalled
|
|
AC_CACHE_CHECK([whether signal handlers need to be reinstalled],
|
|
ac_cv_signal_need_reinstall, [
|
|
AC_LANG_SAVE
|
|
AC_LANG_CPLUSPLUS
|
|
AC_TRY_RUN([
|
|
#include <stdlib.h>
|
|
#ifdef HAVE_UNISTD_H
|
|
#include <unistd.h>
|
|
#endif
|
|
#include <signal.h>
|
|
static int handled_signal = 0;
|
|
RETSIGTYPE sigusr1_handler(int) { handled_signal++; }
|
|
int main(void) { /* returns 0 if signals need not to be reinstalled */
|
|
signal(SIGUSR1, sigusr1_handler); raise(SIGUSR1); raise(SIGUSR1);
|
|
exit(handled_signal == 2);
|
|
}
|
|
], ac_cv_signal_need_reinstall=yes, ac_cv_signal_need_reinstall=no,
|
|
dnl When cross-compiling, do not assume anything.
|
|
ac_cv_signal_need_reinstall="guessing yes"
|
|
)
|
|
AC_LANG_RESTORE
|
|
]
|
|
)
|
|
AC_TRANSLATE_DEFINE(SIGNAL_NEED_REINSTALL, "$ac_cv_signal_need_reinstall",
|
|
[Define if your system requires signals to be reinstalled.])
|
|
|
|
dnl Check if sigaction handlers need to be reinstalled
|
|
AC_CACHE_CHECK([whether sigaction handlers need to be reinstalled],
|
|
ac_cv_sigaction_need_reinstall, [
|
|
AC_LANG_SAVE
|
|
AC_LANG_CPLUSPLUS
|
|
AC_TRY_RUN([
|
|
#include <stdlib.h>
|
|
#ifdef HAVE_UNISTD_H
|
|
#include <unistd.h>
|
|
#endif
|
|
#include <signal.h>
|
|
static int handled_signal = 0;
|
|
RETSIGTYPE sigusr1_handler(int) { handled_signal++; }
|
|
typedef RETSIGTYPE (*signal_handler)(int);
|
|
static signal_handler mysignal(int sig, signal_handler handler) {
|
|
struct sigaction old_sa;
|
|
struct sigaction new_sa;
|
|
new_sa.sa_handler = handler;
|
|
return ((sigaction(sig,&new_sa,&old_sa) < 0) ? SIG_IGN : old_sa.sa_handler);
|
|
}
|
|
int main(void) { /* returns 0 if signals need not to be reinstalled */
|
|
mysignal(SIGUSR1, sigusr1_handler); raise(SIGUSR1); raise(SIGUSR1);
|
|
exit(handled_signal == 2);
|
|
}
|
|
], ac_cv_sigaction_need_reinstall=yes, ac_cv_sigaction_need_reinstall=no,
|
|
dnl When cross-compiling, do not assume anything.
|
|
ac_cv_sigaction_need_reinstall="guessing yes"
|
|
)
|
|
AC_LANG_RESTORE
|
|
]
|
|
)
|
|
AC_TRANSLATE_DEFINE(SIGACTION_NEED_REINSTALL, "$ac_cv_sigaction_need_reinstall",
|
|
[Define if your system requires sigactions to be reinstalled.])
|
|
|
|
dnl Check if Mach exceptions supported.
|
|
AC_CACHE_CHECK([whether your system supports Mach exceptions],
|
|
ac_cv_have_mach_exceptions, [
|
|
AC_LANG_SAVE
|
|
AC_LANG_CPLUSPLUS
|
|
AC_TRY_RUN([
|
|
#define HAVE_MACH_EXCEPTIONS 1
|
|
#define CONFIGURE_TEST_SIGSEGV_RECOVERY
|
|
#include "vm_alloc.cpp"
|
|
#include "sigsegv.cpp"
|
|
], [
|
|
sigsegv_recovery=mach
|
|
ac_cv_have_mach_exceptions=yes
|
|
],
|
|
ac_cv_have_mach_exceptions=no,
|
|
dnl When cross-compiling, do not assume anything.
|
|
ac_cv_have_mach_exceptions=no
|
|
)
|
|
AC_LANG_RESTORE
|
|
]
|
|
)
|
|
AC_TRANSLATE_DEFINE(HAVE_MACH_EXCEPTIONS, "$ac_cv_have_mach_exceptions",
|
|
[Define if your system supports Mach exceptions.])
|
|
|
|
dnl Otherwise, check if extended signals are supported.
|
|
if [[ -z "$sigsegv_recovery" ]]; then
|
|
AC_CACHE_CHECK([whether your system supports extended signal handlers],
|
|
ac_cv_have_extended_signals, [
|
|
AC_LANG_SAVE
|
|
AC_LANG_CPLUSPLUS
|
|
AC_TRY_RUN([
|
|
#define HAVE_SIGINFO_T 1
|
|
#define CONFIGURE_TEST_SIGSEGV_RECOVERY
|
|
#include "vm_alloc.cpp"
|
|
#include "sigsegv.cpp"
|
|
], [
|
|
sigsegv_recovery=siginfo
|
|
ac_cv_have_extended_signals=yes
|
|
],
|
|
ac_cv_have_extended_signals=no,
|
|
dnl When cross-compiling, do not assume anything.
|
|
ac_cv_have_extended_signals=no
|
|
)
|
|
AC_LANG_RESTORE
|
|
]
|
|
)
|
|
AC_TRANSLATE_DEFINE(HAVE_SIGINFO_T, "$ac_cv_have_extended_signals",
|
|
[Define if your system support extended signals.])
|
|
fi
|
|
|
|
dnl Otherwise, check for subterfuges.
|
|
if [[ -z "$sigsegv_recovery" ]]; then
|
|
AC_CACHE_CHECK([whether we then have a subterfuge for your system],
|
|
ac_cv_have_sigcontext_hack, [
|
|
AC_LANG_SAVE
|
|
AC_LANG_CPLUSPLUS
|
|
AC_TRY_RUN([
|
|
#define HAVE_SIGCONTEXT_SUBTERFUGE 1
|
|
#define CONFIGURE_TEST_SIGSEGV_RECOVERY
|
|
#include "vm_alloc.cpp"
|
|
#include "sigsegv.cpp"
|
|
], [
|
|
sigsegv_recovery=sigcontext
|
|
ac_cv_have_sigcontext_hack=yes
|
|
],
|
|
ac_cv_have_sigcontext_hack=no,
|
|
dnl When cross-compiling, do not assume anything.
|
|
ac_cv_have_sigcontext_hack=no
|
|
)
|
|
AC_LANG_RESTORE
|
|
])
|
|
AC_TRANSLATE_DEFINE(HAVE_SIGCONTEXT_SUBTERFUGE, "$ac_cv_have_sigcontext_hack",
|
|
[Define if we know a hack to replace siginfo_t->si_addr member.])
|
|
fi
|
|
|
|
dnl Check if we can ignore the fault (instruction skipping in SIGSEGV handler)
|
|
AC_CACHE_CHECK([whether we can skip instruction in SIGSEGV handler],
|
|
ac_cv_have_skip_instruction, [
|
|
AC_LANG_SAVE
|
|
AC_LANG_CPLUSPLUS
|
|
AC_TRY_RUN([
|
|
#define HAVE_SIGSEGV_SKIP_INSTRUCTION 1
|
|
#define CONFIGURE_TEST_SIGSEGV_RECOVERY
|
|
#include "vm_alloc.cpp"
|
|
#include "sigsegv.cpp"
|
|
], ac_cv_have_skip_instruction=yes, ac_cv_have_skip_instruction=no,
|
|
dnl When cross-compiling, do not assume anything.
|
|
ac_cv_have_skip_instruction=no
|
|
)
|
|
AC_LANG_RESTORE
|
|
]
|
|
)
|
|
AC_TRANSLATE_DEFINE(HAVE_SIGSEGV_SKIP_INSTRUCTION, "$ac_cv_have_skip_instruction",
|
|
[Define if we can ignore the fault (instruction skipping in SIGSEGV handler).])
|
|
|
|
dnl Can we do Video on SEGV Signals ?
|
|
CAN_VOSF=no
|
|
if [[ -n "$sigsegv_recovery" ]]; then
|
|
CAN_VOSF=yes
|
|
fi
|
|
|
|
dnl A dummy program that returns always true
|
|
AC_PATH_PROG([BLESS], "true")
|
|
|
|
dnl Determine the addressing mode to use
|
|
if [[ "x$WANT_NATIVE_M68K" = "xyes" ]]; then
|
|
ADDRESSING_MODE="real"
|
|
else
|
|
ADDRESSING_MODE=""
|
|
AC_MSG_CHECKING([for the addressing mode to use])
|
|
for am in $ADDRESSING_TEST_ORDER; do
|
|
case $am in
|
|
real)
|
|
dnl Requires ability to mmap() Low Memory globals
|
|
if [[ "x$ac_cv_can_map_lm$ac_cv_pagezero_hack" = "xnono" ]]; then
|
|
continue
|
|
fi
|
|
dnl Requires VOSF screen updates
|
|
if [[ "x$CAN_VOSF" = "xno" ]]; then
|
|
continue
|
|
fi
|
|
dnl Real addressing will probably work.
|
|
ADDRESSING_MODE="real"
|
|
WANT_VOSF=yes dnl we can use VOSF and we need it actually
|
|
DEFINES="$DEFINES -DREAL_ADDRESSING"
|
|
if [[ "x$ac_cv_pagezero_hack" = "xyes" ]]; then
|
|
BLESS=Darwin/lowmem
|
|
LDFLAGS="$LDFLAGS -pagezero_size 0x2000"
|
|
fi
|
|
break
|
|
;;
|
|
direct)
|
|
dnl Requires VOSF screen updates
|
|
if [[ "x$CAN_VOSF" = "xyes" ]]; then
|
|
ADDRESSING_MODE="direct"
|
|
WANT_VOSF=yes dnl we can use VOSF and we need it actually
|
|
DEFINES="$DEFINES -DDIRECT_ADDRESSING"
|
|
break
|
|
fi
|
|
;;
|
|
banks)
|
|
dnl Default addressing mode
|
|
ADDRESSING_MODE="memory banks"
|
|
break
|
|
;;
|
|
*)
|
|
AC_MSG_ERROR([Internal configure.in script error for $am addressing mode])
|
|
esac
|
|
done
|
|
AC_MSG_RESULT($ADDRESSING_MODE)
|
|
if [[ "x$ADDRESSING_MODE" = "x" ]]; then
|
|
AC_MSG_WARN([Sorry, no suitable addressing mode in $ADDRESSING_TEST_ORDER])
|
|
ADDRESSING_MODE="memory banks"
|
|
fi
|
|
fi
|
|
|
|
dnl Banked Memory Addressing mode is not supported by the JIT compiler
|
|
if [[ "x$WANT_JIT" = "xyes" -a "x$ADDRESSING_MODE" = "xmemory banks" ]]; then
|
|
AC_MSG_ERROR([Sorry, the JIT Compiler requires Direct Addressing, at least])
|
|
fi
|
|
|
|
dnl Enable VOSF screen updates with this feature is requested and feasible
|
|
if [[ "x$WANT_VOSF" = "xyes" -a "x$CAN_VOSF" = "xyes" ]]; then
|
|
AC_DEFINE(ENABLE_VOSF, 1, [Define if using video enabled on SEGV signals.])
|
|
else
|
|
WANT_VOSF=no
|
|
fi
|
|
|
|
dnl Check for GAS.
|
|
HAVE_GAS=no
|
|
AC_MSG_CHECKING(for GAS .p2align feature)
|
|
cat >conftest.S << EOF
|
|
.text
|
|
.p2align 5
|
|
EOF
|
|
if $CC conftest.S -c -o conftest.o >/dev/null 2>&1 ; then HAVE_GAS=yes; fi
|
|
AC_MSG_RESULT($HAVE_GAS)
|
|
|
|
dnl Check for GCC 2.7 or higher.
|
|
HAVE_GCC27=no
|
|
AC_MSG_CHECKING(for GCC 2.7 or higher)
|
|
AC_EGREP_CPP(xyes,
|
|
[#if __GNUC__ - 1 > 1 || __GNUC_MINOR__ - 1 > 5
|
|
xyes
|
|
#endif
|
|
], [AC_MSG_RESULT(yes); HAVE_GCC27=yes], AC_MSG_RESULT(no))
|
|
|
|
dnl Check for GCC 3.0 or higher.
|
|
HAVE_GCC30=no
|
|
AC_MSG_CHECKING(for GCC 3.0 or higher)
|
|
AC_EGREP_CPP(xyes,
|
|
[#if __GNUC__ >= 3
|
|
xyes
|
|
#endif
|
|
], [AC_MSG_RESULT(yes); HAVE_GCC30=yes], AC_MSG_RESULT(no))
|
|
|
|
dnl Set "-fomit-frame-pointer" on i386 GCC 2.7 or higher.
|
|
dnl Also set "-fno-exceptions" for C++ because exception handling requires
|
|
dnl the frame pointer.
|
|
if [[ "x$HAVE_GCC27" = "xyes" -a "x$HAVE_I386" = "xyes" ]]; then
|
|
CFLAGS="$CFLAGS -fomit-frame-pointer"
|
|
CXXFLAGS="$CXXFLAGS -fomit-frame-pointer -fno-exceptions"
|
|
fi
|
|
|
|
dnl (gb) Do not merge constants since it breaks fpu/fpu_x86.cpp.
|
|
dnl As of 2001/08/02, this affects the following compilers:
|
|
dnl Official: probably gcc-3.1 (mainline CVS)
|
|
dnl Mandrake: gcc-2.96 >= 0.59mdk, gcc-3.0.1 >= 0.1mdk
|
|
dnl Red Hat : gcc-2.96 >= 89, gcc-3.0 >= 1
|
|
if [[ "x$HAVE_GCC27" = "xyes" ]]; then
|
|
SAVED_CXXFLAGS="$CXXFLAGS"
|
|
CXXFLAGS="$CXXFLAGS -fno-merge-constants"
|
|
AC_CACHE_CHECK([whether GCC supports constants merging], ac_cv_gcc_constants_merging, [
|
|
AC_LANG_SAVE
|
|
AC_LANG_CPLUSPLUS
|
|
AC_TRY_COMPILE([],[],[ac_cv_gcc_constants_merging=yes],[ac_cv_gcc_constants_merging=no])
|
|
AC_LANG_RESTORE
|
|
])
|
|
if [[ "x$ac_cv_gcc_constants_merging" != "xyes" ]]; then
|
|
CXXFLAGS="$SAVED_CXXFLAGS"
|
|
fi
|
|
fi
|
|
|
|
dnl Select appropriate CPU source and REGPARAM define.
|
|
ASM_OPTIMIZATIONS=none
|
|
CPUSRCS="cpuemu1.cpp cpuemu2.cpp cpuemu3.cpp cpuemu4.cpp cpuemu5.cpp cpuemu6.cpp cpuemu7.cpp cpuemu8.cpp"
|
|
|
|
dnl (gb) JITSRCS will be emptied later if the JIT is not available
|
|
dnl Other platforms should define their own set of noflags file variants
|
|
CAN_JIT=no
|
|
JITSRCS="compemu1.cpp compemu2.cpp compemu3.cpp compemu4.cpp compemu5.cpp compemu6.cpp compemu7.cpp compemu8.cpp"
|
|
|
|
if [[ "x$HAVE_GCC27" = "xyes" -a "x$HAVE_I386" = "xyes" ]]; then
|
|
dnl i386 CPU
|
|
DEFINES="$DEFINES -DUNALIGNED_PROFITABLE -DREGPARAM=\"__attribute__((regparm(3)))\""
|
|
if [[ "x$HAVE_GAS" = "xyes" ]]; then
|
|
ASM_OPTIMIZATIONS=i386
|
|
DEFINES="$DEFINES -DX86_ASSEMBLY -DOPTIMIZED_FLAGS -DSAHF_SETO_PROFITABLE"
|
|
JITSRCS="cpuemu1_nf.cpp cpuemu2_nf.cpp cpuemu3_nf.cpp cpuemu4_nf.cpp cpuemu5_nf.cpp cpuemu6_nf.cpp cpuemu7_nf.cpp cpuemu8_nf.cpp $JITSRCS"
|
|
CAN_JIT=yes
|
|
fi
|
|
elif [[ "x$HAVE_GCC30" = "xyes" -a "x$HAVE_X86_64" = "xyes" ]]; then
|
|
dnl x86-64 CPU
|
|
DEFINES="$DEFINES -DUNALIGNED_PROFITABLE"
|
|
if [[ "x$HAVE_GAS" = "xyes" ]]; then
|
|
ASM_OPTIMIZATIONS="x86-64"
|
|
DEFINES="$DEFINES -DX86_64_ASSEMBLY -DOPTIMIZED_FLAGS"
|
|
fi
|
|
elif [[ "x$HAVE_GCC27" = "xyes" -a "x$HAVE_SPARC" = "xyes" -a "x$HAVE_GAS" = "xyes" ]]; then
|
|
dnl SPARC CPU
|
|
case "$target_os" in
|
|
solaris*)
|
|
AC_MSG_CHECKING(SPARC CPU architecture)
|
|
SPARC_TYPE=`Solaris/which_sparc`
|
|
AC_MSG_RESULT($SPARC_TYPE)
|
|
case "$SPARC_TYPE" in
|
|
SPARC_V8)
|
|
ASM_OPTIMIZATIONS="SPARC V8 architecture"
|
|
DEFINES="$DEFINES -DSPARC_V8_ASSEMBLY" dnl -DOPTIMIZED_FLAGS"
|
|
CFLAGS="$CFLAGS -Wa,-Av8"
|
|
CXXFLAGS="$CXXFLAGS -Wa,-Av8"
|
|
;;
|
|
SPARC_V9)
|
|
ASM_OPTIMIZATIONS="SPARC V9 architecture"
|
|
DEFINES="$DEFINES -DSPARC_V9_ASSEMBLY" dnl -DOPTIMIZED_FLAGS"
|
|
CFLAGS="$CFLAGS -Wa,-Av9"
|
|
CXXFLAGS="$CXXFLAGS -Wa,-Av9"
|
|
;;
|
|
esac
|
|
;;
|
|
esac
|
|
elif [[ "x$WANT_NATIVE_M68K" = "xyes" ]]; then
|
|
dnl Native m68k, no emulation
|
|
CPUINCLUDES="-I../native_cpu"
|
|
CPUSRCS="asm_support.s"
|
|
fi
|
|
|
|
dnl Enable JIT compiler, if possible.
|
|
if [[ "x$WANT_JIT" = "xyes" -a "x$CAN_JIT" ]]; then
|
|
JITSRCS="$JITSRCS ../uae_cpu/compiler/compemu_support.cpp ../uae_cpu/compiler/compemu_fpp.cpp compstbl.o cpustbl_nf.o"
|
|
DEFINES="$DEFINES -DUSE_JIT -DUSE_JIT_FPU"
|
|
|
|
if [[ "x$WANT_JIT_DEBUG" = "xyes" ]]; then
|
|
if [[ "x$WANT_MON" = "xyes" ]]; then
|
|
DEFINES="$DEFINES -DJIT_DEBUG=1"
|
|
else
|
|
AC_MSG_WARN([cxmon not found, ignoring --enable-jit-debug])
|
|
WANT_JIT_DEBUG=no
|
|
fi
|
|
fi
|
|
|
|
dnl IEEE core is the only FPU emulator to use with the JIT compiler
|
|
case $FPE_CORE_TEST_ORDER in
|
|
ieee*) ;;
|
|
*) AC_MSG_WARN([Forcing use of the IEEE FPU core, as the JIT compiler supports only this one.]) ;;
|
|
esac
|
|
FPE_CORE_TEST_ORDER="ieee"
|
|
else
|
|
WANT_JIT=no
|
|
WANT_JIT_DEBUG=no
|
|
JITSRCS=""
|
|
fi
|
|
|
|
dnl Utility macro used by next two tests.
|
|
dnl AC_EXAMINE_OBJECT(C source code,
|
|
dnl commands examining object file,
|
|
dnl [commands to run if compile failed]):
|
|
dnl
|
|
dnl Compile the source code to an object file; then convert it into a
|
|
dnl printable representation. All unprintable characters and
|
|
dnl asterisks (*) are replaced by dots (.). All white space is
|
|
dnl deleted. Newlines (ASCII 0x10) in the input are preserved in the
|
|
dnl output, but runs of newlines are compressed to a single newline.
|
|
dnl Finally, line breaks are forcibly inserted so that no line is
|
|
dnl longer than 80 columns and the file ends with a newline. The
|
|
dnl result of all this processing is in the file conftest.dmp, which
|
|
dnl may be examined by the commands in the second argument.
|
|
dnl
|
|
AC_DEFUN([gcc_AC_EXAMINE_OBJECT],
|
|
[AC_LANG_SAVE
|
|
AC_LANG_C
|
|
dnl Next bit cribbed from AC_TRY_COMPILE.
|
|
cat > conftest.$ac_ext <<EOF
|
|
[#line __oline__ "configure"
|
|
#include "confdefs.h"
|
|
$1
|
|
]EOF
|
|
if AC_TRY_EVAL(ac_compile); then
|
|
od -c conftest.o |
|
|
sed ['s/^[0-7]*[ ]*/ /
|
|
s/\*/./g
|
|
s/ \\n/*/g
|
|
s/ [0-9][0-9][0-9]/./g
|
|
s/ \\[^ ]/./g'] |
|
|
tr -d '
|
|
' | tr -s '*' '
|
|
' | fold | sed '$a\
|
|
' > conftest.dmp
|
|
$2
|
|
ifelse($3, , , else
|
|
$3
|
|
)dnl
|
|
fi
|
|
rm -rf conftest*
|
|
AC_LANG_RESTORE])
|
|
|
|
dnl Floating point format probe.
|
|
dnl The basic concept is the same as the above: grep the object
|
|
dnl file for an interesting string. We have to watch out for
|
|
dnl rounding changing the values in the object, however; this is
|
|
dnl handled by ignoring the least significant byte of the float.
|
|
dnl
|
|
dnl Does not know about VAX G-float or C4x idiosyncratic format.
|
|
dnl It does know about PDP-10 idiosyncratic format, but this is
|
|
dnl not presently supported by GCC. S/390 "binary floating point"
|
|
dnl is in fact IEEE (but maybe we should have that in EBCDIC as well
|
|
dnl as ASCII?)
|
|
dnl
|
|
AC_DEFUN([gcc_AC_C_FLOAT_FORMAT],
|
|
[AC_CACHE_CHECK(floating point format, ac_cv_c_float_format,
|
|
[gcc_AC_EXAMINE_OBJECT(
|
|
[/* This will not work unless sizeof(double) == 8. */
|
|
extern char sizeof_double_must_be_8 [sizeof(double) == 8 ? 1 : -1];
|
|
|
|
/* This structure must have no internal padding. */
|
|
struct possibility {
|
|
char prefix[8];
|
|
double candidate;
|
|
char postfix[8];
|
|
};
|
|
|
|
#define C(cand) { "\nformat:", cand, ":tamrof\n" }
|
|
struct possibility table [] =
|
|
{
|
|
C( 3.25724264705901305206e+01), /* @@IEEEFP - IEEE 754 */
|
|
C( 3.53802595280598432000e+18), /* D__float - VAX */
|
|
C( 5.32201830133125317057e-19), /* D.PDP-10 - PDP-10 - the dot is 0x13a */
|
|
C( 1.77977764695171661377e+10), /* IBMHEXFP - s/390 format, ascii */
|
|
C(-5.22995989424860458374e+10) /* IBMHEXFP - s/390 format, EBCDIC */
|
|
};],
|
|
[if grep 'format:.@IEEEF.:tamrof' conftest.dmp >/dev/null 2>&1; then
|
|
ac_cv_c_float_format='IEEE (big-endian)'
|
|
elif grep 'format:.I@@PFE.:tamrof' conftest.dmp >/dev/null 2>&1; then
|
|
ac_cv_c_float_format='IEEE (big-endian)'
|
|
elif grep 'format:.FEEEI@.:tamrof' conftest.dmp >/dev/null 2>&1; then
|
|
ac_cv_c_float_format='IEEE (little-endian)'
|
|
elif grep 'format:.EFP@@I.:tamrof' conftest.dmp >/dev/null 2>&1; then
|
|
ac_cv_c_float_format='IEEE (little-endian)'
|
|
elif grep 'format:.__floa.:tamrof' conftest.dmp >/dev/null 2>&1; then
|
|
ac_cv_c_float_format='VAX D-float'
|
|
elif grep 'format:..PDP-1.:tamrof' conftest.dmp >/dev/null 2>&1; then
|
|
ac_cv_c_float_format='PDP-10'
|
|
elif grep 'format:.BMHEXF.:tamrof' conftest.dmp >/dev/null 2>&1; then
|
|
ac_cv_c_float_format='IBM 370 hex'
|
|
else
|
|
AC_MSG_ERROR(Unknown floating point format)
|
|
fi],
|
|
[AC_MSG_ERROR(compile failed)])
|
|
])
|
|
# IEEE is the default format. If the float endianness isn't the same
|
|
# as the integer endianness, we have to set FLOAT_WORDS_BIG_ENDIAN
|
|
# (which is a tristate: yes, no, default). This is only an issue with
|
|
# IEEE; the other formats are only supported by a few machines each,
|
|
# all with the same endianness.
|
|
format=IEEE_FLOAT_FORMAT
|
|
fbigend=
|
|
case $ac_cv_c_float_format in
|
|
'IEEE (big-endian)' )
|
|
if test $ac_cv_c_bigendian = no; then
|
|
fbigend=1
|
|
fi
|
|
;;
|
|
'IEEE (little-endian)' )
|
|
if test $ac_cv_c_bigendian = yes; then
|
|
fbigend=0
|
|
fi
|
|
;;
|
|
'VAX D-float' )
|
|
format=VAX_FLOAT_FORMAT
|
|
;;
|
|
'PDP-10' )
|
|
format=PDP10_FLOAT_FORMAT
|
|
;;
|
|
'IBM 370 hex' )
|
|
format=IBM_FLOAT_FORMAT
|
|
;;
|
|
esac
|
|
AC_DEFINE_UNQUOTED(HOST_FLOAT_FORMAT, $format,
|
|
[Define to the floating point format of the host machine.])
|
|
if test -n "$fbigend"; then
|
|
AC_DEFINE_UNQUOTED(HOST_FLOAT_WORDS_BIG_ENDIAN, $fbigend,
|
|
[Define to 1 if the host machine stores floating point numbers in
|
|
memory with the word containing the sign bit at the lowest address,
|
|
or to 0 if it does it the other way around.
|
|
|
|
This macro should not be defined if the ordering is the same as for
|
|
multi-word integers.])
|
|
fi
|
|
])
|
|
|
|
dnl Select appropriate FPU source.
|
|
gcc_AC_C_FLOAT_FORMAT
|
|
AC_CHECK_HEADERS(ieee754.h ieeefp.h floatingpoint.h nan.h)
|
|
|
|
for fpe in $FPE_CORE_TEST_ORDER; do
|
|
case $fpe in
|
|
ieee)
|
|
case $ac_cv_c_float_format in
|
|
IEEE*)
|
|
FPE_CORE="IEEE fpu core"
|
|
DEFINES="$DEFINES -DFPU_IEEE"
|
|
FPUSRCS="../uae_cpu/fpu/fpu_ieee.cpp"
|
|
dnl Math functions not mandated by C99 standard
|
|
AC_CHECK_FUNCS(isnanl isinfl)
|
|
dnl Math functions required by C99 standard, but probably not
|
|
dnl implemented everywhere. In that case, we fall back to the
|
|
dnl regular variant for doubles.
|
|
AC_CHECK_FUNCS(logl log10l expl powl fabsl sqrtl)
|
|
AC_CHECK_FUNCS(sinl cosl tanl sinhl coshl tanhl)
|
|
AC_CHECK_FUNCS(asinl acosl atanl asinhl acoshl atanhl)
|
|
AC_CHECK_FUNCS(floorl ceill)
|
|
break
|
|
;;
|
|
esac
|
|
;;
|
|
x86)
|
|
if [[ ":$HAVE_GCC27:$HAVE_I386:$HAVE_GAS:" = ":yes:yes:yes:" ]]; then
|
|
FPE_CORE="i387 fpu core"
|
|
DEFINES="$DEFINES -DFPU_X86"
|
|
FPUSRCS="../uae_cpu/fpu/fpu_x86.cpp"
|
|
break
|
|
fi
|
|
;;
|
|
uae)
|
|
FPE_CORE="uae fpu core"
|
|
DEFINES="$DEFINES -DFPU_UAE"
|
|
FPUSRCS="../uae_cpu/fpu/fpu_uae.cpp"
|
|
break
|
|
;;
|
|
*)
|
|
AC_MSG_ERROR([Internal configure.in script error for $fpe fpu core])
|
|
;;
|
|
esac
|
|
done
|
|
if [[ "x$FPE_CORE" = "x" ]]; then
|
|
AC_MSG_ERROR([Sorry, no suitable FPU core found in $FPE_CORE_TEST_ORDER])
|
|
fi
|
|
|
|
dnl Check for certain math functions
|
|
AC_CHECK_FUNCS(atanh)
|
|
AC_CHECK_FUNCS(isnan isinf finite isnormal signbit)
|
|
|
|
dnl UAE CPU sources for all non-m68k-native architectures.
|
|
if [[ "x$WANT_NATIVE_M68K" = "xno" ]]; then
|
|
CPUINCLUDES="-I../uae_cpu"
|
|
CPUSRCS="../uae_cpu/basilisk_glue.cpp ../uae_cpu/memory.cpp ../uae_cpu/newcpu.cpp ../uae_cpu/readcpu.cpp $FPUSRCS cpustbl.cpp cpudefs.cpp $CPUSRCS $JITSRCS"
|
|
fi
|
|
|
|
dnl Remove the "-g" option if set for GCC.
|
|
if [[ "x$HAVE_GCC27" = "xyes" ]]; then
|
|
CFLAGS=`echo $CFLAGS | sed -e 's/-g//g'`
|
|
CXXFLAGS=`echo $CXXFLAGS | sed -e 's/-g//g'`
|
|
fi
|
|
|
|
dnl Or if we have -IPA (MIPSPro compilers)
|
|
if [[ "x$HAVE_IPA" = "xyes" ]]; then
|
|
CFLAGS="`echo $CFLAGS | sed -e 's/-g//g'` -O3 -OPT:Olimit=0 -IPA"
|
|
CXXFLAGS="`echo $CXXFLAGS | sed -e 's/-g//g'` -O3 -OPT:Olimit=0 -IPA"
|
|
CXXFLAGS="-LANG:std $CXXFLAGS"
|
|
LDFLAGS="$LDFLAGS -O3 -OPT:Olimit=0 -IPA"
|
|
fi
|
|
|
|
dnl Generate Makefile.
|
|
AC_SUBST(DEFINES)
|
|
AC_SUBST(SYSSRCS)
|
|
AC_SUBST(CPUINCLUDES)
|
|
AC_SUBST(CPUSRCS)
|
|
AC_SUBST(BLESS)
|
|
AC_CONFIG_FILES([Makefile])
|
|
AC_OUTPUT
|
|
|
|
dnl Print summary.
|
|
echo
|
|
echo Basilisk II configuration summary:
|
|
echo
|
|
echo SDL support ............................ : $SDL_SUPPORT
|
|
echo XFree86 DGA support .................... : $WANT_XF86_DGA
|
|
echo XFree86 VidMode support ................ : $WANT_XF86_VIDMODE
|
|
echo fbdev DGA support ...................... : $WANT_FBDEV_DGA
|
|
echo Enable video on SEGV signals ........... : $WANT_VOSF
|
|
echo ESD sound support ...................... : $WANT_ESD
|
|
echo GTK user interface ..................... : $WANT_GTK
|
|
echo mon debugger support ................... : $WANT_MON
|
|
echo Running m68k code natively ............. : $WANT_NATIVE_M68K
|
|
echo Use JIT compiler ....................... : $WANT_JIT
|
|
echo JIT debug mode ......................... : $WANT_JIT_DEBUG
|
|
echo Floating-Point emulation core .......... : $FPE_CORE
|
|
echo Assembly optimizations ................. : $ASM_OPTIMIZATIONS
|
|
echo Addressing mode ........................ : $ADDRESSING_MODE
|
|
echo Bad memory access recovery type ........ : $sigsegv_recovery
|
|
echo
|
|
echo "Configuration done. Now type \"make\" (or \"gmake\")."
|