mirror of
https://github.com/cc65/cc65.git
synced 2024-08-17 19:29:12 +00:00
74 lines
1.6 KiB
ArmAsm
74 lines
1.6 KiB
ArmAsm
|
;
|
||
|
; Christian Groessler, Dec-2001
|
||
|
;
|
||
|
; ucase_fn
|
||
|
; helper routine to convert a string (file name) to uppercase
|
||
|
; used by open.s and remove.s
|
||
|
;
|
||
|
; Calling parameters:
|
||
|
; AX - points to filename
|
||
|
; Return parameters:
|
||
|
; C - 0/1 for OK/Error (filename too long)
|
||
|
; AX - points to uppercased version of the filename on the stack
|
||
|
; tmp3 - amount of bytes used on the stack (needed for cleanup)
|
||
|
; Uses:
|
||
|
; ptr4 - scratch pointer used to remember original AX pointer
|
||
|
;
|
||
|
;
|
||
|
|
||
|
.include "atari.inc"
|
||
|
|
||
|
.importzp tmp3,ptr4,sp
|
||
|
.import _strupr,subysp
|
||
|
.export ucase_fn
|
||
|
|
||
|
ucase_fn: .proc
|
||
|
|
||
|
; we make sure that the filename doesn't contain lowercase letters
|
||
|
; we copy the filename we got onto the stack, uppercase it and use this
|
||
|
; one to open the iocb
|
||
|
; we're using tmp3, ptr4
|
||
|
|
||
|
; save the original pointer
|
||
|
sta ptr4
|
||
|
stx ptr4+1
|
||
|
|
||
|
; now we need the length of the name
|
||
|
ldy #0
|
||
|
loop: lda (ptr4),y
|
||
|
beq str_end
|
||
|
cmp #ATEOL ; we also accept Atari EOF char as end of string
|
||
|
beq str_end
|
||
|
iny
|
||
|
bne loop ; not longer than 255 chars (127 real limit)
|
||
|
toolong:sec ; indicate error
|
||
|
rts
|
||
|
|
||
|
str_end:iny ; room for terminating zero
|
||
|
cpy #128 ; we only can handle lenght < 128
|
||
|
bcs toolong
|
||
|
sty tmp3 ; save size
|
||
|
jsr subysp ; make room on the stack
|
||
|
|
||
|
; copy filename to the temp. place on the stack
|
||
|
lda #0 ; end-of-string
|
||
|
sta (sp),y ; Y still contains length + 1
|
||
|
dey
|
||
|
loop2: lda (ptr4),y
|
||
|
sta (sp),y
|
||
|
dey
|
||
|
bpl loop2 ; bpl: this way we only support a max. length of 127
|
||
|
|
||
|
; uppercase the temp. filename
|
||
|
ldx sp+1
|
||
|
lda sp
|
||
|
jsr _strupr
|
||
|
|
||
|
; leave X and Y pointing to the modified filename
|
||
|
lda sp
|
||
|
ldx sp+1
|
||
|
clc ; indicate success
|
||
|
rts
|
||
|
|
||
|
ucase_fn: .endproc
|