Added C65/C64DX accelerator code and documentation.

libsrc/c64/acc_c65_speed.s

@@ -0,0 +1,70 @@
+;
+; Marco van den Heuvel, 2018-04-27
+;
+
+; unsigned char __fastcall__ set_c65_speed (unsigned char speed);
+;
+;/* Set the speed of the C65 CPU, using SPEED_SLOW will switch to
+; * 1 Mhz mode, SPEED_3X or SPEED_FAST will switch to 3.5 Mhz (fast) mode.
+; *
+; * Note that any value higher or equal to SPEED_3X will switch to fast mode.
+; *
+; * This function will return the actual speed the CPU is at after trying
+; * to set the requested speed, to my knowledge the switching should not fail.
+; *
+; * This function does not check for the presence of a C65/C64DX in C64 mode,
+; * make sure you use 'detect_c65();' before using.
+; */
+
+; unsigned char get_c65_speed (void);
+;
+;/* Get the speed of the C65 CPU.
+; *
+; * Possible return values:
+; * SPEED_SLOW  : 1 Mhz mode
+; * SPEED_3X    : 3.5 Mhz mode
+; *
+; * This function does not check for the presence of a C65/C64DX in C64 mode,
+; * make sure you use 'detect_c65();' before using.
+; */
+
+        .export         _set_c65_speed
+        .export         _get_c65_speed
+
+        .include        "accelerator.inc"
+
+_set_c65_speed:
+        tay
+        jsr     activate_new_vic_mode
+        cpy     #SPEED_3X
+        bcs     high_speed
+low_speed:
+        and     #$BF
+store_speed:
+        sta     C65_VICIII_CTRL_B
+        lda     C65_VICIII_CTRL_B
+        jmp     return_c65_speed
+
+high_speed:
+        ora     #$40
+        bne     store_speed
+
+_get_c65_speed:
+        jsr     activate_new_vic_mode
+return_c65_speed:
+        sta     C65_VICIII_KEY
+        and     #$40
+        beq     speed_is_slow
+        lda     #SPEED_3X
+        .byte   $2C
+speed_is_slow:
+        ldx     #$00
+        rts
+
+activate_new_vic_mode:
+        lda     #C65_VICIII_UNLOCK_1
+        sta     C65_VICIII_KEY
+        lda     #C65_VICIII_UNLOCK_2
+        sta     C65_VICIII_KEY
+        lda     C65_VICIII_CTRL_B
+        rts

libsrc/c64/acc_detect_c65.s

@@ -0,0 +1,55 @@
+;
+; Marco van den Heuvel, 2018-04-27
+;
+
+; unsigned char detect_c65 (void);
+;
+;/* Check for the presence of a C65/C64DX in C64 mode.
+; *
+; * Possible return values:
+; * 0x00  : C65/C64DX in C64 mode not present
+; * 0x01  : C65/C64DX in C64 mode present
+; */
+
+        .export         _detect_c65
+
+        .include        "accelerator.inc"
+
+_detect_c65:
+        ldy     $D000
+
+; Make sure the CPU is not a 65816
+        clc
+        .byte   $E2,$01                ; NOP #$01 on 6510 and 65(S)C02, LDA $(01,S),Y on 65CE02 and 4510, SEP #$01 on 65816
+        lda     #$00
+        tax
+        bcs     not_found              ; carry will be set on 65816
+
+; Make sure the CPU is not a 6510
+        .byte   $1A                    ; NOP on 6510, INA on 65(S)C(E)02
+        beq     not_found
+        txa
+
+; Make sure the CPU is a 65CE02/4510
+        .byte   $A3,$A3                ; NOP NOP on 65(S)C02, LDZ #$A3 on 65CE02 and 4510
+        .byte   $6B                    ; NOP on 65(S)C02, TZA on 65CE02 and 4510
+        cmp     #$A3
+        bne     not_found
+
+; Switch to VICIII mode and check if $D040 is a mirror of $D000
+        ldy     #C65_VICIII_UNLOCK_1
+        sty     C65_VICIII_KEY
+        ldy     #C65_VICIII_UNLOCK_2
+        sty     C65_VICIII_KEY
+        cpy     $D040
+        bne     found
+        inc     $D000
+        cpy     $D040
+        beq     not_found
+
+found:
+        lda     #$01
+not_found:
+        sty     $D000
+        sta     C65_VICIII_KEY
+        rts