Merge pull request #2392 from colinleroy/asm-fputc-fputs

Asm fputc fputs

libsrc/common/checkferror.s

@@ -0,0 +1,24 @@
+;
+; Colin Leroy-Mira, 2024
+;
+; Helper to check for file opened, not eof, not ferror
+; Expects file pointer in ptr1,
+; Returns with Z flag set if everything is OK,
+; Destroys A, X, Y,
+; Sets file flags in A
+;
+
+        .export         checkferror
+        .importzp       ptr1
+
+        .include        "_file.inc"
+
+checkferror:
+        ldy     #_FILE::f_flags
+        lda     (ptr1),y
+        tax
+        and     #(_FOPEN|_FERROR|_FEOF); Check for file open, error/eof
+        tay
+        txa
+        cpy     #_FOPEN
+        rts

libsrc/common/fgetc.s

@@ -5,7 +5,8 @@
 ;
 
         .export         _fgetc
-        .import         _read, pusha0, pushax, popptr1, incsp2, returnFFFF
+        .import         _read, checkferror
+        .import         pusha0, pushax, popptr1, incsp2, returnFFFF
         .importzp       ptr1
 
         .include        "stdio.inc"
@@ -16,16 +17,10 @@ _fgetc:
         stx     ptr1+1
         jsr     pushax          ; Backup our ptr
 
-        ldy     #_FILE::f_flags
-        lda     (ptr1),y
-        tax
-        and     #_FOPEN         ; Check for file open
-        beq     ret_eof
-        txa
-        and     #(_FERROR|_FEOF); Check for error/eof
+        jsr     checkferror
         bne     ret_eof
 
-        txa
+        tax
         and     #_FPUSHBACK     ; Check for pushed back char
         beq     do_read
 

libsrc/common/fgets.s

@@ -90,9 +90,7 @@ read_loop:
 
 :       cmp     #$0A            ; Stop at \n
         beq     done
-
-        clc
-        bcc     read_loop
+        bne     read_loop
 
 got_eof:
         lda     didread

libsrc/common/fputc.c

@@ -1,41 +0,0 @@
-/*
-** fputc.c
-**
-** Ullrich von Bassewitz, 02.06.1998
-*/
-
-
-
-#include <stdio.h>
-#include <unistd.h>
-#include "_file.h"
-
-
-
-/*****************************************************************************/
-/*                                   Code                                    */
-/*****************************************************************************/
-
-
-
-int __fastcall__ fputc (int c, register FILE* f)
-{
-    /* Check if the file is open or if there is an error condition */
-    if ((f->f_flags & _FOPEN) == 0 || (f->f_flags & (_FERROR | _FEOF)) != 0) {
-        goto ReturnEOF;
-    }
-
-    /* Write the byte */
-    if (write (f->f_fd, &c, 1) != 1) {
-        /* Error */
-        f->f_flags |= _FERROR;
-ReturnEOF:
-        return EOF;
-    }
-
-    /* Return the byte written */
-    return c & 0xFF;
-}
-
-
-

libsrc/common/fputc.s

@@ -0,0 +1,66 @@
+;
+; Colin Leroy-Mira, 2024
+;
+; int __fastcall__ fputc (int c, FILE* f);
+;
+
+        .export         _fputc
+        .importzp       ptr1
+        .import         _write, checkferror
+        .import         pushax, pusha0, popax, incsp2
+        .import         pushptr1, popptr1, returnFFFF
+
+        .include        "stdio.inc"
+        .include        "_file.inc"
+
+_fputc:
+        sta     ptr1
+        stx     ptr1+1
+
+        jsr     popax           ; Get char, as we'll have
+        sta     c               ; to return it anyway
+        stx     c+1
+
+        jsr     checkferror
+        bne     ret_eof
+
+        jsr     pushptr1        ; Backup fp pointer
+
+        ; Push _write parameters
+        ldy     #_FILE::f_fd
+        lda     (ptr1),y
+        jsr     pusha0
+
+        lda     #<c
+        ldx     #>c
+        jsr     pushax
+
+        lda     #$01
+        ldx     #$00
+
+        ; Write
+        jsr     _write
+
+        ; Check for errors
+        cmp     #$01
+        bne     set_ferror
+
+        ; Return char
+        lda     c
+        ldx     #$00
+        jmp     incsp2          ; Drop fp pointer copy
+
+ret_eof:
+        jmp     returnFFFF
+
+set_ferror:
+        jsr     popptr1
+        lda     #_FERROR
+        ldy     #_FILE::f_flags
+        ora     (ptr1),y
+        sta     (ptr1),y
+        jmp     returnFFFF
+
+        .bss
+
+c:      .res 2

libsrc/common/fputs.c

@@ -1,28 +0,0 @@
-/*
-** int fputs (const char* s, FILE* f);
-**
-** Ullrich von Bassewitz, 11.08.1998
-*/
-
-
-
-#include <stdio.h>
-#include <string.h>
-#include <unistd.h>
-#include "_file.h"
-
-
-
-int __fastcall__ fputs (const char* s, register FILE* f)
-{
-    /* Check if the file is open or if there is an error condition */
-    if ((f->f_flags & _FOPEN) == 0 || (f->f_flags & (_FERROR | _FEOF)) != 0) {
-        return EOF;
-    }
-
-    /* Write the string */
-    return write (f->f_fd, s, strlen (s));
-}
-
-
-

libsrc/common/fputs.s

@@ -0,0 +1,36 @@
+;
+; Colin Leroy-Mira, 2024
+;
+; int __fastcall__ fputs (const char* s, register FILE* f)
+;
+
+        .export         _fputs
+        .importzp       ptr1, ptr2
+        .import         _write, _strlen, checkferror
+        .import         swapstk, pushax, returnFFFF
+
+        .include        "stdio.inc"
+        .include        "_file.inc"
+
+_fputs:
+        sta     ptr1
+        stx     ptr1+1
+
+        jsr     checkferror
+        bne     ret_eof
+
+        ; Push _write parameters
+        ldy     #_FILE::f_fd
+        lda     (ptr1),y
+        ldx     #$00
+        jsr     swapstk         ; Push fd, get s
+
+        jsr     pushax          ; Push s
+
+        jsr     _strlen         ; Get length
+
+        ; Write
+        jmp     _write
+
+ret_eof:
+        jmp     returnFFFF

test/ref/test_fputc.c

@@ -0,0 +1,39 @@
+/*
+  !!DESCRIPTION!! fgets test
+  !!LICENCE!!     Public domain
+*/
+
+#include "common.h"
+
+#include <ctype.h>
+#include <errno.h>
+#include <stdio.h>
+#include <stdlib.h>
+#include <string.h>
+#include <unistd.h>
+
+FILE *in, *out;
+int c, err;
+
+#define INFILE   "cf.in"
+
+int main(int argc,char **argv)
+{
+    in = fopen(INFILE, "rb");
+    if (in == NULL) {
+        return EXIT_FAILURE;
+    }
+
+    if (fputc(c, in) != EOF) {
+      printf("Error: can fputc to a file opened for reading\n");
+      return EXIT_FAILURE;
+    }
+    clearerr(in);
+
+    while ((c = fgetc(in)) != EOF) {
+      fputc(c, stdout);
+    }
+
+    fclose(in);
+    return 0;
+}

test/ref/test_fputs.c

@@ -0,0 +1,40 @@
+/*
+  !!DESCRIPTION!! fgets test
+  !!LICENCE!!     Public domain
+*/
+
+#include "common.h"
+
+#include <ctype.h>
+#include <errno.h>
+#include <stdio.h>
+#include <stdlib.h>
+#include <string.h>
+#include <unistd.h>
+
+FILE *in, *out;
+char buf[512], err;
+
+#define INFILE   "cf.in"
+
+int main(int argc,char **argv)
+{
+    in = fopen(INFILE, "rb");
+    if (in == NULL) {
+        return EXIT_FAILURE;
+    }
+
+    strcpy(buf, "test");
+    if (fputs(buf, in) != EOF) {
+      printf("Error: can fputs to a file opened for reading\n");
+      return EXIT_FAILURE;
+    }
+    clearerr(in);
+
+    while (fgets(buf, 512, in) != NULL) {
+      fputs(buf, stdout);
+    }
+
+    fclose(in);
+    return 0;
+}