Added C64 Turbo Master accelerator code and documentation.

2026-04-26 13:18:31 +00:00 · 2018-04-30 14:30:35 -07:00
parent 5c07db3a74
commit ad7b339c44
7 changed files with 234 additions and 1 deletions
@@ -0,0 +1,47 @@
+;
+; Marco van den Heuvel, 2018-04-30
+;
+
+; unsigned char detect_turbomaster (void);
+;
+;/* Check for the presence of a Turbo Master cartridge.
+; *
+; * Possible return values:
+; * 0x00  : TurboMaster cartridge not present
+; * 0x01  : TurboMaster cartridge present
+; */
+
+        .export         _detect_turbomaster
+
+        .include        "accelerator.inc"
+
+_detect_turbomaster:
+        lda     #$00
+        tax
+
+; Make sure the current CPU is not a 6510
+        .byte   $1A                   ; NOP on 8502, INA on 65(S)C(E)02, 4510 and 65816
+        beq     not_found
+
+; Make sure the current CPU is not a 65816
+        clc
+        .byte   $E2,$01                ; NOP #$01 on 65(S)C02, LDA $(01,S),Y on 65CE02 and 4510, SEP #$01 on 65816
+        bcs     not_found              ; carry will be set on 65816
+
+; Make sure the current CPU is not a 65CE02/4510
+        .byte   $A3,$A3                ; NOP NOP on 65(S)C02 and LDZ #$00 on 65CE02 and 4510
+        .byte   $6B                    ; NOP on 65(S)C02 and TZA on 65CE02 and 4510
+        cmp     #$A3
+        beq     not_found
+
+; Check for turbo master basic replacement
+        ldy     TURBOMASTER_DETECT
+        cpy     #$A2
+        bne     not_found
+found:
+        lda     #$01
+        .byte   $24
+not_found:
+        txa
+        rts
+
@@ -0,0 +1,63 @@
+;
+; Marco van den Heuvel, 2018-04-30
+;
+
+; unsigned char __fastcall__ set_turbomaster_speed (unsigned char speed);
+;
+;/* Set the speed of the Turbo Master cartridge, using SPEED_SLOW will switch to
+; * 1 Mhz mode, SPEED_4X or SPEED_FAST will switch to 4 Mhz mode.
+; *
+; * Note that any value higher or equal to SPEED_4X will switch to 4 Mhz mode,
+; * any value lower than SPEED_4X will switch to 1 Mhz mode.
+; *
+; * This function will return the actual speed the CPU is at after trying
+; * to set the requested speed, if the speed is different it might indicate
+; * that the hardware switch has locked the speed.
+; *
+; * This function does not check for the presence of a Turbo Master cartridge,
+; * make sure you use 'detect_turbomaster();' before using.
+; */
+
+; unsigned char get_turbomaster_speed (void);
+;
+;/* Get the speed of the Turbo Master cartridge.
+; *
+; * Possible return values:
+; * SPEED_SLOW  : 1 Mhz mode
+; * SPEED_4X    : 4 Mhz mode
+; *
+; * This function does not check for the presence of a Turbo Master cartridge,
+; * make sure you use 'detect_turbomaster();' before using.
+; */
+
+        .export         _set_turbomaster_speed
+        .export         _get_turbomaster_speed
+
+        .include        "accelerator.inc"
+
+_set_turbomaster_speed:
+        tay
+        lda     TURBOMASTER_SPEED_REG
+        cpy     #SPEED_4X
+        bcs     high_speed
+low_speed:
+        and     #$7F
+store_speed:
+        sta     TURBOMASTER_SPEED_REG
+        jmp     _get_turbomaster_speed
+
+high_speed:
+        ora     #$80
+        bne     store_speed
+
+
+_get_turbomaster_speed:
+        ldx     #$00
+        lda     TURBOMASTER_SPEED_REG
+        and     #$80
+        beq     is_slow_speed
+is_high_speed:
+        lda     #SPEED_4X
+is_slow_speed:
+        rts
+