mirror of
https://github.com/cc65/cc65.git
synced 2024-12-27 00:29:31 +00:00
419eb700b5
The way we want to use the INITBSS segment - and especially the fact that it won't have the type bss on all ROM based targets - means that the name INITBSS is misleading. After all INIT is the best name from my perspective as it serves several purposes and therefore needs a rather generic name. Unfortunately this means that the current INIT segment needs to be renamed too. Looking for a short (ideally 4 letter) name I came up with ONCE as it contains all code (and data) accessed only once during initialization.
98 lines
2.4 KiB
ArmAsm
98 lines
2.4 KiB
ArmAsm
;
|
|
; Stefan Haubenthal, 27.7.2009
|
|
;
|
|
; time_t _systime (void);
|
|
; /* Similar to time(), but:
|
|
; ** - Is not ISO C
|
|
; ** - Does not take the additional pointer
|
|
; ** - Does not set errno when returning -1
|
|
; */
|
|
;
|
|
|
|
.include "time.inc"
|
|
.include "c64.inc"
|
|
.include "get_tv.inc"
|
|
|
|
.constructor initsystime
|
|
.importzp tmp1, tmp2
|
|
.import _get_tv, _get_ostype
|
|
|
|
|
|
;----------------------------------------------------------------------------
|
|
.code
|
|
|
|
.proc __systime
|
|
|
|
lda CIA1_TODHR
|
|
bpl AM
|
|
and #%01111111
|
|
sed
|
|
clc
|
|
adc #$12
|
|
cld
|
|
AM: jsr BCD2dec
|
|
sta TM + tm::tm_hour
|
|
lda CIA1_TODMIN
|
|
jsr BCD2dec
|
|
sta TM + tm::tm_min
|
|
lda CIA1_TODSEC
|
|
jsr BCD2dec
|
|
sta TM + tm::tm_sec
|
|
lda CIA1_TOD10 ; Dummy read to unfreeze
|
|
lda #<TM
|
|
ldx #>TM
|
|
jmp _mktime
|
|
|
|
; dec = (((BCD>>4)*10) + (BCD&0xf))
|
|
BCD2dec:tax
|
|
and #%00001111
|
|
sta tmp1
|
|
txa
|
|
and #%11110000 ; *16
|
|
lsr ; *8
|
|
sta tmp2
|
|
lsr
|
|
lsr ; *2
|
|
adc tmp2 ; = *10
|
|
adc tmp1
|
|
rts
|
|
|
|
.endproc
|
|
|
|
;----------------------------------------------------------------------------
|
|
; Constructor that writes to the 1/10 sec register of the TOD to kick it
|
|
; into action. If this is not done, the clock hangs. We will read the register
|
|
; and write it again, ignoring a possible change in between.
|
|
.segment "ONCE"
|
|
|
|
.proc initsystime
|
|
|
|
lda CIA1_TOD10
|
|
sta CIA1_TOD10
|
|
jsr _get_tv
|
|
cmp #TV::PAL
|
|
bne @60Hz
|
|
jsr _get_ostype
|
|
cmp #$43
|
|
beq @60Hz
|
|
lda CIA1_CRA
|
|
ora #$80
|
|
sta CIA1_CRA
|
|
@60Hz: rts
|
|
|
|
.endproc
|
|
|
|
;----------------------------------------------------------------------------
|
|
; TM struct with date set to 1970-01-01
|
|
.data
|
|
|
|
TM: .word 0 ; tm_sec
|
|
.word 0 ; tm_min
|
|
.word 0 ; tm_hour
|
|
.word 1 ; tm_mday
|
|
.word 0 ; tm_mon
|
|
.word 70 ; tm_year
|
|
.word 0 ; tm_wday
|
|
.word 0 ; tm_yday
|
|
.word 0 ; tm_isdst
|