mirror of
https://github.com/cc65/cc65.git
synced 2024-06-25 13:29:41 +00:00
0ee9b2e446
So far the INIT segment was run from the later heap+stack. Now the INIT segment is run from the later BSS. The background is that so far the INIT segment was pretty small (from $80 to $180 bytes). But upcoming changes will increase the INIT segment in certain scenarios up to ~ $1000 bytes. So programs with very limited heap+stack might just not been able to move the INIT segment to its run location. But moving the INIT segment to the later BSS allows it to occupy the later BSS+heap+stack. In order to allow that the constructors are _NOT_ allowed anymore to access the BSS. Rather they must use the DATA segment or the new INITBSS segment. The latter isn't cleared at any point so the constructors may use it to expose values to the main program. However they must make sure to always write the values as they are not pre-initialized.
102 lines
2.1 KiB
ArmAsm
102 lines
2.1 KiB
ArmAsm
;
|
|
; Startup code for cc65 (C16 version)
|
|
;
|
|
; Note: The C16 is actually the Plus/4 with just 16KB of memory. So, many
|
|
; things are similar here; and, we even use the plus4.inc include file.
|
|
;
|
|
|
|
.export _exit
|
|
.export __STARTUP__ : absolute = 1 ; Mark as startup
|
|
.import initlib, donelib
|
|
.import callmain, zerobss
|
|
.import MEMTOP, RESTOR, BSOUT, CLRCH
|
|
.importzp ST
|
|
|
|
.include "zeropage.inc"
|
|
.include "plus4.inc"
|
|
|
|
; ------------------------------------------------------------------------
|
|
; Startup code
|
|
|
|
.segment "STARTUP"
|
|
|
|
Start:
|
|
|
|
; Save the zero-page locations that we need.
|
|
|
|
ldx #zpspace-1
|
|
L1: lda sp,x
|
|
sta zpsave,x
|
|
dex
|
|
bpl L1
|
|
|
|
; Switch to the second charset.
|
|
|
|
lda #14
|
|
jsr BSOUT
|
|
|
|
; Clear the BSS data.
|
|
|
|
jsr zerobss
|
|
|
|
; Save some system stuff; and, set up the stack.
|
|
|
|
tsx
|
|
stx spsave ; save system stk ptr
|
|
|
|
sec
|
|
jsr MEMTOP ; Get top memory
|
|
cpy #$80 ; We can only use the low 32K :-(
|
|
bcc MemOk
|
|
ldy #$80
|
|
ldx #$00
|
|
MemOk: stx sp
|
|
sty sp+1 ; set argument stack ptr
|
|
|
|
; Call the module constructors.
|
|
|
|
jsr initlib
|
|
|
|
; Push the command-line arguments; and, call main().
|
|
|
|
jsr callmain
|
|
|
|
; Call the module destructors. This is also the exit() entry.
|
|
|
|
_exit: pha ; Save the return code on stack
|
|
jsr donelib ; Run module destructors
|
|
|
|
; Copy back the zero-page stuff.
|
|
|
|
ldx #zpspace-1
|
|
L2: lda zpsave,x
|
|
sta sp,x
|
|
dex
|
|
bpl L2
|
|
|
|
; Store the return code into BASIC's status variable.
|
|
|
|
pla
|
|
sta ST
|
|
|
|
; Restore the stack pointer.
|
|
|
|
ldx spsave
|
|
txs
|
|
|
|
; Back to BASIC.
|
|
|
|
rts
|
|
|
|
; ------------------------------------------------------------------------
|
|
|
|
.segment "INITBSS"
|
|
|
|
zpsave: .res zpspace
|
|
|
|
; ------------------------------------------------------------------------
|
|
|
|
.bss
|
|
|
|
spsave: .res 1
|