mirror of
https://github.com/cc65/cc65.git
synced 2024-07-16 17:29:43 +00:00
7f52a770d9
So far the joy_masks array allowed several joystick drivers for a single target to each have different joy_read return values. However this meant that every call to joy_read implied an additional joy_masks lookup to post-process the return value. Given that almost all targets only come with a single joystick driver this seems an inappropriate overhead. Therefore now the target header files contain constants matching the return value of the joy_read of the joystick driver(s) on that target. If there indeed are several joystick drivers for a single target they must agree on a common return value for joy_read. In some cases this was alredy the case as there's a "natural" return value for joy_read. However a few joystick drivers need to be adjusted. This may cause some overhead inside the driver. But that is for sure smaller than the overhead introduced by the joy_masks lookup before. !!! ToDo !!! The following three joystick drivers become broken with this commit and need to be adjusted: - atrmj8.s - c64-numpad.s - vic20-stdjoy.s
118 lines
2.7 KiB
ArmAsm
118 lines
2.7 KiB
ArmAsm
;
|
|
; P.A.S.E. joystick driver for the Atmos
|
|
; Can be used multiple times when statically linked to the application.
|
|
;
|
|
; 2002-12-20, Based on Ullrich von Bassewitz's code.
|
|
; 2009-12-21, Stefan Haubenthal
|
|
; 2013-07-15, Greg King
|
|
;
|
|
|
|
.include "joy-kernel.inc"
|
|
.include "joy-error.inc"
|
|
.include "atmos.inc"
|
|
|
|
.macpack module
|
|
|
|
|
|
; ------------------------------------------------------------------------
|
|
; Header. Includes jump table
|
|
|
|
module_header _atmos_pase_joy
|
|
|
|
; Driver signature
|
|
|
|
.byte $6A, $6F, $79 ; "joy"
|
|
.byte JOY_API_VERSION ; Driver API version number
|
|
|
|
; Library reference
|
|
|
|
.addr $0000
|
|
|
|
; Jump table.
|
|
|
|
.addr INSTALL
|
|
.addr UNINSTALL
|
|
.addr COUNT
|
|
.addr READ
|
|
.addr 0 ; IRQ entry unused
|
|
|
|
; ------------------------------------------------------------------------
|
|
; Constants
|
|
|
|
JOY_COUNT = 2 ; Number of joysticks we support
|
|
|
|
; ------------------------------------------------------------------------
|
|
; Data.
|
|
|
|
.bss
|
|
temp1: .byte $00
|
|
temp2: .byte $00
|
|
|
|
.code
|
|
|
|
; ------------------------------------------------------------------------
|
|
; INSTALL routine. Is called after the driver is loaded into memory. If
|
|
; possible, check if the hardware is present and determine the amount of
|
|
; memory available.
|
|
; Must return an JOY_ERR_xx code in a/x.
|
|
;
|
|
|
|
INSTALL:
|
|
lda #JOY_ERR_OK
|
|
ldx #0
|
|
; rts ; Run into UNINSTALL instead
|
|
|
|
; ------------------------------------------------------------------------
|
|
; UNINSTALL routine. Is called before the driver is removed from memory.
|
|
; Can do cleanup or whatever. Must not return anything.
|
|
;
|
|
|
|
UNINSTALL:
|
|
rts
|
|
|
|
|
|
; ------------------------------------------------------------------------
|
|
; COUNT: Return the total number of available joysticks in a/x.
|
|
;
|
|
|
|
COUNT:
|
|
lda #JOY_COUNT
|
|
ldx #0
|
|
rts
|
|
|
|
; ------------------------------------------------------------------------
|
|
; READ: Read a particular joystick passed in A.
|
|
;
|
|
|
|
READ:
|
|
tay
|
|
|
|
lda VIA::PRA
|
|
pha
|
|
lda VIA::DDRA
|
|
pha
|
|
lda #%11000000
|
|
sta VIA::DDRA
|
|
lda #%10000000
|
|
sta VIA::PRA2
|
|
lda VIA::PRA2
|
|
sta temp1
|
|
lda #%01000000
|
|
sta VIA::PRA2
|
|
lda VIA::PRA
|
|
sta temp2
|
|
pla
|
|
sta VIA::DDRA
|
|
pla
|
|
sta VIA::PRA2
|
|
|
|
ldx #0
|
|
tya
|
|
bne @L1
|
|
lda temp1
|
|
eor #$FF
|
|
rts
|
|
@L1: lda temp2
|
|
eor #$FF
|
|
rts
|