mirror of
https://github.com/cc65/cc65.git
synced 2024-10-04 03:56:13 +00:00
842c151edd
We want to add the capability to not only get the time but also set the time, but there's no "setter" for the "getter" time(). The first ones that come into mind are gettimeofday() and settimeofday(). However, they take a struct timezone argument that doesn't make sense - even the man pages says "The use of the timezone structure is obsolete; the tz argument should normally be specified as NULL." And POSIX says "Applications should use the clock_gettime() function instead of the obsolescent gettimeofday() function." The ...timeofday() functions work with microseconds while the clock_...time() functions work with nanoseconds. Given that we expect our targets to support only 1/10 of seconds the microseconds look preferable at first sight. However, already microseconds require the cc65 data type 'long' so it's not such a relevant difference to nanoseconds. Additionally clock_getres() seems useful. In order to avoid code duplication clock_gettime() takes over the role of the actual time getter from _systime(). So time() now calls clock_gettime() instead of _systime(). For some reason beyond my understanding _systime() was mentioned in time.h. _systime() worked exactly like e.g. _sysremove() and those _sys...() functions are all considered internal. The only reason I could see would be a performance gain of bypassing the time() wrapper. However, all known _systime() implementations internally called mktime(). And mktime() is implemented in C using an iterative algorithm so I really can't see what would be left to gain here. From that perspective I decided to just remove _systime().
93 lines
2.1 KiB
ArmAsm
93 lines
2.1 KiB
ArmAsm
;
|
|
; Oliver Schmidt, 14.08.2018
|
|
;
|
|
; int clock_gettime (clockid_t clk_id, struct timespec *tp);
|
|
;
|
|
|
|
.import pushax, steaxspidx, incsp1, incsp3, return0
|
|
|
|
.include "time.inc"
|
|
.include "zeropage.inc"
|
|
.include "errno.inc"
|
|
.include "mli.inc"
|
|
|
|
_clock_gettime:
|
|
jsr pushax
|
|
|
|
; Clear tv_nsec (+ tv_sec)
|
|
sta ptr1
|
|
stx ptr1+1
|
|
lda #$00
|
|
ldy #.sizeof(timespec)-1
|
|
: sta (ptr1),y
|
|
dey
|
|
bpl :-
|
|
|
|
; Update date + time
|
|
lda #GET_TIME_CALL
|
|
ldx #GET_TIME_COUNT
|
|
jsr callmli
|
|
bcs oserr
|
|
|
|
; Get date
|
|
lda DATELO+1
|
|
lsr
|
|
php ; Save month msb
|
|
cmp #70 ; Year < 70?
|
|
bcs :+ ; No, leave alone
|
|
adc #100 ; Move 19xx to 20xx
|
|
: sta TM + tm::tm_year
|
|
lda DATELO
|
|
tax ; Save day
|
|
plp ; Restore month msb
|
|
ror
|
|
lsr
|
|
lsr
|
|
lsr
|
|
lsr
|
|
beq erange ; [1..12] allows for validity check
|
|
tay
|
|
dey ; Move [1..12] to [0..11]
|
|
sty TM + tm::tm_mon
|
|
txa ; Restore day
|
|
and #%00011111
|
|
sta TM + tm::tm_mday
|
|
|
|
; Get time
|
|
lda TIMELO+1
|
|
sta TM + tm::tm_hour
|
|
lda TIMELO
|
|
sta TM + tm::tm_min
|
|
|
|
; Make time_t
|
|
lda #<TM
|
|
ldx #>TM
|
|
jsr _mktime
|
|
|
|
; Store tv_sec
|
|
ldy #timespec::tv_sec
|
|
jsr steaxspidx
|
|
|
|
; Return success
|
|
jsr incsp1
|
|
jmp return0
|
|
|
|
; Load errno code
|
|
erange: lda #ERANGE
|
|
|
|
; Cleanup stack
|
|
jsr incsp3 ; Preserves A
|
|
|
|
; Set __errno
|
|
jmp __directerrno
|
|
|
|
; Cleanup stack
|
|
oserr: jsr incsp3 ; Preserves A
|
|
|
|
; Set __oserror
|
|
jmp __mappederrno
|
|
|
|
.bss
|
|
|
|
TM: .tag tm
|