mirror of
https://github.com/cc65/cc65.git
synced 2024-06-15 02:29:32 +00:00
da65866e24
- use this function instead of directly looking at _dos_type in the included targetutil and test programs - fixes/improvements to the Atari runtime library regarding the recently changed _dos_type values - libsrc/atari/targetutil/w2cas.c: exit if no filename was entered - add documentation for the new function
90 lines
2.1 KiB
ArmAsm
90 lines
2.1 KiB
ArmAsm
;
|
|
; Freddy Offenga & Christian Groessler, December 2004
|
|
;
|
|
; function to get default device: char *_getdefdev(void);
|
|
;
|
|
; SpartaDOS:
|
|
; the ZCRNAME routine is only used to get the default drive because
|
|
; ZCRNAME has two disadvantages:
|
|
; 1. It will convert D: into D1: instead of Dn: (n = default drive)
|
|
; 2. It will give a 'no arguments' status if it detects something
|
|
; like Dn: (without filename).
|
|
;
|
|
; OS/A+ DOS:
|
|
; ZCRNAME is slightly different from SpartaDOS. It will convert D:
|
|
; into Dn: where n is the default drive.
|
|
|
|
.include "atari.inc"
|
|
.import __dos_type
|
|
.export __getdefdev ; get default device
|
|
.export __defdev ; this is the default device string (e.g. "D1:")
|
|
.ifdef DYNAMIC_DD
|
|
.constructor __getdefdev, 24
|
|
.endif
|
|
|
|
; Get default device (LBUF will be destroyed!!)
|
|
|
|
__getdefdev:
|
|
|
|
lda __dos_type ; which DOS?
|
|
cmp #OSADOS+1
|
|
bcs finish ; only supported on OS/A+ and SpartaDOS
|
|
; (TODO: add XDOS support)
|
|
|
|
ldy #BUFOFF
|
|
lda #0
|
|
sta (DOSVEC),y ; reset buffer offset
|
|
|
|
; Store dummy argument
|
|
|
|
ldy #LBUF
|
|
lda #'X'
|
|
sta (DOSVEC),y
|
|
iny
|
|
lda #ATEOL
|
|
sta (DOSVEC),y
|
|
|
|
; One extra store to avoid the buggy sequence from OS/A+ DOS:
|
|
; <D><RETURN><:> => drive number = <RETURN>
|
|
|
|
iny
|
|
sta (DOSVEC),y
|
|
|
|
; Create crunch vector
|
|
|
|
ldy #ZCRNAME+1
|
|
lda (DOSVEC),y
|
|
sta crvec+1
|
|
iny
|
|
lda (DOSVEC),y
|
|
sta crvec+2
|
|
|
|
crvec: jsr $FFFF ; will be set to crunch vector
|
|
|
|
; Get default device
|
|
|
|
ldy #COMFNAM ; COMFNAM is always "Dn:"
|
|
lda (DOSVEC),y
|
|
sta __defdev
|
|
iny
|
|
lda (DOSVEC),y
|
|
sta __defdev+1
|
|
|
|
; Return pointer to default device
|
|
|
|
finish: lda #<__defdev
|
|
ldx #>__defdev
|
|
rts
|
|
|
|
.data
|
|
|
|
; Default device
|
|
|
|
__defdev:
|
|
.ifdef DEFAULT_DEVICE
|
|
.byte 'D', '0'+DEFAULT_DEVICE, ':', 0
|
|
.else
|
|
.byte "D1:", 0
|
|
.endif
|
|
|