4cade/src/prelaunch/last.gladiator.a

;license:MIT
;(c) 2020 by qkumba

!cpu 6502
!to "build/PRELAUNCH/LG",plain
*=$106

    !source "src/prelaunch/common.a"

         +ENABLE_ACCEL
         lda   #$60
         sta   $11EA
         jsr   $1000      ; decompress

         lda   #$4C
         sta   $BC00
         lda   #$40
         sta   $BC01
         lda   #$02
         sta   $BC02
         lda   #<callback2
         sta   $BC0B
         lda   #>callback2
         sta   $BC0C
         ldx   #(reset_e-callback1)-1
-        lda   callback1,x
         sta   $240,x
         dex
         bpl   -

         +DISABLE_ACCEL
         jmp   $11EF

callback1 !pseudopc $240 {
         lda   #<reset
         sta   $3F2
         lda   #>reset
         sta   $3F3
         jmp   $FB6F
reset
         +READ_RAM1_NO_WRITE
         jmp   ($FFFC)

callback2
         jsr   $BC16
         lda   $BD4C
         cmp   #8
         bne   +
         lda   $2D
         bne   +
         lda   #$15
         sta   $5FF2
         lda   #2
         sta   $5FF3
         lda   #$FE
         sta   $5FF4
+        rts
}
reset_e

!if * > $1C0 {
  !error "code is too large, ends at ", *
}