mirror of
https://github.com/a2-4am/4cade.git
synced 2024-06-25 21:29:43 +00:00
170 lines
4.5 KiB
Plaintext
170 lines
4.5 KiB
Plaintext
;license:MIT
|
|
;(c) 2018-9 by 4am
|
|
;
|
|
; Browse Mode - main UI
|
|
;
|
|
; Public functions
|
|
; - BrowseMode
|
|
;
|
|
|
|
!zone {
|
|
|
|
;------------------------------------------------------------------------------
|
|
; BrowseMode
|
|
; main entry point for Browse Mode, which allows the user to browse the game
|
|
; catalog in alphabetical order and launch games
|
|
;
|
|
; in: none
|
|
; out: never returns to caller (may JMP to other major modes)
|
|
;------------------------------------------------------------------------------
|
|
BrowseMode
|
|
ldx #$FF
|
|
txs
|
|
|
|
.BrowseModeInputLoop
|
|
jsr WaitForKeyFor30Seconds
|
|
bit CLEARKBD
|
|
|
|
ldy #kNumBrowseKeys
|
|
- dey
|
|
bmi @noKeyMatch
|
|
cmp .BrowseKeys,y
|
|
bne -
|
|
ldx .BrowseKeyDispatch,y
|
|
bne @BrowseDispatch ; always branches
|
|
|
|
@noKeyMatch
|
|
jsr IsSearchKey
|
|
beq +
|
|
jsr SoftBell ; beep on invalid input
|
|
jmp .BrowseModeInputLoop ; and start over
|
|
+
|
|
ldx #kBrowseSearch
|
|
; execution falls through here
|
|
@BrowseDispatch
|
|
ldy .BrowseDispatchTableLo,x
|
|
sty @j+1
|
|
ldy .BrowseDispatchTableHi,x
|
|
sty @j+2
|
|
@j jsr $FDFD ; SMC
|
|
jmp .BrowseModeInputLoop
|
|
|
|
.OnSearch
|
|
sta InputBuffer
|
|
lda #$01
|
|
sta InputLength
|
|
jmp SearchMode
|
|
|
|
.OnPrevious
|
|
dec gGameToLaunch
|
|
jmp +
|
|
.OnNext
|
|
inc gGameToLaunch
|
|
+
|
|
ldx gGameToLaunch
|
|
cpx #$FF
|
|
bne @notTooSmall
|
|
GameCount = *+1
|
|
ldx #$D1 ; SMC
|
|
dex
|
|
bne @done ; always branches
|
|
@notTooSmall
|
|
cpx GameCount
|
|
bcc @done
|
|
ldx #0
|
|
@done stx gGameToLaunch
|
|
jmp .OnBrowseChanged
|
|
|
|
.OnLaunch
|
|
jsr PlayGame
|
|
jsr BlankHGR
|
|
jmp .ForceBrowseChanged
|
|
|
|
.OnCheat
|
|
jsr ToggleCheat
|
|
beq .ForceBrowseChanged ; always branches because Z=1 on exit from ToggleCheat
|
|
|
|
.OnTab
|
|
ldx gGameToLaunch
|
|
jsr MiniAttractMode
|
|
cmp #$8D
|
|
beq .OnLaunch
|
|
.ForceBrowseChanged
|
|
bit CLEARKBD
|
|
ldx gGameToLaunch
|
|
; execution falls through here
|
|
.OnBrowseChanged
|
|
+LDADDR gGamesListStore
|
|
jsr okvs_nth ; get the filename of the new game
|
|
+STAY @key
|
|
|
|
jsr GetOffscreenAddress ; load new title screenshot offscreen
|
|
sta + ; new title screenshot (offscreen)
|
|
jsr LoadFile
|
|
!word kHGRTitleDirectory
|
|
@key !word $FDFD ; SMC
|
|
!byte $00
|
|
+ !byte $FD ; SMC
|
|
|
|
clc
|
|
jsr DrawUIOffscreen
|
|
jmp ShowOtherPage
|
|
|
|
;------------------------------------------------------------------------------
|
|
|
|
; indices into BrowseDispatchTable
|
|
kBrowseSearch = 0
|
|
kBrowsePrevious = 1
|
|
kBrowseNext = 2
|
|
kBrowseExitToSearch = 3
|
|
kBrowseTab = 4
|
|
kBrowseLaunch = 5
|
|
kBrowseCredits = 6
|
|
kBrowseCheat = 7
|
|
|
|
.BrowseDispatchTableLo
|
|
!byte <.OnSearch
|
|
!byte <.OnPrevious
|
|
!byte <.OnNext
|
|
!byte <SearchMode
|
|
!byte <.OnTab
|
|
!byte <.OnLaunch
|
|
!byte <Credits
|
|
!byte <.OnCheat
|
|
.BrowseDispatchTableHi
|
|
!byte >.OnSearch
|
|
!byte >.OnPrevious
|
|
!byte >.OnNext
|
|
!byte >SearchMode
|
|
!byte >.OnTab
|
|
!byte >.OnLaunch
|
|
!byte >Credits
|
|
!byte >.OnCheat
|
|
|
|
kNumBrowseKeys = 11 ; number of entries in next 2 tables (each)
|
|
.BrowseKeys
|
|
!byte $83 ; Ctrl-C = toggle cheat mode
|
|
!byte $AF ; '/' = credits
|
|
!byte $BF ; '?' = credits
|
|
!byte $A0 ; Space = mini attract mode
|
|
!byte $89 ; TAB = mini attract mode
|
|
!byte $8D ; ENTER = launch current game
|
|
!byte $9B ; Esc = switch to search mode
|
|
!byte $8A ; down arrow = next
|
|
!byte $95 ; right arrow = next
|
|
!byte $8B ; up arrow = previous
|
|
!byte $88 ; left arrow = previous
|
|
.BrowseKeyDispatch
|
|
!byte kBrowseCheat
|
|
!byte kBrowseCredits
|
|
!byte kBrowseCredits
|
|
!byte kBrowseTab
|
|
!byte kBrowseTab
|
|
!byte kBrowseLaunch
|
|
!byte kBrowseExitToSearch
|
|
!byte kBrowseNext
|
|
!byte kBrowseNext
|
|
!byte kBrowsePrevious
|
|
!byte kBrowsePrevious
|
|
}
|