dos33fsprogs/mist/mist.s

; Mist

; a version of Myst?
; (yes there's a subtle German joke here)

; by deater (Vince Weaver) <vince@deater.net>

; Zero Page
	.include "zp.inc"
	.include "hardware.inc"
	.include "common_defines.inc"

mist_start:
	;===================
	; init screen
	jsr	TEXT
	jsr	HOME
	bit	KEYRESET

	bit	SET_GR
	bit	PAGE0
	bit	LORES
	bit	FULLGR

	lda	#0
	sta	DRAW_PAGE
	sta	LEVEL_OVER

	; init cursor

	lda	#20
	sta	CURSOR_X
	sta	CURSOR_Y

	lda	LOCATION
	cmp	#1		; FIXME
	bne	not_first_time

	; first time init
	lda	#0

	sta	CLOCK_MINUTE
	sta	CLOCK_HOUR
	jsr	clock_inside_reset

	lda	#0
	sta	DIRECTION

	sta	GEAR_OPEN

	sta	BREAKER_TRIPPED
	sta	GENERATOR_VOLTS
	sta	ROCKET_VOLTS
	sta	GENERATOR_VOLTS_DISP
	sta	ROCKET_VOLTS_DISP
	sta	SWITCH_TOP_ROW
	sta	SWITCH_BOTTOM_ROW
	sta	ROCKET_HANDLE_STEP

	sta	ROCKET_NOTE1
	sta	ROCKET_NOTE2
	sta	ROCKET_NOTE3
	sta	ROCKET_NOTE4


; debug
;	lda	#1
;	sta	GEAR_OPEN
;	jsr	open_the_gear

not_first_time:


	; set up initial location

	jsr	change_location

	lda	#1
	sta	CURSOR_VISIBLE		; visible at first



game_loop:
	;=================
	; reset things
	;=================

	lda	#0
	sta	IN_SPECIAL
	sta	IN_RIGHT
	sta	IN_LEFT

	;====================================
	; copy background to current page
	;====================================

	jsr	gr_copy_to_current

	;====================================
	; handle special-case forground logic
	;====================================

	; handle gear opening

	lda	GEAR_OPEN
	beq	not_gear_related

	jsr	check_gear_delete
not_gear_related:

	; handle clock puzzles

	lda	LOCATION
	cmp	#25     ; clock puzzle
	beq	location_clock
	cmp	#27
	beq	location_inside_clock
	bne	location_generator

location_clock:
	jsr	draw_clock_face
	jmp	nothing_special
location_inside_clock:
	jsr	draw_clock_inside
	jmp	nothing_special

	; handle generator puzzle
location_generator:
	cmp	#36
	bne	nothing_special
	lda	DIRECTION
	and	#$f
	cmp	#DIRECTION_N
	bne	nothing_special

	jsr	generator_update_volts
	jsr	generator_draw_buttons
	jmp	nothing_special

nothing_special:

	;====================================
	; draw pointer
	;====================================

	jsr	draw_pointer

	;====================================
	; page flip
	;====================================

	jsr	page_flip

	;====================================
	; handle keypress/joystick
	;====================================

	jsr	handle_keypress


	;====================================
	; inc frame count
	;====================================

	inc	FRAMEL
	bne	room_frame_no_oflo
	inc	FRAMEH
room_frame_no_oflo:

	;====================================
	; check level over
	;====================================

	lda	LEVEL_OVER
	bne	really_exit
	jmp	game_loop

really_exit:
	jmp	end_level

;=================
; special exits

go_to_meche:
	lda	#LOAD_MECHE
	sta	WHICH_LOAD

	lda	#$ff
	sta	LEVEL_OVER

        rts


pad_special:
	lda	#40
	sta	LOCATION
	jsr	change_location

	rts

leave_tower2:
	lda	#42
	sta	LOCATION

	lda	#DIRECTION_W
	sta	DIRECTION

	jsr	change_location

	rts

leave_tower1:
	lda	#46
	sta	LOCATION

	lda	#DIRECTION_E
	sta	DIRECTION

	jsr	change_location

	rts


green_house:

	; FIXME: handle switch separately

	lda	#32
	sta	LOCATION

	jsr	change_location

	rts



	;==========================
	; includes
	;==========================

	.include	"gr_copy.s"
	.include	"gr_offsets.s"
	.include	"gr_pageflip.s"
	.include	"gr_putsprite_crop.s"
	.include	"text_print.s"
	.include	"gr_fast_clear.s"
	.include	"decompress_fast_v2.s"
	.include	"keyboard.s"
	.include	"draw_pointer.s"

	.include	"audio.s"

	.include	"graphics_mist/mist_graphics.inc"

	.include	"end_level.s"

	; puzzles

	.include	"clock_bridge_puzzle.s"
	.include	"marker_switch.s"
	.include	"brother_books.s"
	.include	"generator_puzzle.s"

	; linking books

	; letters

	.include	"letter_cat.s"


	.include	"common_sprites.inc"

	.include	"leveldata_mist.inc"





;.align $100
;audio_red_page:
;.incbin "audio/red_page.btc"