logo music: initial commit
This commit is contained in:
Vince Weaver
parent
91efaaf7bc
commit
02fdfc02cd
|
|
@ -0,0 +1,12 @@
|
|||
MEMORY {
|
||||
ZP: start = $00, size = $1A, type = rw;
|
||||
RAM: start = $4800, size = $4800, file = %O;
|
||||
}
|
||||
|
||||
SEGMENTS {
|
||||
CODE: load = RAM, type = ro, align=$100;
|
||||
RODATA: load = RAM, type = ro;
|
||||
DATA: load = RAM, type = rw;
|
||||
BSS: load = RAM, type = bss, define = yes;
|
||||
ZEROPAGE: load = ZP, type = zp;
|
||||
}
|
||||
|
|
@ -0,0 +1,87 @@
|
|||
;; HARDWARE LOCATIONS
|
||||
|
||||
KEYPRESS = $C000
|
||||
KEYRESET = $C010
|
||||
|
||||
;; SOFT SWITCHES
|
||||
CLR80COL = $C000 ; PAGE0/PAGE1 normal
|
||||
SET80COL = $C001 ; PAGE0/PAGE1 switches PAGE0 in Aux instead
|
||||
EIGHTYCOLOFF = $C00C
|
||||
EIGHTYCOLON = $C00D
|
||||
SPEAKER = $C030
|
||||
SET_GR = $C050
|
||||
SET_TEXT = $C051
|
||||
FULLGR = $C052
|
||||
TEXTGR = $C053
|
||||
PAGE0 = $C054
|
||||
PAGE1 = $C055
|
||||
LORES = $C056 ; Enable LORES graphics
|
||||
HIRES = $C057 ; Enable HIRES graphics
|
||||
AN3 = $C05E ; Annunciator 3
|
||||
|
||||
PADDLE_BUTTON0 = $C061
|
||||
PADDL0 = $C064
|
||||
PTRIG = $C070
|
||||
|
||||
;; BASIC ROUTINES
|
||||
|
||||
NORMAL = $F273
|
||||
|
||||
;; MONITOR ROUTINES
|
||||
|
||||
HLINE = $F819 ;; HLINE Y,$2C at A
|
||||
VLINE = $F828 ;; VLINE A,$2D at Y
|
||||
CLRSCR = $F832 ;; Clear low-res screen
|
||||
CLRTOP = $F836 ;; clear only top of low-res screen
|
||||
SETGR = $FB40 ;; GR
|
||||
SETCOL = $F864 ;; COLOR=A
|
||||
TEXT = $FB36
|
||||
TABV = $FB5B ;; VTAB to A
|
||||
BELL = $FBDD ;; ring the bell
|
||||
BASCALC = $FBC1 ;;
|
||||
VTAB = $FC22 ;; VTAB to CV
|
||||
HOME = $FC58 ;; Clear the text screen
|
||||
WAIT = $FCA8 ;; delay 1/2(26+27A+5A^2) us
|
||||
CROUT1 = $FD8B
|
||||
SETINV = $FE80 ;; INVERSE
|
||||
SETNORM = $FE84 ;; NORMAL
|
||||
COUT = $FDED ;; output A to screen
|
||||
COUT1 = $FDF0 ;; output A to screen
|
||||
|
||||
|
||||
|
||||
|
||||
|
||||
|
||||
COLOR_BLACK = 0
|
||||
COLOR_RED = 1
|
||||
COLOR_DARKBLUE = 2
|
||||
COLOR_PURPLE = 3
|
||||
COLOR_DARKGREEN = 4
|
||||
COLOR_GREY = 5
|
||||
COLOR_MEDIUMBLUE = 6
|
||||
COLOR_LIGHTBLUE = 7
|
||||
COLOR_BROWN = 8
|
||||
COLOR_ORANGE = 9
|
||||
COLOR_GREY2 = 10
|
||||
COLOR_PINK = 11
|
||||
COLOR_LIGHTGREEN = 12
|
||||
COLOR_YELLOW = 13
|
||||
COLOR_AQUA = 14
|
||||
COLOR_WHITE = 15
|
||||
|
||||
COLOR_BOTH_BLACK = $00
|
||||
COLOR_BOTH_RED = $11
|
||||
COLOR_BOTH_DARKBLUE = $22
|
||||
COLOR_BOTH_DARKGREEN = $44
|
||||
COLOR_BOTH_GREY = $55
|
||||
COLOR_BOTH_MEDIUMBLUE = $66
|
||||
COLOR_BOTH_LIGHTBLUE = $77
|
||||
COLOR_BOTH_BROWN = $88
|
||||
COLOR_BOTH_ORANGE = $99
|
||||
COLOR_BOTH_PINK = $BB
|
||||
COLOR_BOTH_LIGHTGREEN = $CC
|
||||
COLOR_BOTH_YELLOW = $DD
|
||||
COLOR_BOTH_AQUA = $EE
|
||||
COLOR_BOTH_WHITE = $FF
|
||||
|
||||
|
|
@ -0,0 +1,146 @@
|
|||
;================================
|
||||
;================================
|
||||
; mockingboard interrupt handler
|
||||
;================================
|
||||
;================================
|
||||
; On Apple II/6502 the interrupt handler jumps to address in 0xfffe
|
||||
; This is in the ROM, which saves the registers
|
||||
; on older IIe it saved A to $45 (which could mess with DISK II)
|
||||
; newer IIe doesn't do that.
|
||||
; It then calculates if it is a BRK or not (which trashes A)
|
||||
; Then it sets up the stack like an interrupt and calls 0x3fe
|
||||
|
||||
; Note: the IIc is much more complicated
|
||||
; its firmware tries to decode the proper source
|
||||
; based on various things, including screen hole values
|
||||
; we bypass that by switching out ROM and replacing the
|
||||
; $fffe vector with this, but that does mean we have
|
||||
; to be sure status flag and accumulator set properly
|
||||
|
||||
interrupt_handler:
|
||||
php ; save status flags
|
||||
pha ; save A ; 3
|
||||
; A is saved in $45 by firmware
|
||||
txa
|
||||
pha ; save X
|
||||
tya
|
||||
pha ; save Y
|
||||
|
||||
|
||||
|
||||
; inc $0404 ; debug (flashes char onscreen)
|
||||
|
||||
|
||||
.include "pt3_lib_irq_handler.s"
|
||||
|
||||
jmp exit_interrupt
|
||||
|
||||
;=================================
|
||||
; Finally done with this interrupt
|
||||
;=================================
|
||||
|
||||
quiet_exit:
|
||||
stx DONE_PLAYING
|
||||
jsr clear_ay_both
|
||||
|
||||
ldx #$ff ; also mute the channel
|
||||
stx AY_REGISTERS+7 ; just in case
|
||||
|
||||
|
||||
exit_interrupt:
|
||||
|
||||
; update time
|
||||
; inc ticks
|
||||
; lda ticks
|
||||
; cmp #50
|
||||
; bne no_tick_oflo
|
||||
|
||||
; lda #0
|
||||
; sta ticks
|
||||
; inc seconds
|
||||
|
||||
no_tick_oflo:
|
||||
|
||||
; if done, no timeout
|
||||
; lda command
|
||||
; cmp #DONE
|
||||
; beq handle_credits
|
||||
|
||||
; trigger at timeout value
|
||||
|
||||
; lda seconds
|
||||
; cmp timeout
|
||||
; bne handle_credits
|
||||
|
||||
; inc trigger
|
||||
|
||||
; lda which
|
||||
; asl
|
||||
; tax
|
||||
; lda todo_list,x
|
||||
; sta command
|
||||
|
||||
; cmp #DO_CREDITS
|
||||
; bne itsnot
|
||||
|
||||
; jsr switch_to_credits
|
||||
; lda command
|
||||
|
||||
itsnot:
|
||||
; cmp #DONE
|
||||
; beq handle_credits
|
||||
|
||||
; lda todo_list+1,x
|
||||
; sta timeout
|
||||
|
||||
; point to next
|
||||
; inc which
|
||||
|
||||
; reset seconds
|
||||
; lda #0
|
||||
; sta seconds
|
||||
|
||||
; HUGE HACK
|
||||
; return to our code instead of BASIC
|
||||
|
||||
; ldx original_stack
|
||||
; txs
|
||||
; lda #>command_loop
|
||||
; pha
|
||||
; lda #<command_loop
|
||||
; pha
|
||||
|
||||
; lda #0 ; program status word
|
||||
; pha
|
||||
|
||||
; rti
|
||||
|
||||
;handle_credits:
|
||||
; lda command
|
||||
; cmp #DONE
|
||||
; bne done_match
|
||||
|
||||
; jsr display_credits
|
||||
|
||||
done_match:
|
||||
pla
|
||||
tay ; restore Y
|
||||
pla
|
||||
tax ; restore X
|
||||
pla ; restore a ; 4
|
||||
|
||||
; on II+/IIe (but not IIc) we need to do this?
|
||||
interrupt_smc:
|
||||
lda $45 ; restore A
|
||||
plp
|
||||
|
||||
rti ; return from interrupt ; 6
|
||||
|
||||
;============
|
||||
; typical
|
||||
; ???? cycles
|
||||
|
||||
|
||||
|
||||
seconds: .byte $00
|
||||
ticks: .byte $00
|
||||
|
|
@ -0,0 +1,67 @@
|
|||
; Play music while running LOGO
|
||||
|
||||
; by deater (Vince Weaver) <vince@deater.net>
|
||||
|
||||
; Zero Page
|
||||
.include "zp.inc"
|
||||
.include "hardware.inc"
|
||||
.include "nozp.inc"
|
||||
|
||||
STROUT = $db3a
|
||||
|
||||
NONE = 0
|
||||
DO_LOAD = 1
|
||||
DO_LIST = 2
|
||||
DO_RUN = 3
|
||||
DO_CREDITS = 4
|
||||
DONE = 5
|
||||
|
||||
;==========================================
|
||||
; we are loaded at $6000
|
||||
;
|
||||
; since we are now decompressed here after load
|
||||
; we don't have to worry about running into DOS3.3 at $9600
|
||||
;
|
||||
; we shouldn't need to set HIMEM as we don't use many vars
|
||||
; and variable memory starts right after the program
|
||||
|
||||
bot_demo:
|
||||
|
||||
;===================
|
||||
; PT3 player Setup
|
||||
|
||||
lda #0
|
||||
sta DONE_PLAYING
|
||||
lda #1
|
||||
sta LOOP
|
||||
|
||||
jsr mockingboard_detect
|
||||
bcc mockingboard_not_found
|
||||
setup_interrupt:
|
||||
jsr mockingboard_init
|
||||
jsr mockingboard_setup_interrupt
|
||||
jsr reset_ay_both
|
||||
jsr clear_ay_both
|
||||
jsr pt3_init_song
|
||||
|
||||
start_interrupts:
|
||||
; tsx
|
||||
; stx original_stack
|
||||
|
||||
cli
|
||||
|
||||
mockingboard_not_found:
|
||||
|
||||
.include "pt3_lib_core.s"
|
||||
.include "pt3_lib_init.s"
|
||||
.include "pt3_lib_mockingboard_setup.s"
|
||||
.include "interrupt_handler.s"
|
||||
; if you're self patching, detect has to be after interrupt_handler.s
|
||||
.include "pt3_lib_mockingboard_detect.s"
|
||||
|
||||
PT3_LOC = song
|
||||
.align $100
|
||||
song:
|
||||
;.incbin "../../demos/applebot_demo/music/mAZE_-_The_Upbeated_Eaten_Apple.pt3"
|
||||
;.incbin "../../demos/outline2021/demo/mAZE_-_Apple_snapple_Outline.pt3"
|
||||
.incbin "./music/Fret.pt3"
|
||||
Binary file not shown.
|
|
@ -0,0 +1,27 @@
|
|||
;; Things that normally would go in the zero page
|
||||
|
||||
|
||||
AY_REGISTERS:
|
||||
A_FINE_TONE: .byte $00
|
||||
A_COARSE_TONE: .byte $00
|
||||
B_FINE_TONE: .byte $00
|
||||
B_COARSE_TONE: .byte $00
|
||||
C_FINE_TONE: .byte $00
|
||||
C_COARSE_TONE: .byte $00
|
||||
NOISE: .byte $00
|
||||
ENABLE:
|
||||
PT3_MIXER_VAL: .byte $00
|
||||
A_VOLUME: .byte $00
|
||||
B_VOLUME: .byte $00
|
||||
C_VOLUME: .byte $00
|
||||
ENVELOPE_FINE: .byte $00
|
||||
ENVELOPE_COARSE:.byte $00
|
||||
ENVELOPE_SHAPE: .byte $00
|
||||
|
||||
LOOP: .byte $00
|
||||
MB_VALUE: .byte $00
|
||||
DONE_PLAYING: .byte $00
|
||||
DONE_SONG: .byte $00
|
||||
PT3_TEMP: .byte $00
|
||||
|
||||
|
||||
File diff suppressed because it is too large
Load Diff
|
|
@ -0,0 +1,575 @@
|
|||
; pt3_lib_init.s
|
||||
|
||||
; Initialize a song
|
||||
|
||||
; this is done before song starts playing so it is not
|
||||
; as performance / timing critical
|
||||
|
||||
;====================================
|
||||
; pt3_init_song
|
||||
;====================================
|
||||
;
|
||||
pt3_init_song:
|
||||
|
||||
lda #$0
|
||||
sta DONE_SONG ; 3
|
||||
ldx #(end_vars-begin_vars)
|
||||
zero_song_structs_loop:
|
||||
dex
|
||||
sta note_a,X
|
||||
bne zero_song_structs_loop
|
||||
|
||||
sta pt3_noise_period_smc+1 ; 4
|
||||
sta pt3_noise_add_smc+1 ; 4
|
||||
|
||||
sta pt3_envelope_period_l_smc+1 ; 4
|
||||
sta pt3_envelope_period_h_smc+1 ; 4
|
||||
sta pt3_envelope_slide_l_smc+1 ; 4
|
||||
sta pt3_envelope_slide_h_smc+1 ; 4
|
||||
sta pt3_envelope_slide_add_l_smc+1 ; 4
|
||||
sta pt3_envelope_slide_add_h_smc+1 ; 4
|
||||
sta pt3_envelope_add_smc+1 ; 4
|
||||
sta pt3_envelope_type_smc+1 ; 4
|
||||
sta pt3_envelope_type_old_smc+1 ; 4
|
||||
sta pt3_envelope_delay_smc+1 ; 4
|
||||
sta pt3_envelope_delay_orig_smc+1 ; 4
|
||||
|
||||
sta PT3_MIXER_VAL ; 3
|
||||
|
||||
sta current_pattern_smc+1 ; 4
|
||||
sta current_line_smc+1 ; 4
|
||||
sta current_subframe_smc+1 ; 4
|
||||
|
||||
lda #$f ; 2
|
||||
sta note_a+NOTE_VOLUME ; 4
|
||||
sta note_b+NOTE_VOLUME ; 4
|
||||
sta note_c+NOTE_VOLUME ; 4
|
||||
|
||||
; default ornament/sample in A
|
||||
; X is zero coming in here
|
||||
;ldx #(NOTE_STRUCT_SIZE*0) ; 2
|
||||
jsr load_ornament0_sample1 ; 6+93
|
||||
|
||||
; default ornament/sample in B
|
||||
ldx #(NOTE_STRUCT_SIZE*1) ; 2
|
||||
jsr load_ornament0_sample1 ; 6+93
|
||||
|
||||
; default ornament/sample in C
|
||||
ldx #(NOTE_STRUCT_SIZE*2) ; 2
|
||||
jsr load_ornament0_sample1 ; 6+93
|
||||
|
||||
;=======================
|
||||
; load default speed
|
||||
|
||||
lda PT3_LOC+PT3_SPEED ; 4
|
||||
sta pt3_speed_smc+1 ; 4
|
||||
|
||||
;=======================
|
||||
; load loop
|
||||
|
||||
lda PT3_LOC+PT3_LOOP ; 4
|
||||
sta pt3_loop_smc+1 ; 4
|
||||
|
||||
|
||||
;========================
|
||||
;========================
|
||||
; set up note/freq table
|
||||
; this saves some space and makes things marginally faster longrun
|
||||
;========================
|
||||
;========================
|
||||
; note (heh) that there are separate tables if version 3.3
|
||||
; but we are going to assume we are only going to be playing
|
||||
; newer 3.4+ version files so only need the newer tables
|
||||
|
||||
ldx PT3_LOC+PT3_HEADER_FREQUENCY ; 4
|
||||
beq use_freq_table_0
|
||||
dex
|
||||
beq use_freq_table_1
|
||||
dex
|
||||
beq use_freq_table_2
|
||||
; fallthrough (freq table 3)
|
||||
|
||||
use_freq_table_3:
|
||||
;=================================================
|
||||
; Create Table #3, v4+, "PT3NoteTable_REAL_34_35"
|
||||
;=================================================
|
||||
|
||||
ldy #11 ; !2
|
||||
freq_table_3_copy_loop:
|
||||
; note, high lookup almost same as 2v4, just need to adjust one value
|
||||
|
||||
lda base2_v4_high,Y ; !3
|
||||
sta NoteTable_high,Y ; !3
|
||||
lda base3_low,Y ; !3
|
||||
sta NoteTable_low,Y ; !3
|
||||
dey ; !1
|
||||
bpl freq_table_3_copy_loop ; !2
|
||||
|
||||
dec NoteTable_high ; adjust to right value
|
||||
|
||||
jsr NoteTablePropogate ; !3
|
||||
|
||||
lda #<table3_v4_adjust
|
||||
sta note_table_adjust_smc+1
|
||||
lda #>table3_v4_adjust
|
||||
sta note_table_adjust_smc+2
|
||||
|
||||
jsr NoteTableAdjust
|
||||
|
||||
jmp done_set_freq_table
|
||||
|
||||
|
||||
|
||||
use_freq_table_2:
|
||||
;=================================================
|
||||
; Create Table #2, v4+, "PT3NoteTable_ASM_34_35"
|
||||
;=================================================
|
||||
|
||||
ldy #11
|
||||
freq_table_2_copy_loop:
|
||||
lda base2_v4_high,Y
|
||||
sta NoteTable_high,Y
|
||||
lda base2_v4_low,Y
|
||||
sta NoteTable_low,Y
|
||||
dey
|
||||
bpl freq_table_2_copy_loop
|
||||
|
||||
jsr NoteTablePropogate ; !3
|
||||
|
||||
lda #<table2_v4_adjust
|
||||
sta note_table_adjust_smc+1
|
||||
lda #>table2_v4_adjust
|
||||
sta note_table_adjust_smc+2
|
||||
|
||||
jsr NoteTableAdjust
|
||||
|
||||
jmp done_set_freq_table
|
||||
|
||||
use_freq_table_1:
|
||||
;=================================================
|
||||
; Create Table #1, "PT3NoteTable_ST"
|
||||
;=================================================
|
||||
|
||||
ldy #11
|
||||
freq_table_1_copy_loop:
|
||||
lda base1_high,Y
|
||||
sta NoteTable_high,Y
|
||||
lda base1_low,Y
|
||||
sta NoteTable_low,Y
|
||||
dey
|
||||
bpl freq_table_1_copy_loop
|
||||
|
||||
jsr NoteTablePropogate ; !3
|
||||
|
||||
; last adjustments
|
||||
lda #$FD ; Tone[23]=$3FD
|
||||
sta NoteTable_low+23
|
||||
dec NoteTable_low+46 ; Tone[46]-=1;
|
||||
|
||||
|
||||
jmp done_set_freq_table
|
||||
|
||||
|
||||
use_freq_table_0:
|
||||
;=================================================
|
||||
; Create Table #0, "PT3NoteTable_PT_34_35"
|
||||
;=================================================
|
||||
|
||||
ldy #11
|
||||
freq_table_0_copy_loop:
|
||||
lda base0_v4_high,Y
|
||||
sta NoteTable_high,Y
|
||||
lda base0_v4_low,Y
|
||||
sta NoteTable_low,Y
|
||||
dey
|
||||
bpl freq_table_0_copy_loop
|
||||
|
||||
jsr NoteTablePropogate ; !3
|
||||
|
||||
lda #<table0_v4_adjust
|
||||
sta note_table_adjust_smc+1
|
||||
lda #>table0_v4_adjust
|
||||
sta note_table_adjust_smc+2
|
||||
|
||||
jsr NoteTableAdjust
|
||||
|
||||
|
||||
done_set_freq_table:
|
||||
|
||||
|
||||
;======================
|
||||
; calculate version
|
||||
ldx #6 ; 2
|
||||
lda PT3_LOC+PT3_VERSION ; 4
|
||||
sec ; 2
|
||||
sbc #'0' ; 2
|
||||
cmp #9 ; 2
|
||||
bcs not_ascii_number ; bge ; 2/3
|
||||
tax ; 2
|
||||
|
||||
not_ascii_number:
|
||||
|
||||
; adjust version<6 SMC code in the slide code
|
||||
|
||||
; FIXME: I am sure there's a more clever way to do this
|
||||
|
||||
lda #$2C ; BIT ; 2
|
||||
cpx #$6 ; 2
|
||||
bcs version_greater_than_or_equal_6 ; bgt ; 3
|
||||
; less than 6, jump
|
||||
; also carry is known to be clear
|
||||
adc #$20 ; BIT->JMP 2C->4C ; 2
|
||||
version_greater_than_or_equal_6:
|
||||
sta version_smc ; 4
|
||||
|
||||
pick_volume_table:
|
||||
|
||||
;=======================
|
||||
; Pick which volume number, based on version
|
||||
|
||||
; if (PlParams.PT3.PT3_Version <= 4)
|
||||
|
||||
cpx #5 ; 2
|
||||
|
||||
; carry clear = 3.3/3.4 table
|
||||
; carry set = 3.5 table
|
||||
|
||||
;==========================
|
||||
; VolTableCreator
|
||||
;==========================
|
||||
; Creates the appropriate volume table
|
||||
; based on z80 code by Ivan Roshin ZXAYHOBETA/VTII10bG.asm
|
||||
;
|
||||
|
||||
; Called with carry==0 for 3.3/3.4 table
|
||||
; Called with carry==1 for 3.5 table
|
||||
|
||||
; 177f-1932 = 435 bytes, not that much better than 512 of lookup
|
||||
|
||||
|
||||
VolTableCreator:
|
||||
|
||||
; Init initial variables
|
||||
lda #$0
|
||||
sta z80_d_smc+1
|
||||
ldy #$11
|
||||
|
||||
; Set up self modify
|
||||
|
||||
ldx #$2A ; ROL for self-modify
|
||||
bcs vol_type_35
|
||||
|
||||
vol_type_33:
|
||||
|
||||
; For older table, we set initial conditions a bit
|
||||
; different
|
||||
|
||||
dey
|
||||
tya
|
||||
|
||||
ldx #$ea ; NOP for self modify
|
||||
|
||||
vol_type_35:
|
||||
sty z80_l_smc+1 ; l=16 or 17
|
||||
sta z80_e_smc+1 ; e=16 or 0
|
||||
stx vol_smc ; set the self-modify code
|
||||
|
||||
ldy #16 ; skip first row, all zeros
|
||||
ldx #16 ; c=16
|
||||
vol_outer:
|
||||
clc ; add HL,DE
|
||||
z80_l_smc:
|
||||
lda #$d1
|
||||
z80_e_smc:
|
||||
adc #$d1
|
||||
sta z80_e_smc+1
|
||||
lda #0
|
||||
z80_d_smc:
|
||||
adc #$d1
|
||||
sta z80_d_smc+1 ; carry is important
|
||||
|
||||
; sbc hl,hl
|
||||
lda #0
|
||||
adc #$ff
|
||||
eor #$ff
|
||||
|
||||
vol_write:
|
||||
sta z80_h_smc+1
|
||||
pha
|
||||
|
||||
vol_inner:
|
||||
pla
|
||||
pha
|
||||
|
||||
vol_smc:
|
||||
nop ; nop or ROL depending
|
||||
|
||||
z80_h_smc:
|
||||
lda #$d1
|
||||
|
||||
adc #$0 ; a=a+carry;
|
||||
|
||||
sta VolumeTable,Y
|
||||
iny
|
||||
|
||||
pla ; add HL,DE
|
||||
adc z80_e_smc+1
|
||||
pha
|
||||
lda z80_h_smc+1
|
||||
adc z80_d_smc+1
|
||||
sta z80_h_smc+1
|
||||
|
||||
inx ; inc C
|
||||
txa ; a=c
|
||||
and #$f
|
||||
bne vol_inner
|
||||
|
||||
|
||||
pla
|
||||
|
||||
lda z80_e_smc+1 ; a=e
|
||||
cmp #$77
|
||||
bne vol_m3
|
||||
|
||||
inc z80_e_smc+1
|
||||
|
||||
vol_m3:
|
||||
txa ; a=c
|
||||
bne vol_outer
|
||||
|
||||
vol_done:
|
||||
rts
|
||||
|
||||
|
||||
;=========================================
|
||||
; copy note table seed to proper location
|
||||
;=========================================
|
||||
|
||||
; faster inlined
|
||||
|
||||
;NoteTableCopy:
|
||||
|
||||
; ldy #11 ; !2
|
||||
;note_table_copy_loop:
|
||||
;ntc_smc1:
|
||||
; lda base1_high,Y ; !3
|
||||
; sta NoteTable_high,Y ; !3
|
||||
;ntc_smc2:
|
||||
; lda base1_low,Y ; !3
|
||||
; sta NoteTable_low,Y ; !3
|
||||
; dey ; !1
|
||||
; bpl note_table_copy_loop ; !2
|
||||
; rts ; !1
|
||||
|
||||
|
||||
;==========================================
|
||||
; propogate the freq down, dividing by two
|
||||
;==========================================
|
||||
NoteTablePropogate:
|
||||
|
||||
ldy #0
|
||||
note_table_propogate_loop:
|
||||
clc
|
||||
lda NoteTable_high,Y
|
||||
ror
|
||||
sta NoteTable_high+12,Y
|
||||
|
||||
lda NoteTable_low,Y
|
||||
ror
|
||||
sta NoteTable_low+12,Y
|
||||
|
||||
iny
|
||||
cpy #84
|
||||
bne note_table_propogate_loop
|
||||
|
||||
rts
|
||||
|
||||
|
||||
;================================================
|
||||
; propogation isn't enough, various values
|
||||
; are often off by one, so adjust using a bitmask
|
||||
;================================================
|
||||
NoteTableAdjust:
|
||||
|
||||
ldx #0
|
||||
note_table_adjust_outer:
|
||||
|
||||
note_table_adjust_smc:
|
||||
lda table0_v4_adjust,X
|
||||
sta PT3_TEMP
|
||||
|
||||
; reset smc
|
||||
lda #<NoteTable_low
|
||||
sta ntl_smc+1
|
||||
lda #>NoteTable_low
|
||||
sta ntl_smc+2
|
||||
|
||||
|
||||
ldy #7
|
||||
note_table_adjust_inner:
|
||||
ror PT3_TEMP
|
||||
bcc note_table_skip_adjust
|
||||
|
||||
ntl_smc:
|
||||
inc NoteTable_low,X
|
||||
|
||||
note_table_skip_adjust:
|
||||
clc
|
||||
lda #12
|
||||
adc ntl_smc+1
|
||||
sta ntl_smc+1
|
||||
lda #0
|
||||
adc ntl_smc+2 ; unnecessary if aligned
|
||||
sta ntl_smc+2
|
||||
|
||||
skip_adjust_done:
|
||||
dey
|
||||
bpl note_table_adjust_inner
|
||||
|
||||
inx
|
||||
cpx #12
|
||||
bne note_table_adjust_outer
|
||||
|
||||
rts
|
||||
|
||||
|
||||
;base0_v3_high:
|
||||
;.byte $0C,$0B,$0A,$0A,$09,$09,$08,$08,$07,$07,$06,$06
|
||||
;base0_v3_low:
|
||||
;.byte $21,$73,$CE,$33,$A0,$16,$93,$18,$A4,$36,$CE,$6D
|
||||
|
||||
; note: same as base0_v3_high
|
||||
base0_v4_high:
|
||||
.byte $0C,$0B,$0A,$0A,$09,$09,$08,$08,$07,$07,$06,$06
|
||||
base0_v4_low:
|
||||
.byte $22,$73,$CF,$33,$A1,$17,$94,$19,$A4,$37,$CF,$6D
|
||||
|
||||
base1_high:
|
||||
.byte $0E,$0E,$0D,$0C,$0B,$0B,$0A,$09,$09,$08,$08,$07
|
||||
base1_low:
|
||||
.byte $F8,$10,$60,$80,$D8,$28,$88,$F0,$60,$E0,$58,$E0
|
||||
|
||||
;base2_v3_high:
|
||||
;.byte $0D,$0C,$0B,$0B,$0A,$09,$09,$08,$08,$07,$07,$07
|
||||
;base2_v3_low:
|
||||
;.byte $3E,$80,$CC,$22,$82,$EC,$5C,$D6,$58,$E0,$6E,$04
|
||||
|
||||
; note almost same as above
|
||||
base2_v4_high:
|
||||
.byte $0D,$0C,$0B,$0A,$0A,$09,$09,$08,$08,$07,$07,$06
|
||||
base2_v4_low:
|
||||
.byte $10,$55,$A4,$FC,$5F,$CA,$3D,$B8,$3B,$C5,$55,$EC
|
||||
|
||||
; note almost same as above
|
||||
;base3_high:
|
||||
;.byte $0C,$0C,$0B,$0A,$0A,$09,$09,$08,$08,$07,$07,$06
|
||||
base3_low:
|
||||
.byte $DA,$22,$73,$CF,$33,$A1,$17,$94,$19,$A4,$37,$CF
|
||||
|
||||
|
||||
; Adjustment factors
|
||||
table0_v4_adjust:
|
||||
.byte $40,$e6,$9c,$66,$40,$2c,$20,$30,$48,$6c,$1c,$5a
|
||||
|
||||
table2_v4_adjust:
|
||||
.byte $20,$a8,$40,$f8,$bc,$90,$78,$70,$74,$08,$2a,$50
|
||||
|
||||
table3_v4_adjust:
|
||||
.byte $B4,$40,$e6,$9c,$66,$40,$2c,$20,$30,$48,$6c,$1c
|
||||
|
||||
|
||||
; Table #1 of Pro Tracker 3.3x - 3.5x
|
||||
;PT3NoteTable_ST_high:
|
||||
;.byte $0E,$0E,$0D,$0C,$0B,$0B,$0A,$09
|
||||
;.byte $09,$08,$08,$07,$07,$07,$06,$06
|
||||
;.byte $05,$05,$05,$04,$04,$04,$04,$03
|
||||
;.byte $03,$03,$03,$03,$02,$02,$02,$02
|
||||
;.byte $02,$02,$02,$01,$01,$01,$01,$01
|
||||
;.byte $01,$01,$01,$01,$01,$01,$01,$00
|
||||
;.byte $00,$00,$00,$00,$00,$00,$00,$00
|
||||
;.byte $00,$00,$00,$00,$00,$00,$00,$00
|
||||
;.byte $00,$00,$00,$00,$00,$00,$00,$00
|
||||
;.byte $00,$00,$00,$00,$00,$00,$00,$00
|
||||
;.byte $00,$00,$00,$00,$00,$00,$00,$00
|
||||
;.byte $00,$00,$00,$00,$00,$00,$00,$00
|
||||
|
||||
;PT3NoteTable_ST_low:
|
||||
;.byte $F8,$10,$60,$80,$D8,$28,$88,$F0
|
||||
;.byte $60,$E0,$58,$E0,$7C,$08,$B0,$40
|
||||
;.byte $EC,$94,$44,$F8,$B0,$70,$2C,$FD
|
||||
;.byte $BE,$84,$58,$20,$F6,$CA,$A2,$7C
|
||||
;.byte $58,$38,$16,$F8,$DF,$C2,$AC,$90
|
||||
;.byte $7B,$65,$51,$3E,$2C,$1C,$0A,$FC
|
||||
;.byte $EF,$E1,$D6,$C8,$BD,$B2,$A8,$9F
|
||||
;.byte $96,$8E,$85,$7E,$77,$70,$6B,$64
|
||||
;.byte $5E,$59,$54,$4F,$4B,$47,$42,$3F
|
||||
;.byte $3B,$38,$35,$32,$2F,$2C,$2A,$27
|
||||
;.byte $25,$23,$21,$1F,$1D,$1C,$1A,$19
|
||||
;.byte $17,$16,$15,$13,$12,$11,$10,$0F
|
||||
|
||||
|
||||
; Table #2 of Pro Tracker 3.4x - 3.5x
|
||||
;PT3NoteTable_ASM_34_35_high:
|
||||
;.byte $0D,$0C,$0B,$0A,$0A,$09,$09,$08
|
||||
;.byte $08,$07,$07,$06,$06,$06,$05,$05
|
||||
;.byte $05,$04,$04,$04,$04,$03,$03,$03
|
||||
;.byte $03,$03,$02,$02,$02,$02,$02,$02
|
||||
;.byte $02,$01,$01,$01,$01,$01,$01,$01
|
||||
;.byte $01,$01,$01,$01,$01,$00,$00,$00
|
||||
;.byte $00,$00,$00,$00,$00,$00,$00,$00
|
||||
;.byte $00,$00,$00,$00,$00,$00,$00,$00
|
||||
;.byte $00,$00,$00,$00,$00,$00,$00,$00
|
||||
;.byte $00,$00,$00,$00,$00,$00,$00,$00
|
||||
;.byte $00,$00,$00,$00,$00,$00,$00,$00
|
||||
;.byte $00,$00,$00,$00,$00,$00,$00,$00
|
||||
|
||||
;PT3NoteTable_ASM_34_35_low:
|
||||
;.byte $10,$55,$A4,$FC,$5F,$CA,$3D,$B8
|
||||
;.byte $3B,$C5,$55,$EC,$88,$2A,$D2,$7E
|
||||
;.byte $2F,$E5,$9E,$5C,$1D,$E2,$AB,$76
|
||||
;.byte $44,$15,$E9,$BF,$98,$72,$4F,$2E
|
||||
;.byte $0F,$F1,$D5,$BB,$A2,$8B,$74,$60
|
||||
;.byte $4C,$39,$28,$17,$07,$F9,$EB,$DD
|
||||
;.byte $D1,$C5,$BA,$B0,$A6,$9D,$94,$8C
|
||||
;.byte $84,$7C,$75,$6F,$69,$63,$5D,$58
|
||||
;.byte $53,$4E,$4A,$46,$42,$3E,$3B,$37
|
||||
;.byte $34,$31,$2F,$2C,$29,$27,$25,$23
|
||||
;.byte $21,$1F,$1D,$1C,$1A,$19,$17,$16
|
||||
;.byte $15,$14,$12,$11,$10,$0F,$0E,$0D
|
||||
|
||||
|
||||
;PT3VolumeTable_33_34:
|
||||
;.byte $0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0
|
||||
;.byte $0,$0,$0,$0,$0,$0,$0,$0,$1,$1,$1,$1,$1,$1,$1,$1
|
||||
;.byte $0,$0,$0,$0,$0,$0,$1,$1,$1,$1,$1,$2,$2,$2,$2,$2
|
||||
;.byte $0,$0,$0,$0,$1,$1,$1,$1,$2,$2,$2,$2,$3,$3,$3,$3
|
||||
;.byte $0,$0,$0,$0,$1,$1,$1,$2,$2,$2,$3,$3,$3,$4,$4,$4
|
||||
;.byte $0,$0,$0,$1,$1,$1,$2,$2,$3,$3,$3,$4,$4,$4,$5,$5
|
||||
;.byte $0,$0,$0,$1,$1,$2,$2,$3,$3,$3,$4,$4,$5,$5,$6,$6
|
||||
;.byte $0,$0,$1,$1,$2,$2,$3,$3,$4,$4,$5,$5,$6,$6,$7,$7
|
||||
;.byte $0,$0,$1,$1,$2,$2,$3,$3,$4,$5,$5,$6,$6,$7,$7,$8
|
||||
;.byte $0,$0,$1,$1,$2,$3,$3,$4,$5,$5,$6,$6,$7,$8,$8,$9
|
||||
;.byte $0,$0,$1,$2,$2,$3,$4,$4,$5,$6,$6,$7,$8,$8,$9,$A
|
||||
;.byte $0,$0,$1,$2,$3,$3,$4,$5,$6,$6,$7,$8,$9,$9,$A,$B
|
||||
;.byte $0,$0,$1,$2,$3,$4,$4,$5,$6,$7,$8,$8,$9,$A,$B,$C
|
||||
;.byte $0,$0,$1,$2,$3,$4,$5,$6,$7,$7,$8,$9,$A,$B,$C,$D
|
||||
;.byte $0,$0,$1,$2,$3,$4,$5,$6,$7,$8,$9,$A,$B,$C,$D,$E
|
||||
;.byte $0,$1,$2,$3,$4,$5,$6,$7,$8,$9,$A,$B,$C,$D,$E,$F
|
||||
|
||||
;PT3VolumeTable_35:
|
||||
;.byte $0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0
|
||||
;.byte $0,$0,$0,$0,$0,$0,$0,$0,$1,$1,$1,$1,$1,$1,$1,$1
|
||||
;.byte $0,$0,$0,$0,$1,$1,$1,$1,$1,$1,$1,$1,$2,$2,$2,$2
|
||||
;.byte $0,$0,$0,$1,$1,$1,$1,$1,$2,$2,$2,$2,$2,$3,$3,$3
|
||||
;.byte $0,$0,$1,$1,$1,$1,$2,$2,$2,$2,$3,$3,$3,$3,$4,$4
|
||||
;.byte $0,$0,$1,$1,$1,$2,$2,$2,$3,$3,$3,$4,$4,$4,$5,$5
|
||||
;.byte $0,$0,$1,$1,$2,$2,$2,$3,$3,$4,$4,$4,$5,$5,$6,$6
|
||||
;.byte $0,$0,$1,$1,$2,$2,$3,$3,$4,$4,$5,$5,$6,$6,$7,$7
|
||||
;.byte $0,$1,$1,$2,$2,$3,$3,$4,$4,$5,$5,$6,$6,$7,$7,$8
|
||||
;.byte $0,$1,$1,$2,$2,$3,$4,$4,$5,$5,$6,$7,$7,$8,$8,$9
|
||||
;.byte $0,$1,$1,$2,$3,$3,$4,$5,$5,$6,$7,$7,$8,$9,$9,$A
|
||||
;.byte $0,$1,$1,$2,$3,$4,$4,$5,$6,$7,$7,$8,$9,$A,$A,$B
|
||||
;.byte $0,$1,$2,$2,$3,$4,$5,$6,$6,$7,$8,$9,$A,$A,$B,$C
|
||||
;.byte $0,$1,$2,$3,$3,$4,$5,$6,$7,$8,$9,$A,$A,$B,$C,$D
|
||||
;.byte $0,$1,$2,$3,$4,$5,$6,$7,$7,$8,$9,$A,$B,$C,$D,$E
|
||||
;.byte $0,$1,$2,$3,$4,$5,$6,$7,$8,$9,$A,$B,$C,$D,$E,$F
|
||||
|
|
@ -0,0 +1,116 @@
|
|||
|
||||
|
||||
pt3_irq_handler:
|
||||
|
||||
pt3_irq_smc1:
|
||||
bit MOCK_6522_T1CL ; clear 6522 interrupt by reading T1C-L ; 4
|
||||
|
||||
lda DONE_PLAYING ; 3
|
||||
beq pt3_play_music ; if song done, don't play music ; 3/2nt
|
||||
jmp done_pt3_irq_handler ; 3
|
||||
;============
|
||||
; 13
|
||||
|
||||
pt3_play_music:
|
||||
|
||||
; decode a frame of music
|
||||
|
||||
jsr pt3_make_frame
|
||||
|
||||
; handle song over condition
|
||||
lda DONE_SONG
|
||||
beq mb_write_frame ; if not done, continue
|
||||
|
||||
lda LOOP ; see if looping
|
||||
beq move_to_next
|
||||
|
||||
pt3_loop_smc:
|
||||
lda #$d1 ; looping, move to loop location
|
||||
; non-zero to avoid the temptation
|
||||
; to merge with following lda #$0
|
||||
sta current_pattern_smc+1
|
||||
lda #$0
|
||||
sta current_line_smc+1
|
||||
sta current_subframe_smc+1
|
||||
sta DONE_SONG ; undo the next song
|
||||
|
||||
beq done_pt3_irq_handler ; branch always
|
||||
|
||||
move_to_next:
|
||||
; same as "press right"
|
||||
ldx #$20
|
||||
jmp quiet_exit
|
||||
|
||||
;======================================
|
||||
; Write frames to Mockingboard
|
||||
;======================================
|
||||
; for speed could merge this into
|
||||
; the decode code
|
||||
|
||||
mb_write_frame:
|
||||
|
||||
|
||||
tax ; set up reg count ; 2
|
||||
;============
|
||||
; 2
|
||||
|
||||
;==================================
|
||||
; loop through the 14 registers
|
||||
; reading the value, then write out
|
||||
;==================================
|
||||
|
||||
mb_write_loop:
|
||||
lda AY_REGISTERS,X ; load register value ; 4
|
||||
|
||||
; special case R13. If it is 0xff, then don't update
|
||||
; otherwise might spuriously reset the envelope settings
|
||||
|
||||
cpx #13 ; 2
|
||||
bne mb_not_13 ; 3/2nt
|
||||
cmp #$ff ; 2
|
||||
beq mb_skip_13 ; 3/2nt
|
||||
;============
|
||||
; typ 5
|
||||
mb_not_13:
|
||||
|
||||
|
||||
; address
|
||||
pt3_irq_smc2:
|
||||
stx MOCK_6522_ORA1 ; put address on PA1 ; 4
|
||||
stx MOCK_6522_ORA2 ; put address on PA2 ; 4
|
||||
ldy #MOCK_AY_LATCH_ADDR ; latch_address for PB1 ; 2
|
||||
pt3_irq_smc3:
|
||||
sty MOCK_6522_ORB1 ; latch_address on PB1 ; 4
|
||||
sty MOCK_6522_ORB2 ; latch_address on PB2 ; 4
|
||||
ldy #MOCK_AY_INACTIVE ; go inactive ; 2
|
||||
pt3_irq_smc4:
|
||||
sty MOCK_6522_ORB1 ; 4
|
||||
sty MOCK_6522_ORB2 ; 4
|
||||
|
||||
; value
|
||||
pt3_irq_smc5:
|
||||
sta MOCK_6522_ORA1 ; put value on PA1 ; 4
|
||||
sta MOCK_6522_ORA2 ; put value on PA2 ; 4
|
||||
lda #MOCK_AY_WRITE ; ; 2
|
||||
pt3_irq_smc6:
|
||||
sta MOCK_6522_ORB1 ; write on PB1 ; 4
|
||||
sty MOCK_6522_ORB1 ; 4
|
||||
pt3_irq_smc7:
|
||||
sta MOCK_6522_ORB2 ; write on PB2 ; 4
|
||||
sty MOCK_6522_ORB2 ; 4
|
||||
;===========
|
||||
; 56
|
||||
mb_no_write:
|
||||
inx ; point to next register ; 2
|
||||
cpx #14 ; if 14 we're done ; 2
|
||||
bmi mb_write_loop ; otherwise, loop ; 3/2nt
|
||||
;============
|
||||
; 7
|
||||
mb_skip_13:
|
||||
|
||||
|
||||
;=================================
|
||||
; Finally done with this interrupt
|
||||
;=================================
|
||||
|
||||
done_pt3_irq_handler:
|
||||
|
|
@ -0,0 +1,314 @@
|
|||
;===================================================================
|
||||
; code to detect mockingboard
|
||||
;===================================================================
|
||||
; this isn't always easy
|
||||
; my inclination is to just assume slot #4 but that isn't always realistic
|
||||
|
||||
; code below based on "hw.mockingboard.a" from "Total Replay"
|
||||
|
||||
;license:MIT
|
||||
; By Andrew Roughan
|
||||
; in the style of 4am for Total Replay
|
||||
;
|
||||
; Mockingboard support functions
|
||||
;
|
||||
|
||||
;------------------------------------------------------------------------------
|
||||
; HasMockingboard
|
||||
; detect Mockingboard card by searching for 6522 timers across all slots
|
||||
; access 6522 timers with deterministic cycle counts
|
||||
;
|
||||
; based on prior art in Mockingboard Developers Toolkit
|
||||
; with optimisation from deater/french touch
|
||||
; also takes into account FastChip //e clock difference
|
||||
;
|
||||
; in: none
|
||||
; accelerators should be off
|
||||
; out: C set if Mockingboard found in any slot
|
||||
; if card was found, X = #$Cn where n is the slot number of the card
|
||||
; C clear if no Mockingboard found
|
||||
; other flags clobbered
|
||||
; zp $65-$67 clobbered
|
||||
; A/Y clobbered
|
||||
;------------------------------------------------------------------------------
|
||||
|
||||
mockingboard_detect:
|
||||
lda #$00
|
||||
sta MB_ADDR_L
|
||||
ldx #$C7 ; start at slot #7
|
||||
mb_slot_loop:
|
||||
stx MB_ADDR_H
|
||||
ldy #$04 ; 6522 #1 $Cx04
|
||||
jsr mb_timer_check
|
||||
bne mb_next_slot
|
||||
ldy #$84 ; 6522 #2 $Cx84
|
||||
jsr mb_timer_check
|
||||
bne mb_next_slot
|
||||
mb_found:
|
||||
sec ; found
|
||||
rts
|
||||
|
||||
mb_next_slot:
|
||||
dex
|
||||
cpx #$C0
|
||||
bne mb_slot_loop
|
||||
|
||||
clc ; not found
|
||||
rts
|
||||
|
||||
mb_timer_check:
|
||||
lda (MB_ADDR_L),Y ; read 6522 timer low byte
|
||||
sta MB_VALUE
|
||||
lda (MB_ADDR_L),Y ; second time
|
||||
sec
|
||||
sbc MB_VALUE
|
||||
cmp #$F8 ; looking for (-)8 cycles between reads
|
||||
beq mb_timer_check_done
|
||||
cmp #$F7 ; FastChip //e clock is different
|
||||
mb_timer_check_done:
|
||||
rts
|
||||
|
||||
|
||||
|
||||
;===================================================================
|
||||
; code to patch mockingboard if not in slot#4
|
||||
;===================================================================
|
||||
; this is the brute force version, we have to patch 39 locations
|
||||
; see further below if you want to try a smaller, more dangerous, patch
|
||||
|
||||
.if 0
|
||||
mockingboard_patch:
|
||||
|
||||
lda MB_ADDR_H
|
||||
|
||||
sta pt3_irq_smc1+2 ; 1
|
||||
|
||||
sta pt3_irq_smc2+2 ; 2
|
||||
sta pt3_irq_smc2+5 ; 3
|
||||
|
||||
sta pt3_irq_smc3+2 ; 4
|
||||
sta pt3_irq_smc3+5 ; 5
|
||||
|
||||
sta pt3_irq_smc4+2 ; 6
|
||||
sta pt3_irq_smc4+5 ; 7
|
||||
|
||||
sta pt3_irq_smc5+2 ; 8
|
||||
sta pt3_irq_smc5+5 ; 9
|
||||
|
||||
sta pt3_irq_smc6+2 ; 10
|
||||
sta pt3_irq_smc6+5 ; 11
|
||||
|
||||
sta pt3_irq_smc7+2 ; 12
|
||||
sta pt3_irq_smc7+5 ; 13
|
||||
|
||||
sta mock_init_smc1+2 ; 14
|
||||
sta mock_init_smc1+5 ; 15
|
||||
|
||||
sta mock_init_smc2+2 ; 16
|
||||
sta mock_init_smc2+5 ; 17
|
||||
|
||||
sta reset_ay_smc1+2 ; 18
|
||||
sta reset_ay_smc2+2 ; 19
|
||||
sta reset_ay_smc3+2 ; 20
|
||||
sta reset_ay_smc4+2 ; 21
|
||||
|
||||
sta write_ay_smc1+2 ; 22
|
||||
sta write_ay_smc1+5 ; 23
|
||||
|
||||
sta write_ay_smc2+2 ; 24
|
||||
sta write_ay_smc2+5 ; 25
|
||||
|
||||
sta write_ay_smc3+2 ; 26
|
||||
sta write_ay_smc3+5 ; 27
|
||||
|
||||
sta write_ay_smc4+2 ; 28
|
||||
sta write_ay_smc4+5 ; 29
|
||||
|
||||
sta write_ay_smc5+2 ; 30
|
||||
sta write_ay_smc5+5 ; 31
|
||||
|
||||
sta write_ay_smc6+2 ; 32
|
||||
sta write_ay_smc6+5 ; 33
|
||||
|
||||
sta setup_irq_smc1+2 ; 34
|
||||
sta setup_irq_smc2+2 ; 35
|
||||
sta setup_irq_smc3+2 ; 36
|
||||
sta setup_irq_smc4+2 ; 37
|
||||
sta setup_irq_smc5+2 ; 38
|
||||
sta setup_irq_smc6+2 ; 39
|
||||
|
||||
rts
|
||||
.endif
|
||||
|
||||
;===================================================================
|
||||
; dangerous code to patch mockingboard if not in slot#4
|
||||
;===================================================================
|
||||
; this code patches any $C4 value to the proper slot# if not slot4
|
||||
; this can be dangerous, it might over-write other important values
|
||||
; that should be $C4
|
||||
|
||||
; safer ways to do this:
|
||||
; only do this if 2 bytes after a LDA/STA/LDX/STX
|
||||
; count total and if not 39 then print error message
|
||||
|
||||
mockingboard_patch:
|
||||
; from mockingboard_init $1BBF
|
||||
; to done_pt3_irq_handler $1D85
|
||||
|
||||
ldx MB_ADDR_H
|
||||
ldy #0
|
||||
|
||||
lda #<mockingboard_init
|
||||
sta MB_ADDR_L
|
||||
lda #>mockingboard_init
|
||||
sta MB_ADDR_H
|
||||
|
||||
mb_patch_loop:
|
||||
lda (MB_ADDR_L),Y
|
||||
cmp #$C4
|
||||
bne mb_patch_nomatch
|
||||
|
||||
txa
|
||||
sta (MB_ADDR_L),Y
|
||||
mb_patch_nomatch:
|
||||
|
||||
inc MB_ADDR_L
|
||||
lda MB_ADDR_L
|
||||
bne mb_patch_oflo
|
||||
inc MB_ADDR_H
|
||||
|
||||
mb_patch_oflo:
|
||||
lda MB_ADDR_H
|
||||
cmp #>done_pt3_irq_handler
|
||||
bne mb_patch_loop
|
||||
lda MB_ADDR_L
|
||||
cmp #<done_pt3_irq_handler
|
||||
bne mb_patch_loop
|
||||
|
||||
mb_patch_done:
|
||||
rts
|
||||
|
||||
.if 0
|
||||
|
||||
|
||||
;=======================================
|
||||
; Detect a Mockingboard card
|
||||
;=======================================
|
||||
; Based on code from the French Touch "Pure Noise" Demo
|
||||
; Attempts to time an instruction sequence with a 6522
|
||||
;
|
||||
; If found, puts in bMB
|
||||
; MB_ADDRL:MB_ADDRH has address of Mockingboard
|
||||
; returns X=0 if not found, X=1 if found
|
||||
|
||||
mockingboard_detect:
|
||||
lda #0
|
||||
sta MB_ADDRL
|
||||
|
||||
mb_detect_loop: ; self-modifying
|
||||
lda #$07 ; we start in slot 7 ($C7) and go down to 0 ($C0)
|
||||
ora #$C0 ; make it start with C
|
||||
sta MB_ADDRH
|
||||
ldy #04 ; $CX04
|
||||
ldx #02 ; 2 tries?
|
||||
mb_check_cycle_loop:
|
||||
lda (MB_ADDRL),Y ; timer 6522 (Low Order Counter)
|
||||
; count down
|
||||
sta PT3_TEMP ; 3 cycles
|
||||
lda (MB_ADDRL),Y ; + 5 cycles = 8 cycles
|
||||
; between the two accesses to the timer
|
||||
sec
|
||||
sbc PT3_TEMP ; subtract to see if we had 8 cycles
|
||||
cmp #$f8 ; -8
|
||||
bne mb_not_in_this_slot
|
||||
dex ; decrement, try one more time
|
||||
bne mb_check_cycle_loop ; loop detection
|
||||
inx ; Mockingboard found (X=1)
|
||||
done_mb_detect:
|
||||
;stx bMB ; store result to bMB
|
||||
rts ; return
|
||||
|
||||
mb_not_in_this_slot:
|
||||
dec mb_detect_loop+1 ; decrement the "slot" (self_modify)
|
||||
bne mb_detect_loop ; loop down to one
|
||||
ldx #00
|
||||
beq done_mb_detect
|
||||
|
||||
;alternative MB detection from Nox Archaist
|
||||
; lda #$04
|
||||
; sta MB_ADDRL
|
||||
; ldx #$c7
|
||||
;
|
||||
;find_mb:
|
||||
; stx MB_ADDRH
|
||||
;
|
||||
; ;detect sound I
|
||||
;
|
||||
; sec
|
||||
; ldy #$00
|
||||
; lda (MB_ADDRL), y
|
||||
; sbc (MB_ADDRL), y
|
||||
; cmp #$05
|
||||
; beq found_mb
|
||||
; dex
|
||||
; cpx #$c0
|
||||
; bne find_mb
|
||||
; ldx #$00 ;no mockingboard found
|
||||
; rts
|
||||
;
|
||||
;found_mb:
|
||||
; ldx #$01 ;mockingboard found
|
||||
; rts
|
||||
;
|
||||
; ;optionally detect sound II
|
||||
;
|
||||
; sec
|
||||
; ldy #$80
|
||||
; lda (MB_ADDRL), y
|
||||
; sbc (MB_ADDRL), y
|
||||
; cmp #$05
|
||||
; beq found_mb
|
||||
|
||||
|
||||
;=======================================
|
||||
; Detect a Mockingboard card in Slot4
|
||||
;=======================================
|
||||
; Based on code from the French Touch "Pure Noise" Demo
|
||||
; Attempts to time an instruction sequence with a 6522
|
||||
;
|
||||
; MB_ADDRL:MB_ADDRH has address of Mockingboard
|
||||
; returns X=0 if not found, X=1 if found
|
||||
|
||||
mockingboard_detect_slot4:
|
||||
lda #0
|
||||
sta MB_ADDRL
|
||||
|
||||
mb4_detect_loop: ; self-modifying
|
||||
lda #$04 ; we're only looking in Slot 4
|
||||
ora #$C0 ; make it start with C
|
||||
sta MB_ADDRH
|
||||
ldy #04 ; $CX04
|
||||
ldx #02 ; 2 tries?
|
||||
mb4_check_cycle_loop:
|
||||
lda (MB_ADDRL),Y ; timer 6522 (Low Order Counter)
|
||||
; count down
|
||||
sta PT3_TEMP ; 3 cycles
|
||||
lda (MB_ADDRL),Y ; + 5 cycles = 8 cycles
|
||||
; between the two accesses to the timer
|
||||
sec
|
||||
sbc PT3_TEMP ; subtract to see if we had 8 cycles
|
||||
cmp #$f8 ; -8
|
||||
bne mb4_not_in_this_slot
|
||||
dex ; decrement, try one more time
|
||||
bne mb4_check_cycle_loop ; loop detection
|
||||
inx ; Mockingboard found (X=1)
|
||||
done_mb4_detect:
|
||||
rts ; return
|
||||
|
||||
mb4_not_in_this_slot:
|
||||
ldx #00
|
||||
beq done_mb4_detect
|
||||
|
||||
|
||||
|
||||
.endif
|
||||
|
|
@ -0,0 +1,275 @@
|
|||
; Mockingboad programming:
|
||||
; + Has two 6522 I/O chips connected to two AY-3-8910 chips
|
||||
; + Optionally has some speech chips controlled via the outport on the AY
|
||||
; + Often in slot 4
|
||||
; TODO: how to auto-detect?
|
||||
; References used:
|
||||
; http://macgui.com/usenet/?group=2&id=8366
|
||||
; 6522 Data Sheet
|
||||
; AY-3-8910 Data Sheet
|
||||
|
||||
;========================
|
||||
; Mockingboard card
|
||||
; Essentially two 6522s hooked to the Apple II bus
|
||||
; Connected to AY-3-8910 chips
|
||||
; PA0-PA7 on 6522 connected to DA0-DA7 on AY
|
||||
; PB0 on 6522 connected to BC1
|
||||
; PB1 on 6522 connected to BDIR
|
||||
; PB2 on 6522 connected to RESET
|
||||
|
||||
|
||||
; left speaker
|
||||
MOCK_6522_ORB1 = $C400 ; 6522 #1 port b data
|
||||
MOCK_6522_ORA1 = $C401 ; 6522 #1 port a data
|
||||
MOCK_6522_DDRB1 = $C402 ; 6522 #1 data direction port B
|
||||
MOCK_6522_DDRA1 = $C403 ; 6522 #1 data direction port A
|
||||
MOCK_6522_T1CL = $C404 ; 6522 #1 t1 low order latches
|
||||
MOCK_6522_T1CH = $C405 ; 6522 #1 t1 high order counter
|
||||
MOCK_6522_T1LL = $C406 ; 6522 #1 t1 low order latches
|
||||
MOCK_6522_T1LH = $C407 ; 6522 #1 t1 high order latches
|
||||
MOCK_6522_T2CL = $C408 ; 6522 #1 t2 low order latches
|
||||
MOCK_6522_T2CH = $C409 ; 6522 #1 t2 high order counters
|
||||
MOCK_6522_SR = $C40A ; 6522 #1 shift register
|
||||
MOCK_6522_ACR = $C40B ; 6522 #1 auxilliary control register
|
||||
MOCK_6522_PCR = $C40C ; 6522 #1 peripheral control register
|
||||
MOCK_6522_IFR = $C40D ; 6522 #1 interrupt flag register
|
||||
MOCK_6522_IER = $C40E ; 6522 #1 interrupt enable register
|
||||
MOCK_6522_ORANH = $C40F ; 6522 #1 port a data no handshake
|
||||
|
||||
|
||||
; right speaker
|
||||
MOCK_6522_ORB2 = $C480 ; 6522 #2 port b data
|
||||
MOCK_6522_ORA2 = $C481 ; 6522 #2 port a data
|
||||
MOCK_6522_DDRB2 = $C482 ; 6522 #2 data direction port B
|
||||
MOCK_6522_DDRA2 = $C483 ; 6522 #2 data direction port A
|
||||
|
||||
; AY-3-8910 commands on port B
|
||||
; RESET BDIR BC1
|
||||
MOCK_AY_RESET = $0 ; 0 0 0
|
||||
MOCK_AY_INACTIVE = $4 ; 1 0 0
|
||||
MOCK_AY_READ = $5 ; 1 0 1
|
||||
MOCK_AY_WRITE = $6 ; 1 1 0
|
||||
MOCK_AY_LATCH_ADDR = $7 ; 1 1 1
|
||||
|
||||
|
||||
;========================
|
||||
; Mockingboard Init
|
||||
;========================
|
||||
; Initialize the 6522s
|
||||
; set the data direction for all pins of PortA/PortB to be output
|
||||
|
||||
mockingboard_init:
|
||||
lda #$ff ; all output (1)
|
||||
|
||||
mock_init_smc1:
|
||||
sta MOCK_6522_DDRB1
|
||||
sta MOCK_6522_DDRA1
|
||||
mock_init_smc2:
|
||||
sta MOCK_6522_DDRB2
|
||||
sta MOCK_6522_DDRA2
|
||||
rts
|
||||
|
||||
;===================================
|
||||
;===================================
|
||||
; Reset Both AY-3-8910s
|
||||
;===================================
|
||||
;===================================
|
||||
|
||||
;======================
|
||||
; Reset Left AY-3-8910
|
||||
;======================
|
||||
reset_ay_both:
|
||||
lda #MOCK_AY_RESET
|
||||
reset_ay_smc1:
|
||||
sta MOCK_6522_ORB1
|
||||
lda #MOCK_AY_INACTIVE
|
||||
reset_ay_smc2:
|
||||
sta MOCK_6522_ORB1
|
||||
|
||||
;======================
|
||||
; Reset Right AY-3-8910
|
||||
;======================
|
||||
;reset_ay_right:
|
||||
;could be merged with both
|
||||
lda #MOCK_AY_RESET
|
||||
reset_ay_smc3:
|
||||
sta MOCK_6522_ORB2
|
||||
lda #MOCK_AY_INACTIVE
|
||||
reset_ay_smc4:
|
||||
sta MOCK_6522_ORB2
|
||||
rts
|
||||
|
||||
|
||||
; Write sequence
|
||||
; Inactive -> Latch Address -> Inactive -> Write Data -> Inactive
|
||||
|
||||
;=========================================
|
||||
; Write Right/Left to save value AY-3-8910
|
||||
;=========================================
|
||||
; register in X
|
||||
; value in MB_VALUE
|
||||
|
||||
; note the datasheet says 10,000ns (10 cycle) max hold
|
||||
; time on the write signals. So interleaving write/left
|
||||
; write might violate that
|
||||
|
||||
write_ay_both:
|
||||
; address
|
||||
|
||||
; write left
|
||||
lda #MOCK_AY_LATCH_ADDR ; latch_address on PB1 ; 2
|
||||
ldy #MOCK_AY_INACTIVE ; go inactive ; 2
|
||||
|
||||
write_ay_smc1:
|
||||
stx MOCK_6522_ORA1 ; put address on PA1 ; 4
|
||||
write_ay_smc2:
|
||||
sta MOCK_6522_ORB1 ; latch_address on PB1 ; 4
|
||||
write_ay_smc3:
|
||||
sty MOCK_6522_ORB1 ; go inactive ; 4
|
||||
|
||||
; write right
|
||||
stx MOCK_6522_ORA2 ; put address on PA2 ; 4
|
||||
sta MOCK_6522_ORB2 ; latch_address on PB2 ; 4
|
||||
sty MOCK_6522_ORB2 ; 4
|
||||
;===========
|
||||
|
||||
; value
|
||||
lda MB_VALUE ; 3
|
||||
; write left
|
||||
write_ay_smc4:
|
||||
sta MOCK_6522_ORA1 ; put value on PA1 ; 4
|
||||
lda #MOCK_AY_WRITE ; ; 2
|
||||
write_ay_smc5:
|
||||
sta MOCK_6522_ORB1 ; write on PB1 ; 4
|
||||
write_ay_smc6:
|
||||
sty MOCK_6522_ORB1 ; 4
|
||||
|
||||
|
||||
|
||||
lda MB_VALUE ; 3
|
||||
; write right
|
||||
sta MOCK_6522_ORA2 ; put value on PA2 ; 4
|
||||
lda #MOCK_AY_WRITE ; ; 2
|
||||
sta MOCK_6522_ORB2 ; write on PB2 ; 4
|
||||
sty MOCK_6522_ORB2 ; 4
|
||||
;===========
|
||||
|
||||
|
||||
rts ; 6
|
||||
;===========
|
||||
; 63
|
||||
write_ay_both_end:
|
||||
;.assert >write_ay_both = >write_ay_both_end, error, "write_ay_both crosses page"
|
||||
|
||||
;=======================================
|
||||
; clear ay -- clear all 14 AY registers
|
||||
; should silence the card
|
||||
;=======================================
|
||||
; 7+(74*14)+5=1048
|
||||
clear_ay_both:
|
||||
ldx #13 ; 2
|
||||
lda #0 ; 2
|
||||
sta MB_VALUE ; 3
|
||||
clear_ay_left_loop:
|
||||
jsr write_ay_both ; 6+63
|
||||
dex ; 2
|
||||
bpl clear_ay_left_loop ; 3
|
||||
; -1
|
||||
rts ; 6
|
||||
|
||||
clear_ay_end:
|
||||
;.assert >clear_ay_both = >clear_ay_end, error, "clear_ay_both crosses page"
|
||||
|
||||
;=============================
|
||||
; Setup
|
||||
;=============================
|
||||
mockingboard_setup_interrupt:
|
||||
|
||||
;===========================
|
||||
; Check for Apple IIc
|
||||
;===========================
|
||||
; it does interrupts differently
|
||||
|
||||
lda $FBB3 ; IIe and newer is $06
|
||||
cmp #6
|
||||
beq apple_iie_or_newer
|
||||
|
||||
jmp done_apple_detect
|
||||
apple_iie_or_newer:
|
||||
lda $FBC0 ; 0 on a IIc
|
||||
bne done_apple_detect
|
||||
apple_iic:
|
||||
; activate IIc mockingboard?
|
||||
; this might only be necessary to allow detection
|
||||
; I get the impression the Mockingboard 4c activates
|
||||
; when you access any of the 6522 ports in Slot 4
|
||||
lda #$ff
|
||||
|
||||
; don't bother patching these, IIc mockingboard always slot 4?
|
||||
|
||||
sta MOCK_6522_DDRA1
|
||||
sta MOCK_6522_T1CL
|
||||
|
||||
; bypass the firmware interrupt handler
|
||||
; should we do this on IIe too? probably faster
|
||||
|
||||
sei ; disable interrupts
|
||||
lda $c08b ; disable ROM (enable language card)
|
||||
lda $c08b
|
||||
lda #<interrupt_handler
|
||||
sta $fffe
|
||||
lda #>interrupt_handler
|
||||
sta $ffff
|
||||
|
||||
lda #$EA ; nop out the "lda $45" in the irq hand
|
||||
sta interrupt_smc
|
||||
sta interrupt_smc+1
|
||||
|
||||
done_apple_detect:
|
||||
|
||||
|
||||
;=========================
|
||||
; Setup Interrupt Handler
|
||||
;=========================
|
||||
; Vector address goes to 0x3fe/0x3ff
|
||||
; FIXME: should chain any existing handler
|
||||
|
||||
lda #<interrupt_handler
|
||||
sta $03fe
|
||||
lda #>interrupt_handler
|
||||
sta $03ff
|
||||
|
||||
;============================
|
||||
; Enable 50Hz clock on 6522
|
||||
;============================
|
||||
|
||||
; 4fe7 / 1e6 = .020s, 50Hz
|
||||
|
||||
; 9c40 / 1e6 = .040s, 25Hz
|
||||
; 411a / 1e6 = .016s, 60Hz
|
||||
|
||||
sei ; disable interrupts just in case
|
||||
|
||||
lda #$40 ; Continuous interrupts, don't touch PB7
|
||||
setup_irq_smc1:
|
||||
sta MOCK_6522_ACR ; ACR register
|
||||
lda #$7F ; clear all interrupt flags
|
||||
setup_irq_smc2:
|
||||
sta MOCK_6522_IER ; IER register (interrupt enable)
|
||||
|
||||
lda #$C0
|
||||
setup_irq_smc3:
|
||||
sta MOCK_6522_IFR ; IFR: 1100, enable interrupt on timer one oflow
|
||||
setup_irq_smc4:
|
||||
sta MOCK_6522_IER ; IER: 1100, enable timer one interrupt
|
||||
|
||||
lda #$E7
|
||||
setup_irq_smc5:
|
||||
sta MOCK_6522_T1CL ; write into low-order latch
|
||||
lda #$4f
|
||||
setup_irq_smc6:
|
||||
sta MOCK_6522_T1CH ; write into high-order latch,
|
||||
; load both values into counter
|
||||
; clear interrupt and start counting
|
||||
|
||||
rts
|
||||
|
|
@ -0,0 +1,29 @@
|
|||
; these need to be in zero page
|
||||
; can we find a location that works?
|
||||
|
||||
PATTERN_L = $06
|
||||
PATTERN_H = $07
|
||||
ORNAMENT_L = $08
|
||||
ORNAMENT_H = $09
|
||||
SAMPLE_L = $0A
|
||||
SAMPLE_H = $0B
|
||||
MB_ADDR_L = $0C
|
||||
MB_ADDR_H = $0D
|
||||
|
||||
|
||||
; only used for title screen...
|
||||
TEMP = $FA
|
||||
TEMPY = $FB
|
||||
;INL = $FC
|
||||
;INH = $FD
|
||||
;OUTL = $FE
|
||||
;OUTH = $FF
|
||||
|
||||
; pre-defined applesoft vars
|
||||
|
||||
CH = $24
|
||||
CV = $25
|
||||
GBASL = $26
|
||||
GBASH = $27
|
||||
BASL = $28
|
||||
BASH = $29
|
||||
Loading…
Reference in New Issue